excel - Access VBA如何确定文件是否为Excel格式？

Question

使用 MS Access VBA 如何检查文件以了解它是否为 Excel 格式？

Answer 1

我从来没有遇到过无法通过扩展名直接确定 Excel 文件的问题，但如果我必须这样做，首先想到的是 UNIX 实用程序file，它通过查看文件类型的内容来识别文件类型. 它可以识别大量的文件类型。

我使用Cygwin for Windows，它本质上是 Windows 上的 UNIX 环境。

当我file在 Excel 2010 (xlsx) 文件上使用 Cygwin 中的命令时，我已重命名为“.csv”，我得到：

$ file afile.csv
afile.csv: Microsoft Excel 2007+

这是一个有点尴尬的解决方案，但在您的 VBA 中，您可以使用Windows Script HostC:\cygwin\bin\file.exe分叉一个进程，并捕获每个文件的输出。

如果您在 Excel 文件的路径周围加上单个刻度（即“C:\path\to\file”），Cygwin 应该正确解释它（Cygwin 实用程序希望看到类似 unix 的路径：/path/to/文件）。我刚刚在普通的 Windows 命令提示符下验证了这一点，它工作正常：

c:\>c:\cygwin\bin\file.exe 'C:\path\to\afile.csv'
C:\path\to\afile.csv: Microsoft Excel 2007+

在GnuWin32 SourceForge 项目中也有一个原生的 Windows 二进制文件，但它似乎有点过时了；我没有尝试过，但它仍然可以识别现代 Excel 版本。file

如果您需要本机 Excel 解决方案——我不完全确定我的想法；希望其他人以前做过。

Answer 2

这不是用于 Access，而是用于 Excel，我使用它。这不是最好的，也不是任何人都喜欢的解决方案，但要振作起来。

Public Function IsExcelFormat(ByVal filePath As String) As Boolean

    On Error GoTo Nope
    Application.ScreenUpdating = False

    Dim wb As Workbook
    Set wb = Workbooks.Open(filePath )
    IsExcelFormat = (wb.FileFormat > 50)

CleanExit:
    Application.ScreenUpdating = True
Exit Function

Nope: ' Clearly not Excel format
    Err.clear
    IsExcelFormat = False
    Resume CleanExit:

End Function

是的，它使用 Excel 的自动魔法。我知道。太可怕了 而且 ScreenUpdating 并不完全有效。当您打开和关闭文件时，您的任务栏将更新。但是，它仍然有效。

您可能需要在 Access VBA 脚本中创建一个 Excel 实例，并可选择将其传递给类似这样的功能。注意我没有测试过这个。

Public Function IsExcelFormat(ByVal file_path As String, _
        Optional byRef excel_instance as Excel.Application = Nothing) As Boolean
    On Error GoTo Nope

    Dim local_excel as boolean
    If excel_instance Is Nothing Then 
       Set excel_instance = New Excel.Application
       local_excel = True
    End If

    Dim wb As Excel.Workbook

    excel_instance.ScreenUpdating = False

    Set wb = excel_instance.Workbooks.Open(file_path)
    IsExcelFormat = (wb.FileFormat > 50)
    wb.Close savechanges:=False

CleanExit:
    If local_excel Then 
        excel_instance.Quit
    Else
        excel_instance.ScreenUpdating = True    
    End If
Exit Function
Nope: ' Clearly not Excel format
    Err.clear
    IsExcelFormat = False
    Resume CleanExit:
End Function

Answer 3

关于使用 ADOX 的可能方法的一些说明

Sub SortFiles()
''Library reference: Windows Script Host Object Model
Dim fs As New FileSystemObject
Dim ts As TextStream
Dim sType As String
Dim sFile As File

For Each sFile In fs.GetFolder("Z:\Docs\").Files
    sType = sFile.Type

    If InStr(sType, "Microsoft") = 0 Then
        sList = ListTables(sFile.Name)
        If sList = "Error: Not Excel" Then
            ''Move to suitable folder
        Else
            Debug.Print sList
            Stop
            ''This can be read as Excel, most likely
        End If

    ElseIf sType Like "*Excel*" Then
       ''Includes CSV
        sFile.Move "z:\docs\Excelfiles\"
    Else
        sFile.Move "z:\docs\OtherMS\"
    End If
Next

End Sub

Function ListTables(sFile As String) As String
''Library reference: Microsoft ADO Ext. x.x for DDL and Security
Dim cat As New ADOX.Catalog
Dim scn As String
Dim t As ADOX.Table
Dim cn As New ADODB.Connection
Dim sList As String

On Error GoTo Handle_Err:

    scn = "Provider=Microsoft.ACE.OLEDB.12.0;" _
    & "Data Source=" & sFile & ";Extended Properties=""Excel 8.0;HDR=No"""

    cn.Open scn

    cat.ActiveConnection = cn

    For Each t In cat.Tables
        sList = sList & vbCrLf & t.Name
    Next t

    ListTables = sList

Exit_Proc:
Set cn = Nothing
Set cat = Nothing
Exit Function

Handle_Err:
    If Err.Number = -2147467259 Then
        ''External table is not in the expected format.
        ListTables = "Error: Not Excel"
        Err.Clear
        Resume Exit_Proc
    Else
        Debug.Print Err.Number, Err.Description
    End If

End Function