sql-server - T-SQL根据特定坐标计算1.0的经度值

Question

正如我在这里显示的那样，当我们移动到两极时，经度一度的值（多少公里）会减小。我需要一种算法来计算一个经度对于给定点（经度和纬度）的当前公里。

预先感谢。

Answer 1

这实际上比你想象的要难，但谷歌会帮助解决棘手的问题。

但是，基本上你可以使用这个的一些变体：

declare @radius as float;
declare @latitude as float;
declare @circumference float;

set @radius = 6378 -- in km
set @latitude = 0 -- 0 = equator : 90 = pole

set @circumference = 2 * pi() * @radius * cos(radians(@latitude))

select @circumference
select (@circumference / 360) as km
select (@circumference / 360) / 1.609344 as miles

我提到的棘手部分是地球不是几何球体，也不是完全平坦的事实——但上述内容非常大致正确，例如，您可以使用更准确的半径。

编辑：

或者，如果您有 SQL 2008（或更高版本），则可以使用“geography”数据类型和 STDistance() 函数。

declare @p1 geography = geography::STPointFromText('POINT(1 ' + cast(@latitude as varchar(10))+')', 4326)
declare @p2 geography = geography::STPointFromText('POINT(2 ' + cast(@latitude as varchar(10))+')', 4326)

SELECT @p1.STDistance(@p2); -- this is in metres

在上面的例子中，它找到了同一纬度的两点之间的距离，但在经度为 1° 和经度为 2° 时。

Answer 2

为了计算特定地理点的经纬度长度是多少米，我使用以下算法：

-- Geograpic Point Cordinates
DECLARE @LATTIDUDE REAL=45
DECLARE @LONGITUDE REAL=45
DECLARE @Distance REAL=10

-- Constants
DECLARE @ConvertionConstant AS FLOAT=2*PI()/360
DECLARE @MetersPerDegree AS FLOAT

DECLARE @LattidueInRadians AS FLOAT=@ConvertionConstant*@LATTIDUDE

DECLARE @LongitudeParameter1 AS FLOAT=111412.84
DECLARE @LongitudeParameter2 AS FLOAT=-93.5 
DECLARE @LongitudeParameter3 AS FLOAT=0.118

SET @MetersPerDegree=(@LongitudeParameter1*COS(@LattidueInRadians))+(@LongitudeParameter2*(COS(3*@LattidueInRadians)))+(@LongitudeParameter3*COS(5*@LattidueInRadians))
DECLARE @LongitudeRangeTemp AS FLOAT=@Distance/(@MetersPerDegree/1000)

-- Results for longitude
SELECT @LongitudeRangeTemp AS DegreesForGivenKM
SELECT @MetersPerDegree    AS MetersPerDegreeOfLongitude

-- Constants
DECLARE @LatitudeParameter1 AS FLOAT=111132.92
DECLARE @LatitudeParameter2 AS FLOAT=-559.82
DECLARE @LatitudeParameter3 AS FLOAT=1.175
DECLARE @LatitudeParameter4 AS FLOAT=-0.0023

-- Results for longitude
SET @MetersPerDegree=(@LatitudeParameter1+(@LatitudeParameter2*COS(2*@LattidueInRadians))+(@LatitudeParameter3*COS(4*@LattidueInRadians))+(@LatitudeParameter4*COS(6*@LattidueInRadians)))
DECLARE @LatitudeRangeTemp AS FLOAT=@Distance/(@MetersPerDegree/1000)
SELECT @LatitudeRangeTemp AS  DegreesForGivenKM
SELECT @MetersPerDegree   AS  MetersPerDegreeOfLatitude

为公里添加了一个附加参数 - 代码将计算多少度等于给定的公里。

您可以自由地在函数中实现代码。