3

FastMM 将此行报告为内存泄漏的来源：

StrClassName := MidStr (curLine, length(START_OF_CLASSNAME)+1, length(curline)+1)

Copy和怎么了MidStr？这只是Delphi 2007编译器的bug，还是以后的版本也有这个问题？这是FastMM 报告副本的链接，以及我的应用程序如何显示这些类型的报告的图像。看，为了显示节点，VirtualTreeView我需要一个新的数据类型。我称之为 TMemoryLeak。当我解析报告时，我给出了我TMemoryLeak的类名、调用堆栈、它的大小等。但是当应用程序关闭并且 FastMM 启动时，上面的复制行似乎泄漏了内存。我取消分配调用堆栈的大小，整个对象，但是作为字符串的 ClassName 字段总是会占用内存。

更新（来自评论）

这是声明和构造函数和解构函数。至于生命周期 - 一旦对象用于显示节点树，就会调用对象的解构函数，之后它们就过时了，并且被释放（我希望如此）。

TMemoryLeak = class(TObject)
    private
      fID              :integer;
      fSize            :integer;
      fTotalSize       :integer;
      fCallStack       :TStringList;
      fClassName       :string;
      fRepeatedInstance:integer;


    public
      property ID               :integer      read fID                write fID;
      property TotalSize        :Integer      read fTotalSize         write fTotalSize;
      property Size             :integer      read fSize              write fSize;
      property CallStack        :TStringList  read fCallStack         write fCallStack;
      property ClassName        :string       read fClassName         write fClassName;
      property RepeatedInstance :integer      read fRepeatedInstance  write fRepeatedInstance;
      class function Equal(xA: TMemoryLeak; xB: TMemoryLeak): Boolean;
      procedure clear;
      constructor create;
      destructor destroy; override;
  end;

  TMemoryLeakList=class(TObjectList)
    private
      fSortType         :TMlSortType;
      fSortDirection    :TMLSortDirection;
      fTotalLeakSize    :integer;
      fClassName        :string;
      fRepeatedInstance :Integer;
      fID               :Integer;
      function  GetItem(Index: Integer): TMemoryLeak;
      procedure SetItem(Index: Integer; const Value: TMemoryLeak);

    public
      property Items[Index: Integer]:TMemoryLeak      read GetItem             write SetItem; default;
      property TotalLeakSize        :integer          read fTotalLeakSize      write fTotalLeakSize;
      property SortType             :TMLSortType      read fSortType           write fSortType;
      property SortDirection        :TMLSortDirection read fSortDirection      write fSortDirection;
      property ClassName            :string           read fClassName          write fClassName;
      property RepeatedInstance     :integer          read fRepeatedInstance   write fRepeatedInstance;
      property ID                   :Integer          read fID                 write fID;

      function Add(AObject: TMemoryLeak): Integer;
      procedure Clear();
      procedure Sort;

      constructor create;
      destructor destroy; override;
  end;


constructor TMemoryLeak.create;
  begin
    inherited;
    fCallStack := TStringList.create;
    fRepeatedInstance:=0;
  end;
  destructor TMemoryLeak.destroy;
  begin
    clear;
  end;
  procedure TMemoryLeak.clear;
  begin
    fCallStack.Clear;
  end;
  class function TMemoryLeak.Equal(xA, xB: TMemoryLeak): Boolean;
  var i:Integer;
  begin
    Result:=False;

    if xA.ClassName = xb.ClassName then
    begin
      if xA.size = xb.size then
      begin
        if xA.CallStack.Count = xB.CallStack.Count then
        begin
          for i := 0 to xa.CallStack.Count - 1 do
          begin
            if CompareStr(xA.CallStack[i], xB.CallStack[i]) <> 0 then
            begin
             break;
            end;
          end;
          if i = xa.CallStack.Count then
            Result:=True;
        end
      end
    end

  end;

  { TMemoryLeakList }

  constructor TMemoryLeakList.create;
  begin
    inherited;
    fSortType         :=stID;
    fSortDirection    :=sdAsc;
    fClassName        :='';
    fRepeatedInstance :=0;
  end;
  destructor TMemoryLeakList.destroy;
  begin
    Clear;
  end;
  procedure TMemoryLeakList.Clear;
  var i : Integer;
  begin
      for i := 0 to Count - 1 do
        Items[i].clear;
  end;
4

1 回答 1

11

有道理的解释是你有内存泄漏。

我认为您对 FastMM 泄漏报告的工作方式有误解。您似乎从泄漏报告中推断出Copy，MidStr等是造成泄漏的原因。事实并非如此。当内存被分配但随后没有被释放时会报告泄漏。对于 和 之类的函数Copy，MidStr它们的工作是创建新字符串，这自然会涉及内存分配。报告泄漏是因为为保存字符串缓冲区而创建的内存未释放。当其余代码未能释放该内存时，分配功能不是Copyor的错。MidStr

Delphi 2007 是一个成熟的产品，已知字符串的内存管理是正确的。也许你做了一些绕过字符串引用计数的手动内存复制。nil您是否通过调用来设置一些变量/字段FillChar？FreeMem您是否使用而不是处理记录Dispose？前者不会减少字符串引用计数。像这样的事情是泄漏的可能原因。

查看您发布的代码的摘录，这是一个问题：

destructor TMemoryLeakList.destroy;
begin
  Clear;
end;

您未能调用继承的析构函数。这意味着列表的成员不会被破坏。这就解释了为什么你的字符串没有被破坏。

事实上，您不需要为列表类提供析构函数。只需删除它并让继承的TObjectList析构函数完成工作。由于OwnsObjects默认为True，因此列表中的任何成员在从列表中删除以及列表本身被销毁时都会被销毁。

如果您的Clear方法实际上清除了列表，那么就会发生这种情况。但你Clear的不是真实的Clear。容器中的实数Clear预计会移除所有成员。您应该删除Clear并依赖继承的版本。

在TMemoryLeak中，您也无法调用继承的析构函数。并且也无法销毁该类拥有的字符串列表实例。

总而言之，我会像这样编写这些构造函数和析构函数：

constructor TMemoryLeak.Create;
begin
  inherited;
  fCallStack := TStringList.Create;
end;

destructor TMemoryLeak.Destroy;
begin
  fCallStack.Free;
  inherited;
end;

constructor TMemoryLeakList.Create;
begin
  inherited;//by default OwnsObjects is set to True, list manages member lifetime
  fSortType :=stID;
  fSortDirection :=sdAsc;
end;

然后删除destructor, 并删除Clear方法。继承自的版本TObjectList就足够了。

在您声明的评论中：

一旦对象用于显示节点树，就会调用对象的析构函数。之后它们就过时了，并被释放（我希望如此）。

我会说这很有可能没有帮助。由于您在模式下创建了对象列表OwnsObjects，因此您根本不应该破坏列表的成员。您已经要求列表本身执行此操作。你们两个都做不到。而“我希望”的评论并没有让我对这段代码是正确的充满信心。

由于我们看不到您的所有代码，因此我无法确定这就是它的全部问题。

底线是您的代码有泄漏。相信 FastMM！

于 2012-11-14T13:54:14.403 回答