是的，缓冲区只是一个数组，在汇编中是一个字节序列。
您有 3 个主要选项来分配它，就像在 C 中一样：
静态存储：像 Cstatic char buf[100];
section .bss ; this might not be proper MASM syntax
my_buffer: db 100 dup(?) ; but this is definitely MASM
:在标签名称和之间放置 adb使其只是一个普通标签，如 NASM，而不是具有隐含操作数大小的 MASM“变量”。（如果 MASM 允许您在 .data / .bss 部分执行此操作。它可能不会。）
100 dup意思是将下一件事重复100次。 ?表示未初始化的存储。它实际上将在像 Windows 这样的操作系统下运行的程序中归零，因为它不能让程序看到内核数据或同一台机器上的其他进程留下的陈旧数据。所以100 dup(0)也可以工作，也许可以更好地描述你想要的东西，特别是如果你的代码在没有先写的情况下读取了这些字节中的任何一个。
动态存储：call malloc，或直接调用 OS 函数，如mmap或VirtualAlloc。您可以从分配它的函数返回指向它的指针。
自动存储（在堆栈上）：就像一个 C 局部变量。当分配函数返回时自动解除分配。非常便宜和容易，除非您知道它们需要数兆字节，否则将其用于暂存缓冲区。
处理缓冲区的最简单方法是接受指向已分配缓冲区的指针，并让调用者选择要传递的缓冲区。
例如，一个大写 ASCII 字母的函数可能只需要一个 src 和 dst 指针。如果您希望它就地运行，您可以只传递相同的输入和输出指针，如果它被编写为支持它的话。它不必关心内存管理，它只是在两个缓冲区之间运行。
像 C 这样的函数strdup会创建一个字符串的新副本，而这只对动态存储有意义。将字符串复制到静态缓冲区并返回它不会很好，因为该静态缓冲区只有一个实例。下一次调用它会覆盖旧的内容。
在堆栈上分配缓冲区：
堆栈上的可变大小缓冲区没有问题；您只需要一种事后清理堆栈的方法。使用 EBP / RBP 制作堆栈框架是一种简单的方法。考虑这个示例函数，它根据需要分配一个缓冲区，并使用它来保存字符串反转函数的输出，以便将其传递给print函数。您可以看到编译器在这种情况下做了什么。
void string_reverse(char *d, const char*s, int len);
void print(const char*s, int len); // modify this to an fwrite or whatever.
void print_reversed(const char *s, int len) {
char buf[len];
string_reverse(buf, s, len);
print(buf, len);
}
string_reverse如果不需要 16 字节堆栈对齐并且它不会破坏它的堆栈 arg ，那么这就是您可以手动执行的操作。（ABI / 调用约定并不能保证这些事情中的任何一个，所以我们正在利用我们正在调用的函数的特殊知识来简化print_reversed。）
; MSVC __fastcall convention
; args: ecx, edx (const char *string, size_t length)
print_reversed PROC
push ebp
mov ebp, esp ; make a stack frame
sub esp, edx ; reserve space for a buffer
and esp, -16 ; and realign the stack
; allocate buf[length] on the stack, address = esp
; mov eax, esp ; if you want to copy it somewhere
;sub esp, 12 ; ensure 16-byte stack alignment before CALL
push edx ; 3rd arg and later args go on the stack
mov edx, ecx ; 2nd arg = string
lea ecx, [esp+4] ; 1st arg = output buffer = what we allocated. (PUSH offset ESP by 4, LEA corrects for that)
call string_reverse ; (dst=buf (ECX), src=string (EDX), length=length (stack))
; clean up the stack after the call and set up args for print
pop edx ; assuming string_reverse doesn't modify its stack arg
mov ecx, esp ; esp is once again pointing to our buffer
call print ; print(ECX=buf, EDX=length)
; lea esp, [ebp-8] ; if you needed to push stuff after EBP, restore this way
; pop ebx / pop esi / pop ebp
leave ; mov esp, ebp / pop ebp to clean up the stack frame
ret
ENDP
这是大多数 C 编译器实现alloca或 C99 可变长度数组的方式。