2

我有一个包含 3 个文件、一个 PNG、一个 PHP 和一个 TGA 文件的二进制文件。

这里的文件给你的想法：container.bin

文件是这样构建的：前 6 个字节是指向索引的指针，在本例中为 211794 然后您将所有 3 个文件一个接一个地堆叠，在偏移量 211794 处，您有索引，它告诉您文件从哪里开始并结束

在这个例子中，你有：

[offset start] [offset end] [random data] [offset start] [name]

6 15149 asdf 6 Capture.PNG
15149 15168 4584 15149 index.php
15168 211794 12 15168 untilted.tga

这意味着 capture.png 从偏移量 6 开始，在偏移量 15149 结束，然后 asdf 是一个随机数据，并且开始偏移量再次重复。

现在我想做的是一个 perl 来分离这个二进制文件上的文件。perl 需要检查文件的前 6 个偏移量（头），然后跳转到索引位置，并使用列表将文件提取出来。

4

2 回答 2

2

混合seek和read可用于完成任务：

#!/usr/bin/env perl

use strict;
use warnings;

use Fcntl 'SEEK_SET';

sub get_files_info {
    my ( $fh, $offset ) = @_;
    my %file;

    while (<$fh>) {
        chomp;
        my $split_count = my ( $offset_start, $offset_end, $random_data, $offset_start_copy,
            $file_name ) = split /\s/;
        next if $split_count != 5;

        if ( $offset_start != $offset_start_copy ) {
            warn "Start of offset mismatch: $file_name\n";
            next;
        }

        $file{$file_name} = {
            'offset_start' => $offset_start,
            'offset_end'   => $offset_end,
            'random_data'  => $random_data,
        };
    }

    return %file;
}

sub write_file {
    my ( $fh, $file_name, $file_info ) = @_;

    seek $fh, $file_info->{'offset_start'}, SEEK_SET;
    read $fh, my $contents,
      $file_info->{'offset_end'} - $file_info->{'offset_start'};

    open my $fh_out, '>', $file_name or die 'Error opening file: $!';
    binmode $fh_out;
    print $fh_out $contents;

    print "Wrote file: $file_name\n";
}

open my $fh, '<', 'container.bin' or die "Error opening file: $!";
binmode $fh;
read $fh, my $offset, 6;

seek $fh, $offset, SEEK_SET;

my %file = get_files_info $fh, $offset;

for my $file_name ( keys %file ) {
    write_file $fh, $file_name, $file{$file_name};
}
于 2012-11-18T08:59:03.503 回答
2

这里唯一真正的困难是确保输入和输出文件都以二进制模式读取。这可以通过在:raw打开文件时使用 PerlIO 层来实现。

这个程序似乎做你想做的事。它首先定位索引块并将其读入字符串，然后打开该字符串以供输入，并读取每个组成文件的开始和结束位置以及名称。此后处理每个文件很简单。

请注意，除非索引块的格式比您说的更严格，否则您只能依赖每行上的第一个、第二个和最后一个空格分隔的字段，因为随机文本可能包含空格。也无法指定包含空格的文件名。

使用 的输出Data::Dump是为了演示正确的功能，而不是程序运行所必需的。

use v5.10;
use warnings;

use Fcntl ':seek';

use autodie qw/ open read seek close /;

open my $fh, '<:raw', 'container.bin';

read $fh, my $index_loc, 6;

seek $fh, $index_loc, SEEK_SET;
read $fh, my ($index), 1024;

my %contents;
open my $idx, '<', \$index;
while (<$idx>) {
  my @fields = split;
  next unless @fields;
  $contents{$fields[-1]} = [ $fields[0], $fields[1] ];
}

use Data::Dump;
dd \%contents;

for my $file (keys %contents) {

  my ($start, $end) = @{ $contents{$file} };
  my $size = $end - $start;
  seek $fh, $start, SEEK_SET;

  my $nbytes = read $fh, my ($data), $size;
  die "Premature EOF" unless $nbytes == $size;

  open my $out, '>:raw', $file;
  print { $out } $data;
  close $out;
}

输出

{
  "Capture.PNG"  => [6, 15149],
  "index.php"    => [15149, 15168],
  "untilted.tga" => [15168, 211794],
}
于 2012-11-18T12:02:39.260 回答