3

我有这个程序：

procedure Initialize(out FormatSettings: TFormatSettings);
const
  LongDayNamesEx : array [1..7] of string = ('Lunedì', 'Martedì', 'Mercoledì', 'Giovedì', 'Venerdì', 'Sabato', 'Domenica');
  LongMonthNamesEx : array [1..12] of string = ('Gennaio', 'Febbraio', 'Marzo', 'Aprile', 'Maggio', 'Giugno', 'Luglio', 'Agosto', 'Settembre', 'Ottobre', 'Novembre', 'Dicembre');
begin
  FormatSettings := TFormatSettings.Create;
  with FormatSettings do
  begin
    LongDayNames := LongDayNamesEx;
    LongMonthNames := LongMonthNamesEx;
  end;
end;

我收到有关不兼容类型的错误（E2008）。我该如何解决这个问题？我不想使用以下内容：

LongDayNames[1] := 'Lunedì';
LongDayNames[2] := 'Martedì';
...
LongDayNames[7] := 'Domenica';
LongMonthNames[1] := 'Gennaio';
LongMonthNames[2] := 'Febbraio';
...
LongMonthNames[12] := 'Dicembre';

如果不是非常必要的话。感谢帮助。

4

3 回答 3

5

你可以这样做：

type
  TDayNameArray = array[1..7] of string;
const
  LongDayNamesEx: TDayNameArray = ('Måndag', 'Tisdag', 'Onsdag', 'Torsdag',
    'Fredag', 'Lördag', 'Söndag');
var
  fs: TFormatSettings;
begin
  TDayNameArray(fs.LongDayNames) := LongDayNamesEx;
于 2012-11-20T13:41:59.683 回答
3

Andreas 对您提出的直接问题给出了很好的回答。

采用不同的方法，我认为您可以通过在初始化对象时传递语言环境更轻松地解决您的问题。例如：

FormatSettings := TFormatSettings.Create('it-IT');

意大利语。然后系统将填写区域特定设置、日期名称、月份名称等。

或者您可能会使用采用区域设置 ID 的重载更合适。没关系，你肯定明白。

于 2012-11-20T14:09:24.853 回答
0

要直接回答您提出的问题，显而易见的解决方案是使用 for 循环。结合记录助手和开放数组参数，使其更容易调用：

type
  TTFormatSettingsHelper = record helper for TFormatSettings
    procedure SetLongDayNames(const Values: array of string);
  end;

procedure TTFormatSettingsHelper.SetLongDayNames(const Values: array of string);
var
  Index: Integer;
  Value: string;
begin
  Assert(high(Values)-low(Values)
    = high(Self.LongDayNames)-low(Self.LongDayNames));

  Index := low(Self.LongDayNames);
  for Value in Values do
  begin
    Self.LongDayNames[Index] := Value;
    inc(Index);
  end;
end;

然后要调用它，您只需编写：

FormatSettings.SetLongDayNames(['Lunedì', 'Martedì', 'Mercoledì', 'Giovedì', 
  'Venerdì', 'Sabato', 'Domenica']);
于 2012-11-20T19:57:15.430 回答