5

我目前在我的VBA代码中有以下行Inputbox：

Set myValues = Application.InputBox("Please select on the spreadsheet the first cell in the column with the values that you are looking for:", Type:=8)

但是，当我选择单元格时，它会自动输入例如$A$1. 可以更改此设置，而无需用户手动删除 $，以便Inputbox自动将单元格引用设为A1？

它是自动VLookup宏的一部分，除了VLookup在整个列中固定值之外，它可以完美地工作。

提前致谢。

更新 - 这是完整的代码：

Dim FirstRow As Long
Dim FinalRow As Long
Dim myValues As Range
Dim myResults As Range
Dim myCount As Integer

Sub VlookupMacroNew()  

Set myValues = Application.InputBox("Please select on the spreadsheet the first cell in the column with the values that you are looking for:", Default:=Range("A1").Address(0, 0), Type:=8)

Set myResults = Application.InputBox("Please select on the spreadsheet the first cell where you want your lookup results to start:", Type:=8)

myCount = Application.InputBox("Please enter the column number of the destination range:", Type:=1)

On Error Resume Next
myResults.EntireColumn.Insert Shift:=xlToRight
Set myResults = myResults.Offset(, -1)
FirstRow = myValues.Row
FinalRow = Cells(65536, myValues.Column).End(xlUp).Row

Range(myResults, myResults.Offset(FinalRow - FirstRow)).Formula = _
"=VLOOKUP(" & Cells(FirstRow, myValues.Column).Address & ", " & _
"'S:\Payroll\CONTROL SECTION\[Latest Data.xls]Sheet1'!$A$1:$B$100" & ", " & myCount & ", False)"

myValues 将从单元格 A2 开始，但是当我们使用动态列表时，我需要将查找值更改为 A3、A4、A5 等，因为公式被复制到列表中。通过使用 $A$2 的输入框，查找公式仅查看该单元格引用。

4

2 回答 2

2

您的问题不在于 InputBox，而在于Address()方法的行为。

默认情况下，Address()不带参数返回绝对地址。

Cells(FirstRow, myValues.Column).Address(False,False)

将返回“非固定”范围地址。

于 2012-11-20T17:20:16.553 回答
2

正如蒂姆所说，您的问题不在于 InputBox。相反，当您一次为整个范围设置公式时，它会FirstRow用于每个单元格的公式。理想情况下，您将.FormulaR1C1用于设置公式。这将允许您一次性使公式相对。

下面的解决方案只是修改您的代码以在第一个单元格中放置一个非相对地址，然后将其余单元格中的公式设置为等于第一个单元格中的公式。当您分配这样的公式时，它会使它们相对：

Sub VlookupMacroNew()

Set myValues = Application.InputBox("Please select on the spreadsheet the first cell in the column with the values that you are looking for:", Default:=Range("A1").Address(0, 0), Type:=8)
Set myResults = Application.InputBox("Please select on the spreadsheet the first cell where you want your lookup results to start:", Type:=8)
myCount = Application.InputBox("Please enter the column number of the destination range:", Type:=1)

On Error Resume Next
myResults.EntireColumn.Insert Shift:=xlToRight
Set myResults = myResults.Offset(, -1)
FirstRow = myValues.Row
FinalRow = Cells(65536, myValues.Column).End(xlUp).Row

Range(myResults, myResults.Offset(FinalRow - FirstRow)).Cells(1).Formula = _
"=VLOOKUP(" & Cells(FirstRow, myValues.Column).Address(False, False) & ", " & _
"'S:\Payroll\CONTROL SECTION\[Latest Data.xls]Sheet1'!$A$1:$B$100" & ", " & myCount & ", False)"
Range(myResults, myResults.Offset(FinalRow - FirstRow)).Formula = _
Range(myResults, myResults.Offset(FinalRow - FirstRow)).Cells(1).Formula
End Sub
于 2012-11-20T18:12:16.093 回答