1

我需要让多个远程管理员在现场测试他们的下载速度。Speedtest.net 等并不是我们 WAN 中性能的真正指标。我不想使用 iperf，因为我需要尽量减少远程管理员的技术知识和工作量。我也不希望他们安装任何东西。因此我需要一个简单的批处理文件来下载一个测试文件 5 次。这是我到目前为止所拥有的：

@echo off
rem localize variables to this script
setlocal
rem delete the test file if it already exists
if exist %HomePath%\Downloads\100meg.test del %HomePath%\Downloads\100meg.test
rem perform the test 5 times
for /l %%i IN (1,1,5) DO (
    rem mark the start time
    set STARTTIME=%TIME%
    echo Download started at:%STARTTIME%
    rem start download
    C:\windows\explorer.exe http://mirror.internode.on.net/pub/test/100meg.test
    rem check for file download completion
    :while
        if exist %HomePath%\Downloads\100meg.test goto wend
        goto while
    :wend
    rem mark the end time
    set ENDTIME=%TIME%
    echo Download completed at:%ENDTIME%
    rem convert STARTTIME and ENDTIME to centiseconds
    set /A STARTTIME=(1%STARTTIME:~0,2%-100)*360000 + (1%STARTTIME:~3,2%-100)*6000 + (1%STARTTIME:~6,2%-100)*100 + (1%STARTTIME:~9,2%-100)
    set /A ENDTIME=(1%ENDTIME:~0,2%-100)*360000 + (1%ENDTIME:~3,2%-100)*6000 + (1%ENDTIME:~6,2%-100)*100 + (1%ENDTIME:~9,2%-100)
    rem calculate the time taken in seconds
    set /A DURATION=(%ENDTIME%-%STARTTIME%)/100
    echo Download took:%DURATION% seconds
    rem delete the test file ready for next iteration
    del %HomePath%\Downloads\100meg.test
)

问题是，由于添加了 for 并将块括在其括号中，它就停止了工作。任何人都可以解释为什么这会失败吗？

谢谢！

4

1 回答 1

3

在 FOR 循环中使用 GOTO 总是会中断循环 - 一旦使用 GOTO，剩余的迭代将不会发生。

这是因为 CMD.EXE 的工作方式。括号内的整个命令块被一次性解析并加载到内存中。每次迭代都会执行存储在内存中的已解析命令。这些解析的命令不包含任何标签。GOTO 必须扫描文件，这需要中断循环。

STARTTIME 的“消失”值也与一次解析整个块的事实有关。%STARTTIME%在解析时扩展，但在执行任何块之前解析命令。因此，您将获得执行 FOR 命令之前存在的值，这可能是未定义的。有一个称为延迟扩展的功能，可用于在执行时而不是解析时获取变量的值。在命令提示符下键入HELP SET并阅读从文档大约一半开始的关于延迟扩展的部分。

但是有一种简单的方法可以让您的代码工作 - 只需将 DO 块的内容移动到子例程，然后在循环中调用例程。（我假设您在 DO 子句中的逻辑是正确的）。CALL 不会中断循环:-)

您必须记住在您的例程标签之前放置一个 EXIT /B，以便您的主代码不会落入子例程。

@echo off
rem localize variables to this script
setlocal
rem delete the test file if it already exists
if exist %HomePath%\Downloads\100meg.test del %HomePath%\Downloads\100meg.test
rem perform the test 5 times
for /l %%i IN (1,1,5) do call :downloadTest
exit /b

:downloadTest
rem mark the start time
set STARTTIME=%TIME%
echo Download started at:%STARTTIME%
rem start download
C:\windows\explorer.exe http://mirror.internode.on.net/pub/test/100meg.test
rem check for file download completion
:while
  if exist %HomePath%\Downloads\100meg.test goto wend
  goto while
:wend
rem mark the end time
set ENDTIME=%TIME%
echo Download completed at:%ENDTIME%
rem convert STARTTIME and ENDTIME to centiseconds
set /A STARTTIME=(1%STARTTIME:~0,2%-100)*360000 + (1%STARTTIME:~3,2%-100)*6000 + (1%STARTTIME:~6,2%-100)*100 + (1%STARTTIME:~9,2%-100)
set /A ENDTIME=(1%ENDTIME:~0,2%-100)*360000 + (1%ENDTIME:~3,2%-100)*6000 + (1%ENDTIME:~6,2%-100)*100 + (1%ENDTIME:~9,2%-100)
rem calculate the time taken in seconds
set /A DURATION=(%ENDTIME%-%STARTTIME%)/100
echo Download took:%DURATION% seconds
rem delete the test file ready for next iteration
del %HomePath%\Downloads\100meg.test
exit /b
于 2012-11-14T01:34:07.513 回答