9

有没有办法从 Inno Setup 脚本中生成新的 GUID？

4

4 回答 4

14

在 innosetup 新闻组存档中找到了这个：

http://news.jrsoftware.org/news/innosetup/msg76234.html

我没有测试过。

[Code]

type
  TGUID = record
    D1: LongWord;
    D2: Word;
    D3: Word;
    D4: array[0..7] of Byte;
  end;

function CoCreateGuid(var Guid:TGuid):integer;
 external 'CoCreateGuid@ole32.dll stdcall';

function inttohex(l:longword; digits:integer):string;
var hexchars:string;
begin
 hexchars:='0123456789ABCDEF';
 setlength(result,digits);
 while (digits>0) do begin
  result[digits]:=hexchars[l mod 16+1];
  l:=l div 16;
  digits:=digits-1;
 end;
end;

function GetGuid(dummy:string):string;
var Guid:TGuid;
begin
  if CoCreateGuid(Guid)=0 then begin
  result:='{'+IntToHex(Guid.D1,8)+'-'+
           IntToHex(Guid.D2,4)+'-'+
           IntToHex(Guid.D3,4)+'-'+
           IntToHex(Guid.D4[0],2)+IntToHex(Guid.D4[1],2)+'-'+
           IntToHex(Guid.D4[2],2)+IntToHex(Guid.D4[3],2)+
           IntToHex(Guid.D4[4],2)+IntToHex(Guid.D4[5],2)+
           IntToHex(Guid.D4[6],2)+IntToHex(Guid.D4[7],2)+
           '}';
  end else
    result:='{00000000-0000-0000-0000-000000000000}';
end;

function InitializeSetup(): Boolean;
begin
  MsgBox(GetGuid(''), mbInformation, MB_OK);
  Result := False;
end;
于 2009-08-28T13:56:20.703 回答
3

我使用这个解决方案有一段时间了（运行 5.5.0 (a) 和 5.5.1(a)）。

但是，当我更新到 5.5.2 (u) - 我的构建脚本由于重复类型错误而失败：'TGUID'。

为了修复它，我不得不删除：

type
  TGUID = record
    D1: LongWord;
    D2: Word;
    D3: Word;
    D4: array[0..7] of Byte;
  end;

这仅在 Unicode 版本上发生 - 这意味着 5.5.2 (u) 具有内置的 GUID 类型。

于 2012-11-09T17:17:10.343 回答
2

这是一个更简洁的实现FormatGuid，没有不必要的十六进制格式化函数（我们有什么Format用？！）：

function FormatGuid(Guid:TGuid):string;
begin
  result:=Format('%.8x-%.4x-%.4x-%.2x-%.2x-%.2x-%.2x-%.2x-%.2x-%.2x-%.2x', [Guid.D1, Guid.D2, Guid.D3, Guid.D4[0], Guid.D4[1], Guid.D4[2], Guid.D4[3], Guid.D4[4], Guid.D4[5], Guid.D4[6], Guid.D4[7]]);
end;

您仍然需要像其他答案一样定义TGuid和导入：CoCreateGuid

type
  TGuid = record
    D1: LongWord;
    D2: Word;
    D3: Word;
    D4: array[0..7] of Byte;
  end;

function CoCreateGuid(var Guid:TGuid):integer;
 external 'CoCreateGuid@ole32.dll stdcall';
于 2011-05-05T01:00:55.360 回答
1

您可以通过调用 Windows API 函数 CoCreateGuid（在“OLE32.dll”中）来执行此操作，您可以在脚本的 [Code] 部分中声明该函数。抱歉，我有一段时间没有使用 Inno Setup，所以我不知道该怎么做。为了提供帮助，下面是 GetWindow() 函数的示例 API 声明：

Function GetWindow (HWND: Longint; uCmd: cardinal): Longint;
    external 'GetWindow@user32.dll stdcall';

这是使用 CoCreateGuid 的 VB 示例的链接：

http://support.microsoft.com/kb/176790

在这一切的某个地方是你的答案。

于 2009-08-28T13:56:03.497 回答