2

我需要构造一个字符串并通过发送它PostMessage，即。

FileName := String_1 + String_2 + String_3;
PostMessage(FWndHandle, WM_BLA_BLA, NotifyData^.Action, LParam(FileName));

但有些东西不起作用。另外，FileName 是一个 PChar。代码如下所示：

var
   FileName : PChar;
   Directory_Str : String;
   AnotherString : String;
begin
    // Get memory for filename and fill it with data
    GetMem(FileName, NotifyData^.FileNameLength + SizeOf(WideChar));
    Move(NotifyData^.FileName, Pointer(FileName)^, NotifyData^.FileNameLength);
    PWord(Cardinal(FileName) + NotifyData^.FileNameLength)^ := 0;

    // TODO: Contact string before sending message
    // FileName := AnotherString + Directory_Str + FileName;

    PostMessage(FWndHandle, WM_BLA_BLA, NotifyData^.Action, LParam(FileName));

    ...
end;

现在我需要FileName在调用之前联系另一个字符串到变量PostMessage，即。

FileName := AnotherString + Directory_Str + FileName;
PostMessage(FWndHandle, WM_BLA_BLA, NotifyData^.Action, LParam(FileName));

如果 FileName 是一个字符串，这将起作用，但这里不是这种情况。

任何人都知道如何用 PChar 做到这一点？我尝试了这些方法，有时会奏效，但最后总是会出现问题：

StrPCopy(FileName, FDirectory + String(FileName));

或者

FileName := PChar(AnotherString + Directory_Str + FileName);
4

2 回答 2

7

您不能轻松地使用PostMessage通过引用传递的数据。原因是PostMessage异步执行，您需要保持传递的内存处于活动状态，直到消息被其接收者处理。我想这就是你的GetMem代码背后的原因。

显然，这只适用于同一进程。而且您还会发现 Windows 不允许您使用PostMessage它的任何接收指针的消息。例如，PostMessage总是WM_SETTEXT失败。您只能希望使用用户定义的消息来做到这一点。当然，您需要在接收消息的代码中释放内存。

我将假设您使用的是用户定义的消息，该消息允许发送带有PostMessage. 在这种情况下，您已经有了解决方案。使用字符串变量进行连接，然后在答案中使用第一段代码。

尽管您可以像这样使它更清洁：

function HeapAllocatedPChar(const Value: string): PChar;
var
  bufferSize: Integer;
begin
  bufferSize := (Length(Value)+1)*SizeOf(Char);
  GetMem(Result, bufferSize);
  Move(PChar(Value)^, Result^, bufferSize);
end;

procedure PostString(Window: HWND; Msg: UINT; wParam: WPARAM; 
  const Value: string);
var
  P: PChar;
begin
  P := HeapAllocatedPChar(Value);
  if not PostMessage(Window, Msg, wParam, LPARAM(P)) then
    FreeMem(P);
end;

您可以像这样调用该过程：

PostString(FWndHandle, WM_BLA_BLA, NotifyData^.Action, FDirectory + FileName);

您当前的代码失败，因为：

  1. 当您打电话时，StrPCopy您不会为更长的字符串分配任何内存。
  2. 当你写作时，PChar(AnotherString + Directory_Str + FileName)你陷入了你试图避免的陷阱GetMem。这是一个本地字符串，在处理消息时已被释放。

如果您可以找到一种无需使用PostMessage传递字符串即可解决问题的方法，那么这可能比所有这些复杂性更可取。

于 2012-11-19T20:27:13.477 回答
6

有关您的代码失败的原因，请参阅 David 的回答。

我总是定义一个通过PostMessage操作分配字符串的类。没有泄漏的风险，并且很容易通过更多信息进行扩展。

Type
  TMyMessage = class
    msg : String;
    Constructor Create(aMessage : String);
  end;


// Sending the message
var
  myMsg : TMyMessage;
...
myMsg := TMyMessage.Create('A message');

if not PostMessage(someHandle,WM_something,WParam(myMsg),0)
then begin
  myMsg.free;
  ... Take care of this condition if PostMessage fails !!
end;  

// Receiving the message

procedure TSomeForm.GetMessage(var msg : TMessage);
var
  aMsg : TMyMessage;
begin
  ...
  aMsg := TMyMessage(msg.WParam);
  try
    ...
    // Do something with the message
  finally
    aMsg.Free;
  end;
end;
于 2012-11-19T20:43:01.967 回答