4

有人知道如何按长度对数字进行排序吗？

例如：（11,111,122,12,2,13,21,15,211,22,213,2004）

我希望排序后的数组是：

11
12
13
15
111
122
2
21
22
213
2004年
4

4 回答 4

6

所需的输出似乎表明您不只是想按位数排序，而是先按第一个数字排序，然后按长度排序。

您显示的所需输出省略了211，所以我只是根据我的理解将它放在它所属的位置。

#!/usr/bin/env perl

use strict;
use warnings;

use Test::More;

my @source = (11, 111, 122, 12, 2, 13, 21, 15, 211, 22, 213, 2004);
my @desired = (11, 12, 13, 15, 111, 122, 2, 21, 22, 211, 213, 2004);

my @sorted =sort {
    substr($a, 0, 1) <=> substr($b, 0, 1) ||
    length($a) <=> length($b) || 
    $a <=> $b # thanks @ikegami
} @source;

is_deeply(\@sorted, \@desired, 'Sorted and desired are the same');
于 2012-11-14T04:10:19.757 回答
2 
my @sorted =
   sort { substr($a,0,1) <=> substr($b,0,1) || $a <=> $b }
    @unsorted;

给出您要求的订单。或者，也许你想要

my @sorted =
   sort {  substr($a,0,1) <=> substr($b,0,1)
        || length($a) <=> length($b)
        || $a <=> $b }
   @unsorted;

如果211您提供的输出中没有遗漏，我可以告诉您您想要哪一个。

于 2012-11-14T04:24:48.620 回答
2

考虑一个所谓的Schwartzian 变换，它通过临时将排序键与输入项关联来避免重新计算排序键：

my @sorted =
    map { $_->[0] }
    sort { $a->[1] cmp $b->[1] or $a->[0] <=> $b->[0] }
    map { [ $_ => sprintf "%.1s%08x", $_, length ] }
    @source;
于 2012-11-14T12:22:16.290 回答
1

这是由List::UtilsBy::sort_by

use List::UtilsBy qw( sort_by );

my @sorted = sort_by { sprintf "%.1s%08x", $_, length } @source;

它与其他人建议的 Schwartzian Transform 解决方案大致相同，但包含在一个简洁的抽象中。

于 2012-11-15T12:14:52.857 回答