4

我正在尝试创建一个 Haskell 程序，该程序在屏幕上绘制一些简单的 2d 形状，但是当您将鼠标悬停在每个形状上时，它会打印创建形状的源代码行。

为了做到这一点，我希望能够创建带有尺寸参数和指示行号的最终参数的形状。像这样的东西：

rect1 = Shape(Rectangle 2 2 lineNumber)

这将创建一个宽度为 2 像素、高度为 2 像素的矩形，并使用函数 lineNumber 来存储编写这段代码的行。Haskell中是否存在这样的功能？创建一个简单吗？

我搜索了堆栈溢出并发现了这个问题，其中回答者建议可以使用 C++ 中的 __LINE__ pragma 来实现类似的效果。这是最好的方法还是有办法在纯 Haskell 中做到这一点？

4

1 回答 1

6

您可以使用 Template Haskell 来做到这一点，它在技术上是另一个 GHC 扩展，但可能在某种程度上比 C 预处理器更“纯”。

代码从这里窃取并稍作修改。

{-# LANGUAGE TemplateHaskell #-}

module WithLocation (withLocation) where
import Language.Haskell.TH

withLocation' :: String -> IO a -> IO a
withLocation' s f = do { putStrLn s ; f }

withLocation :: Q Exp
withLocation = withFileLine [| withLocation' |]

withFileLine :: Q Exp -> Q Exp
withFileLine f = do
    let loc = fileLine =<< location
    appE f loc

fileLine :: Loc -> Q Exp
fileLine loc = do
    let floc = formatLoc loc
    [| $(litE $ stringL floc) |]

formatLoc :: Loc -> String
formatLoc loc = let file = loc_filename loc
                    (line, col) = loc_start loc
                in concat [file, ":", show line, ":", show col]

像这样使用它（来自另一个模块）：

{-# LANGUAGE TemplateHaskell #-}

module Main where
import WithLocation

main = do
  $withLocation $ putStrLn "===oo0=Ü=0oo=== Kilroy was here"
于 2012-11-15T22:14:16.947 回答