1

我有以下电影 xml 文件的结构

<movies>
 <movie>
    <genre>Drama</genre>
    <genre>Thriller</genre>
 </movie>
 ....
</movies>

这个片段不应该为每个电影标签选择每个类型的值吗？

<xsl:template match="/">
<html>
<body>
<h2>MOVIES</h2>
<table border="1">
<tr bgcolor="#9acd32">
  <th>Genre</th>
</tr>
<xsl:for-each select="movies/movie">
<tr>
  <td>
  <xsl:for-each select="movies/movie/genre">

          <xsl:value-of select="genre"/>

</xsl:for-each>
  </td>

</tr>
</xsl:for-each>
</table>
</body>
</html>
</xsl:template>

</xsl:stylesheet>

它没有显示任何输出。谁能指出错误？

4

3 回答 3

2

它不起作用，因为嵌套中的选择器xsl:for-each：外部的迭代器movies/movie，所以在内部的你已经在一个movie元素中，但是你正在选择movies/movie/genre；这意味着您正在寻找/movies/movie/movies/movie/genre. 也使用xsl:value-of了不正确的选择器。

代码应该是（未经测试）：

<xsl:for-each select="movies/movie">
<tr>
  <td>
  <!-- context element here is movie -->
  <xsl:for-each select="genre">
      <!-- context element here is genre -->
      <xsl:value-of select="."/>
      <!-- Separate genres with a comma -->
      <xsl:if test="not(position() = last())">, </xsl:if>
  </xsl:for-each>
  </td>
</tr>
</xsl:for-each>

顺便说一下（题外话），该bgcolor属性在 HTML 4 中已被弃用（很久以前）:) 您应该style改用：

<tr style="background-color: #9acd32;">
于 2012-11-16T21:33:05.543 回答
2

虽然 sierrasdetandil 的回答已经为您提供了解决您手头问题的方法，但我想提供一个替代方法，apply-templates而不是for-each：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="html" />

    <xsl:template match="/">
        <html>
            <body>
                <h2>MOVIES</h2>
                    <table>
                        <tr><th>Genre</th></tr>
                        <xsl:apply-templates />
                    </table>
            </body>
        </html>
    </xsl:template>

    <xsl:template match="movies">
        <xsl:apply-templates />
    </xsl:template>

    <xsl:template match="movie">
        <tr>
            <td>
                <xsl:apply-templates />
            </td>
        </tr>
    </xsl:template>

    <xsl:template match="genre">
        <xsl:value-of select="." />
    </xsl:template>

</xsl:stylesheet>
于 2012-11-16T21:50:59.540 回答
1

就这么简单：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="/">
  <table><xsl:apply-templates/></table>
 </xsl:template>
 <xsl:template match="movie">
     <tr>
       <xsl:apply-templates select="node()|@*"/>
     </tr>
 </xsl:template>
 <xsl:template match="genre"><td><xsl:apply-templates/></td></xsl:template>
</xsl:stylesheet>

当此转换应用于提供的 XML 文档时：

<movies>
 <movie>
    <genre>Drama</genre>
    <genre>Thriller</genre>
 </movie>
</movies>

产生了想要的正确结果：

<table>
   <tr>
      <td>Drama</td>
      <td>Thriller</td>
   </tr>
</table>
于 2012-11-17T03:09:03.637 回答