10

在这个线程中，我参考了我的最后一个线程：Convert XML to CSV using XSLT-dynamic columns。

引用线程中的XSLT脚本运行良好，但对于大型XML文档，性能不佳。现在我想编写一个输出另一个 XSLT 脚本的 XSLT 脚本，该脚本将输出最终的CSV文件。

问题：

如何编写第一个 XSLT 脚本？输出应如下所示：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes"/>

<xsl:template match="/*">
    <xsl:text>Name;</xsl:text>
    <xsl:text>Brother;</xsl:text>
    <xsl:text>Sister</xsl:text>
    <-- this part is dynamic -->
    <xsl:apply-templates select="Person" />
</xsl:template>

<xsl:template match="Person">
    <xsl:value-of select="Name" />
    <xsl:value-of select="Brother" />
    <xsl:value-of select="Sister" />
    <-- this part is dynamic too -->
    <xsl:text>&#10;</xsl:text>
</xsl:template>
</xsl:stylesheet>

输入 XML 文件与引用线程中的相同：

<Person>
    <Name>John</Name>
    <FamilyMembers>
        <FamilyMember>
            <Name>Lisa</Name>
            <Type>Sister</Type>
        </FamilyMember>
        <FamilyMember>
            <Name>Tom</Name>
            <Type>Brother</Type>
        </FamilyMember>
    </FamilyMembers>
</Person>
<Person>
    <Name>Daniel</Name>
    <FamilyMembers>
        <FamilyMember>
            <Name>Peter</Name>
            <Type>Father</Type>
        </FamilyMember>
    </FamilyMembers>
</Person>

对于每个不同类型的元素，在生成的 XSLT 脚本中应该有如下一行：

<xsl:text>Type;</xsl:text>
4

3 回答 3

18

要编写一个输出另一个 XSLT 的 XSLT，您需要使用 生成输出元素<xsl:element>，例如

<xsl:element name="xsl:text">

或者<xsl:namespace-alias>如果您想使用文字结果元素，请使用。XSLT 规范有一个例子：

<xsl:stylesheet
  version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:fo="http://www.w3.org/1999/XSL/Format"
  xmlns:axsl="http://www.w3.org/1999/XSL/TransformAlias">

<xsl:namespace-alias stylesheet-prefix="axsl" result-prefix="xsl"/>

<xsl:template match="/">
  <axsl:stylesheet>
    <xsl:apply-templates/>
  </axsl:stylesheet>
</xsl:template>

样式表中的任何<axsl:...>元素都将成为<xsl:...>输出。

于 2012-11-20T12:36:00.800 回答
1

而不是两个外部阶段的解决方案（意味着一个样式表，它编写一个可以执行的样式表），我认为蒂姆的解决方案版本会更好地为您服务，该版本在规模上表现得更好。请使用您的“大型 XML 文档”作为输入来衡量此解决方案的性能。

这个 XSLT 1.0 样式表...

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text" />

<xsl:key name="kTypes" match="Type" use="." />  
<xsl:variable name="distinct-types"
  select="/*/Person/FamilyMembers/FamilyMember/Type[
  generate-id()=generate-id(key('kTypes',.)[1])]" />

<xsl:template match="/">
  <xsl:value-of select="'Name;'" />
  <xsl:for-each select="$distinct-types">
    <xsl:value-of select="." />
    <xsl:if test="position() &lt; last()">
      <xsl:value-of select="';'" />
    </xsl:if>  
  </xsl:for-each>
  <xsl:value-of select="'&#x0A;'" />
  <xsl:apply-templates select="*/Person" />
</xsl:template>

<xsl:template match="Person">
  <xsl:value-of select="concat(Name,';')" />
  <xsl:variable name="family" select="FamilyMembers/FamilyMember" />
  <xsl:for-each select="$distinct-types">
    <xsl:variable name="type" select="string(.)" />
    <xsl:value-of select="$family/self::*[Type=$type]/Name" />
    <xsl:if test="position() &lt; last()">
      <xsl:value-of select="';'" />
    </xsl:if>  
  </xsl:for-each>
  <xsl:value-of select="'&#x0A;'" />
</xsl:template>

</xsl:stylesheet>

...将转换此输入（或大规模有效地转换其他输入）...

<t>
<Person>
    <Name>John</Name>
    <FamilyMembers>
        <FamilyMember>
            <Name>Lisa</Name>
            <Type>Sister</Type>
        </FamilyMember>
        <FamilyMember>
            <Name>Tom</Name>
            <Type>Brother</Type>
        </FamilyMember>
    </FamilyMembers>
</Person>
<Person>
    <Name>Daniel</Name>
    <FamilyMembers>
        <FamilyMember>
            <Name>Peter</Name>
            <Type>Father</Type>
        </FamilyMember>
    </FamilyMembers>
</Person>
</t>

...并产生文本...

Name;Sister;Brother;Father
John;Lisa;Tom;
Daniel;;;Peter
于 2012-11-20T13:13:06.367 回答
0

在此处查看为另一个 XSLT 转换生成样式表的 XSLT 转换的实际示例：

http://dnovatchev.wordpress.com/2006/10/21/a-stylesheet-to-write-xslt-code/

于 2012-11-20T13:43:32.203 回答