-2

我必须生成 XML 输出。它应该显示数组，如下所示。我无法以正确的方式呈现数组。

输入 XML：

<accounts>
    <displayOrdinal>0</displayOrdinal>
    <name>String</name>
    <account>
        <accountNumber>String</accountNumber>
        <name>String</name>
        <balance>
            <balanceAmount>0.0</balanceAmount>
        </balance>
        <balance>
            <balanceAmount>0.0</balanceAmount>
        </balance>
        <properties>
            <displayOrdinal>0</displayOrdinal>
        </properties>
        <properties>
            <displayOrdinal>0</displayOrdinal>
        </properties>
        <usage>
            <type>String</type>
        </usage>
        <usage>
            <type>String</type>
        </usage>
    </account>
    <account>
        <accountNumber>String</accountNumber>
        <name>String</name>
        <balance>
            <balanceAmount>0.0</balanceAmount>
        </balance>
        <balance>
            <balanceAmount>0.0</balanceAmount>
        </balance>
        <properties>
            <displayOrdinal>0</displayOrdinal>
        </properties>
        <properties>
            <displayOrdinal>0</displayOrdinal>
        </properties>
        <usage>
            <type>String</type>
        </usage>
        <usage>
            <type>String</type>
        </usage>
    </account>
</accounts>

我的预期输出应如下所示：

<json:object xmlns:json="http://www.ibm.com/xmlns/prod/2009/jsonx">
    <json:object name="accounts">
        <json:string name="displayOrdinal">0</json:string>
        <json:string name="name">String</json:string>
        <json:array name="account">
            <json:object>
                <json:string name="accountNumber">String</json:string>
                <json:string name="name">String</json:string>
                <json:array name="balance">
                    <json:object>
                        <json:string name="balanceAmount">0.0</json:string>
                    </json:object>
                    <json:object>
                        <json:string name="balanceAmount">0.0</json:string>
                    </json:object>
                </json:array>
                <json:array name="properties">
                    <json:object>
                        <json:string name="displayOrdinal">0</json:string>
                    </json:object>
                    <json:object>
                        <json:string name="displayOrdinal">0</json:string>
                    </json:object>
                </json:array>
                <json:array name="usage">
                    <json:object>
                        <json:string name="type">String</json:string>
                    </json:object>
                    <json:object name="usage">
                        <json:string name="type">String</json:string>
                    </json:object>
                </json:array>
            </json:object>
            <json:object>
                <json:string name="accountNumber">String</json:string>
                <json:string name="name">String</json:string>
                <json:object name="balance">
                    <json:string name="balanceAmount">0.0</json:string>
                </json:object>
                <json:array name="balance">
                    <json:object>
                        <json:string name="balanceAmount">0.0</json:string>
                    </json:object>
                    <json:object>
                        <json:string name="displayOrdinal">0</json:string>
                    </json:object>
                    <json:object>
                        <json:string name="displayOrdinal">0</json:string>
                    </json:object>
                </json:array>
                <json:array name="usage">
                    <json:object>
                        <json:string name="type">String</json:string>
                    </json:object>
                    <json:object>
                        <json:string name="type">String</json:string>
                    </json:object>
                </json:array>
            </json:object>
        </json:array>
    </json:object>
</json:object>

我使用的 XSL 如下：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:json="http://www.ibm.com/xmlns/prod/2009/jsonx">
    <xsl:output method="xml" indent="yes" encoding="UTF-8" omit-xml-declaration="yes"/>
    <xsl:strip-space elements="*"/>
    <!-- Array -->
    <xsl:template match="*[*[2]][name(*[1])=name(*[2])]">
        <json:object name="{name()}">
            <json:array name="{name(*[1])}">
                <xsl:apply-templates/>
            </json:array>
        </json:object>
    </xsl:template>
    <!-- Array member -->
    <xsl:template match="*[parent::*[ name(*[1])=name(*[2]) ]] | /">
        <json:object>
            <xsl:apply-templates/>
        </json:object>
    </xsl:template>
    <!-- Object -->
    <xsl:template match="*">
        <xsl:choose>
            <xsl:when test="text()">
                <json:string name="{name()}">
                    <xsl:value-of select="."/>
                </json:string>
            </xsl:when>
            <xsl:otherwise>
                <json:object name="{name()}">
                    <xsl:apply-templates/>
                </json:object>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
    <!-- String -->
    <xsl:template match="*[not(*)]">
        <xsl:choose>
            <xsl:when test="not(boolean(text()))">
                <xsl:element name="json:null">
                    <xsl:attribute name="name"><xsl:value-of select="name()"/></xsl:attribute>
                </xsl:element>
            </xsl:when>
            <xsl:otherwise>
                <xsl:choose>
                    <xsl:when test="text()= 'false' or text()='true'">
                        <xsl:element name="json:boolean">
                            <xsl:attribute name="name"><xsl:value-of select="name()"/></xsl:attribute>
                            <xsl:value-of select="text()"/>
                        </xsl:element>
                    </xsl:when>
                    <xsl:otherwise>
                        <json:string name="{name()}">
                            <xsl:if test="@*">
                                <xsl:attribute name="{name(@*)}"><xsl:value-of select="@*"/></xsl:attribute>
                            </xsl:if>
                            <xsl:value-of select="."/>
                        </json:string>
                    </xsl:otherwise>
                </xsl:choose>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet>
4

2 回答 2

0

恭喜蒂姆第一个正确的解决方案。

我的解决方案并没有更好，但我将其作为一个感兴趣的问题提出。它产生与 Tim 相同的输出，而且我已经合并了 OP 的原始解决方案尝试建议的 null 和 boolean 类型。

<xsl:stylesheet version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  xmlns:json="http://www.ibm.com/xmlns/prod/2009/jsonx"
  exclude-result-prefixes="xsl xs">
<xsl:output indent="yes" encoding="UTF-8" omit-xml-declaration="yes" />
<xsl:strip-space elements="*" /> 

<xsl:template match="/" name="nameless-object">
  <json:object>
    <xsl:apply-templates />    
  </json:object>
</xsl:template>

<!-- Array -->
<xsl:template match="*
  [     following-sibling::*[1][name()=name(preceding-sibling::*[1])] ]
  [not( preceding-sibling::*[1][name()=name(following-sibling::*[1])])]">
  <xsl:variable name="array-name" select="name()" />  
  <xsl:variable name="followers" select="
    (.|following-sibling::*)[name()=$array-name]" />
  <xsl:variable name="stop" select="
     (following-sibling::*[name()!=$array-name][1] |
      ../*[last()])[1]" />
  <xsl:variable name="preceders" select="
    ($stop| $stop/preceding-sibling::*)[name()=$array-name]" />
  <xsl:variable name="members" select="
      $preceders[count(.|$followers)=count($followers)]" />
  <json:array name="{$array-name}">
    <xsl:for-each select="$members">
      <xsl:call-template name="nameless-object" />
    </xsl:for-each>  
  </json:array>
</xsl:template>

<xsl:template match="*
    [preceding-sibling::*[1][name()=name(following-sibling::*[1])] ]" />

<!-- Object -->  
<xsl:template match="*">
  <json:object name="{name()}">
    <xsl:apply-templates />
  </json:object>
</xsl:template>

<!-- String -->
<xsl:template match="*[not(*)]">
  <json:string name="{name()}">
    <xsl:value-of select="." />
  </json:string>
</xsl:template>

<!-- Null -->
<xsl:template match="*[not(*)][.='']">
  <json:null name="{name()}" />
</xsl:template>

<!-- Boolean -->
<xsl:template match="*[not(*)][.='true' or .='false']">
  <json:boolean name="{name()}">
    <xsl:value-of select="." />
  </json:boolean>
</xsl:template>

</xsl:stylesheet>
于 2012-11-15T12:47:45.443 回答
0

我认为您将需要一些模板。首先，对于数组元素，您需要匹配具有不同前面兄弟但匹配命名的后面兄弟的元素（即它们是数组的第一个元素）

<xsl:template 
      match="*
         [local-name() != local-name(preceding-sibling::*[1])]
         [local-name() = local-name(following-sibling::*[1])]" priority="2">
   <json:array name="{local-name()}">
      <xsl:apply-templates select="self::*" mode="array" />
   </json:array>
</xsl:template>

此处使用优先级是因为在最终的 XSLT 中，将有两个模板可能匹配相同的元素，并且需要首先选择一个数组。

然后，您可以通过将元素输出为 json 对象来处理数组中的元素，然后匹配以下同级，但前提是它具有名称 name。

<xsl:template match="*" mode="array">
   <json:object>
      <xsl:apply-templates />
   </json:object>
   <xsl:apply-templates select="following-sibling::*[1][local-name() = local-name(current())]" mode="array" />
</xsl:template>

还需要一个模板来阻止数组中的元素独立于数组处理进行匹配，以免输出两次。

<xsl:template match="*[local-name() = local-name(preceding-sibling::*[1])]" />

需要的其他模板将是一个用于字符串元素的模板，它们是没有子元素的元素

<xsl:template match="*[not(*)]" priority="1">
   <json:string name="{local-name()}">
      <xsl:value-of select="." />
   </json:string>      
</xsl:template>

最后一个匹配其他元素，这些元素将作为对象输出。

<xsl:template match="*">
   <json:object name="{local-name()}">
      <xsl:apply-templates />
   </json:object>      
</xsl:template>

这是完整的 XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:json="http://www.ibm.com/xmlns/prod/2009/jsonx">
   <xsl:output method="xml" indent="yes"/>

   <xsl:template match="/">
      <json:object xmlns:json="http://www.ibm.com/xmlns/prod/2009/jsonx">
         <xsl:apply-templates />
      </json:object>
   </xsl:template>

   <xsl:template match="*[local-name() != local-name(preceding-sibling::*[1])][local-name() = local-name(following-sibling::*[1])]" priority="2">
      <json:array name="{local-name()}">
         <xsl:apply-templates select="self::*" mode="array" />
      </json:array>
   </xsl:template>

   <xsl:template match="*" mode="array">
      <json:object>
         <xsl:apply-templates />
      </json:object>
      <xsl:apply-templates select="following-sibling::*[1][local-name() = local-name(current())]" mode="array" />
   </xsl:template>

   <xsl:template match="*[local-name() = local-name(preceding-sibling::*[1])]" />

   <xsl:template match="*[not(*)]" priority="1">
      <json:string name="{local-name()}">
         <xsl:value-of select="." />
      </json:string>      
   </xsl:template>   

   <xsl:template match="*">
      <json:object name="{local-name()}">
         <xsl:apply-templates />
      </json:object>      
   </xsl:template>

   <xsl:template match="@*|node()[not(self::*)]">
      <xsl:copy>
         <xsl:apply-templates select="@*|node()"/>
      </xsl:copy>
   </xsl:template>
</xsl:stylesheet>

当应用于您的 XML 时，将输出以下内容

<json:object xmlns:json="http://www.ibm.com/xmlns/prod/2009/jsonx">
   <json:object name="accounts">
      <json:string name="displayOrdinal">0</json:string>
      <json:string name="name">String</json:string>
      <json:array name="account">
         <json:object>
            <json:string name="accountNumber">String</json:string>
            <json:string name="name">String</json:string>
            <json:array name="balance">
               <json:object>
                  <json:string name="balanceAmount">0.0</json:string>
               </json:object>
               <json:object>
                  <json:string name="balanceAmount">0.0</json:string>
               </json:object>
            </json:array>
            <json:array name="properties">
               <json:object>
                  <json:string name="displayOrdinal">0</json:string>
               </json:object>
               <json:object>
                  <json:string name="displayOrdinal">0</json:string>
               </json:object>
            </json:array>
            <json:array name="usage">
               <json:object>
                  <json:string name="type">String</json:string>
               </json:object>
               <json:object>
                  <json:string name="type">String</json:string>
               </json:object>
            </json:array>
         </json:object>
         <json:object>
            <json:string name="accountNumber">String</json:string>
            <json:string name="name">String</json:string>
            <json:array name="balance">
               <json:object>
                  <json:string name="balanceAmount">0.0</json:string>
               </json:object>
               <json:object>
                  <json:string name="balanceAmount">0.0</json:string>
               </json:object>
            </json:array>
            <json:array name="properties">
               <json:object>
                  <json:string name="displayOrdinal">0</json:string>
               </json:object>
               <json:object>
                  <json:string name="displayOrdinal">0</json:string>
               </json:object>
            </json:array>
            <json:array name="usage">
               <json:object>
                  <json:string name="type">String</json:string>
               </json:object>
               <json:object>
                  <json:string name="type">String</json:string>
               </json:object>
            </json:array>
         </json:object>
      </json:array>
   </json:object>
</json:object>
于 2012-11-15T08:46:57.860 回答