6

给定二维空间中的点列表，您想在 Haskell 中执行一个函数来查找两个最近点之间的距离。示例：输入：项目 [(1,5), (3,4), (2,8), (-1,2), (-8.6), (7.0), (1.5), (5.5), (4.8 ), (7.4)] 输出：2.0

假设列表中最远的两个点之间的距离最多为 10000。

这是我的代码：

import Data.List
import System.Random

sort_ :: Ord a => [a] -> [a]
sort_ []    =  []
sort_ [x]  =  [x]
sort_ xs   =  merge (sort_ left) (sort_ right)
  where
    (left, right) = splitAt (length xs `div` 2) xs
    merge [] xs = xs
    merge xs [] = xs
    merge (x:xs) (y:ys)=
    if x <= y then 
        x : merge xs (y:ys)
    else  y : merge (x:xs) ys     

project :: [(Float,Float)] -> Float
project [] = 0
project (x:xs)=
    if null (xs) then 
        error "The list have only 1 point"
    else head(sort_(dstList(x:xs)))

distance :: (Float,Float)->(Float,Float) -> Float
distance (x1,y1) (x2,y2) = sqrt((x1 - x2)^2 + (y1 - y2)^2)


dstList :: [(Float,Float)] -> [Float]
dstList (x:xs)=
    if length xs == 1 then 
        (dstBetween x xs):[]
    else (dstBetween x xs):(dstList xs)


dstBetween :: (Float,Float) -> [(Float,Float)] -> Float
dstBetween pnt (x:xs)=
    if null (xs) then 
        distance pnt x
    else  minimum ((distance pnt ):((dstBetween pnt xs)):[])

{-
Calling generator to create a file created at random points
-}
generator = do
    putStrLn "Enter File Name"
    file <- getLine
    g <- newStdGen
    let pts = take 1000 . unfoldr (Just . (\([a,b],c)->((a,b),c)) . splitAt 2) 
                $ randomRs(-1,1) g :: [(Float,Float)]
    writeFile file . show $ pts

{-
Call the main to read a file and pass it to the function of project
The function of the project should keep the name 'project' as described 
in the statement
-}
main= do
    putStrLn "Enter filename to read"
    name <- getLine
    file <- readFile name
    putStrLn . show . project $ readA file

readA::String->[(Float,Float)]
readA = read

我可以像示例中那样运行程序，也可以使用生成器，如下所示：

在 haskell 解释器中必须输入“生成器”，程序将在此处询问包含一千个点的文件名。并且在Haskell解释器中生成文件后必须写main，并请求一个文件名，这是你用“generator”创建的文件的名称。

问题是我的程序随机生成 1000 个点需要很长时间，在双核处理器的计算机上大约需要 3 分钟。我究竟做错了什么？如何优化我的代码以更快地工作？

4

2 回答 2

13

您正在使用二次算法：

project []  = error "Empty list of points"
project [_] = error "Single point is given"
project ps  = go 10000 ps
  where
    go a [_]    = a
    go a (p:ps) = let a2 = min a $ minimum [distance p q | q<-ps]
                  in a2 `seq` go a2 ps

您应该使用更好的算法。在 SO 上搜索计算几何标签以获得更好的算法。

另请参阅http://en.wikipedia.org/wiki/Closest_pair_of_points_problem。

@maxtaldykin 对算法提出d了一个不错、简单且有效的更改，这应该对随机数据产生真正的影响——按 X 坐标预先对点进行排序，并且永远不要尝试在 X 坐标中距离当前点超过单位的点（其中d是当前已知的最小距离）：

import Data.Ord (comparing)
import Data.List (sortBy)

project2 ps@(_:_:_) = go 10000 p1 t 
  where
    (p1:t) = sortBy (comparing fst) ps
    go d _         [] = d
    go d p1@(x1,_) t  = g2 d t
      where
        g2 d []          = go d (head t) (tail t)
        g2 d (p2@(x2,_):r)
           | x2-x1 >= d  = go d (head t) (tail t)
           | d2 >= d     = g2 d  r
           | otherwise   = g2 d2 r   -- change it "mid-flight"
               where
                 d2 = distance p1 p2

在随机数据上，g2将O(1)及时工作，这样整个事情go就会O(n)受到一个排序的限制，~ n log n.

~ n^2.1第一个代码（在 1k/2k 范围内）和第二个代码（在 10k/20k 范围内）的经验增长顺序显示~n^1.1，测试它快速编译加载到 GHCi 中（第二个代码运行速度比第一个代码快 50 倍） 2,000 点，3,000 点快 80 倍）。

于 2012-11-17T08:14:15.100 回答
6

可以稍微修改您的蛮力搜索以获得更好的随机数据性能。

主要思想是按 x 坐标对点进行排序，并且在比较循环中的距离时，只考虑水平距离不大于当前最小距离的点。

这可能要快一个数量级，但在最坏的情况下，它仍然是O(n^2)。
实际上，在我的机器上，在 2000 点上它快 50 倍。

project points = loop1 10000 byX
  where
    -- sort points by x coordinate
    --  (you need import Data.Ord to use `comparing`)
    byX = sortBy (comparing fst) points

    -- loop through all points from left to right
    -- threading `d` through iterations as a minimum distance so far
    loop1 d = foldl' loop2 d . tails

    -- `tail` drops leftmost points one by one so `x` is moving from left to right
    -- and `xs` contains all points to the right of `x`
    loop2 d [] = d
    loop2 d (x:xs) = let
        -- we take only those points of `xs` whose horizontal distance
        -- is not greater than current minimum distance
        xs' = takeWhile ((<=d) . distanceX x) xs
        distanceX (a,_) (b,_) = b - a

        -- then just get minimum distance from `x` to those `xs'`
      in minimum $ d : map (distance x) xs'

顺便说一句，请不要使用这么多括号。Haskell 不需要包含函数参数。

于 2012-11-17T11:34:51.743 回答