4

我有一些包含十六进制字符串变体的字符串（如果有人愿意的话，来源是 framemaker）。因此，字符串可能看起来像

这是一些带有一些十六进制代码\x27 s 的句子，我们需要修复它。

并且需要更改为

这是一些带有一些十六进制代码的句子，我们需要修复它。

实际上，单个字符串中可能有其中一些，因此我正在寻找遍历文本、捕获所有十六进制代码（看起来像 \x## ）并用正确的字符替换所有这些代码的最佳方法. 我制作了一个包含所有字符的 xml 列表/查找表，如下所示：

<xsl:param name="reflist">
    <Code Value="\x27">'</Code>
<Code Value="\x28">(</Code>
<Code Value="\x29">)</Code>
<Code Value="\x2a">*</Code>
<Code Value="\x2b">+</Code>
    <!-- much more like these... -->
</xsl:param>

现在我使用了一个简单的替换参数，但是字符太多，无法使用。

最好的方法是什么？

4

2 回答 2

5

可以完全避免使用任何“参考表”——像这样：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema"
 xmlns:my="my:my" exclude-result-prefixes="my xs">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="text()[matches(.,  '\\x(\d|[a-f])+')]">
   <xsl:analyze-string select="." regex="\\x(\d|[a-f])+" >
     <xsl:matching-substring>
       <xsl:value-of select=
       "codepoints-to-string(my:hex2dec(substring(.,3), 0))"/>
     </xsl:matching-substring>
     <xsl:non-matching-substring>
      <xsl:value-of select="."/>
     </xsl:non-matching-substring>
   </xsl:analyze-string>
 </xsl:template>

 <xsl:function name="my:hex2dec" as="xs:integer">
  <xsl:param name="pStr" as="xs:string"/>
  <xsl:param name="pAccum" as="xs:integer"/>

  <xsl:sequence select=
   "if(not($pStr))
     then $pAccum
     else
      for $char in substring($pStr, 1, 1),
          $code in
            if($char ge '0' and $char le '9')
              then xs:integer($char)
              else
                string-to-codepoints($char) - string-to-codepoints('a') +10
       return
          my:hex2dec(substring($pStr,2), 16*$pAccum + $code)
   "/>
 </xsl:function>
</xsl:stylesheet>

当此转换应用于以下 XML 文档时：

<t>
 <p>this is some sentence with some hex code\x27 s ,
    and we need that fixed.</p>
 <p>this is some sentence with some hex code\x28 s ,
    and we need that fixed.</p>
 <p>this is some sentence with some hex code\x29 s ,
    and we need that fixed.</p>
 <p>this is some sentence with some hex code\x2a s ,
    and we need that fixed.</p>
 <p>this is some sentence with some hex code\x2b s ,
    and we need that fixed.</p>
 <p>this is some sentence with some hex code\x2c s ,
    and we need that fixed.</p>
 <p>this is some sentence with some hex code\x2d s ,
    and we need that fixed.</p>
 <p>this is some sentence with some hex code\x2e s ,
    and we need that fixed.</p>
 <p>this is some sentence with some hex code\x2f s ,
    and we need that fixed.</p>
</t>

产生了想要的正确结果：

<t>
   <p>this is some sentence with some hex code' s ,
    and we need that fixed.</p>
   <p>this is some sentence with some hex code( s ,
    and we need that fixed.</p>
   <p>this is some sentence with some hex code) s ,
    and we need that fixed.</p>
   <p>this is some sentence with some hex code* s ,
    and we need that fixed.</p>
   <p>this is some sentence with some hex code+ s ,
    and we need that fixed.</p>
   <p>this is some sentence with some hex code, s ,
    and we need that fixed.</p>
   <p>this is some sentence with some hex code- s ,
    and we need that fixed.</p>
   <p>this is some sentence with some hex code. s ,
    and we need that fixed.</p>
   <p>this is some sentence with some hex code/ s ,
    and we need that fixed.</p>
</t>

请注意：

这种转换是通用的，可以正确处理任何十六进制 unicode 代码。

例如，如果在此 XML 文档上应用相同的转换：

<t>
 <p>this is some sentence with some hex code\x0428\x0438\x0448 s ,
    and we need that fixed.</p>
</t>

产生了正确的结果（包含保加利亚语中“烤架”的西里尔字母）：

<t>
   <p>this is some sentence with some hex codeШиш s ,
    and we need that fixed.</p>
</t>
于 2012-11-10T05:18:06.860 回答
3

使用analyze-string如

<xsl:template match="text()">
  <xsl:analyze-string select="." regex="\\x[0-9a-f]{{2}}" flags="i">
    <xsl:matching-substring>
      <xsl:value-of select="$reflist/Code[@Value = .]"/>
    </xsl:matching-substring>
    <xsl:non-matching-substring>
      <xsl:value-of select="."/>
    </xsl:non-matching-substring>
  </xsl:analyze-string>
</xsl:template>

我还建议使用密钥，例如

<xsl:param name="reflist" as="document-node()">
  <xsl:document>
    <Root>
      <Code Value="\x27">'</Code>
      <Code Value="\x28">(</Code>
      <Code Value="\x29">)</Code>
      <Code Value="\x2a">*</Code>
      <Code Value="\x2b">+</Code>
      <!-- much more like these... -->
    </Root>
  </xsl:document>
</xsl:param>

<xsl:key name="code-by-value" match="Code" use="@Value"/>

那么查找可以改进为

<xsl:template match="text/text()">
  <xsl:analyze-string select="." regex="\\x[0-9a-f]{{2}}" flags="i">
    <xsl:matching-substring>
      <xsl:value-of select="key('code-by-value', ., $reflist)"/>
    </xsl:matching-substring>
    <xsl:non-matching-substring>
      <xsl:value-of select="."/>
    </xsl:non-matching-substring>
  </xsl:analyze-string>
</xsl:template>

我找到了一些时间将提出的建议转化为工作代码，输入为

<root>
  <text>this is some sentence with some hex code\x27 s , and we need that \x28and this\x29 fixed.</text>
</root>

完整的样式表是

<xsl:stylesheet 
  version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  exclude-result-prefixes="xs">

<xsl:param name="reflist" as="document-node()">
  <xsl:document>
    <Root>
      <Code Value="\x27">'</Code>
      <Code Value="\x28">(</Code>
      <Code Value="\x29">)</Code>
      <Code Value="\x2a">*</Code>
      <Code Value="\x2b">+</Code>
      <!-- much more like these... -->
    </Root>
  </xsl:document>
</xsl:param>

<xsl:key name="code-by-value" match="Code" use="@Value"/>

<xsl:template match="@* | node()">
  <xsl:copy>
    <xsl:apply-templates select="@* , node()"/>
  </xsl:copy>
</xsl:template>

<xsl:template match="text/text()">
  <xsl:analyze-string select="." regex="\\x[0-9a-f]{{2}}" flags="i">
    <xsl:matching-substring>
      <xsl:value-of select="key('code-by-value', ., $reflist)"/>
    </xsl:matching-substring>
    <xsl:non-matching-substring>
      <xsl:value-of select="."/>
    </xsl:non-matching-substring>
  </xsl:analyze-string>
</xsl:template>

</xsl:stylesheet>

Saxon 9.4 将输入转换如下：

<root>
  <text>this is some sentence with some hex code' s , and we need that (and this) fixed.</text>
</root>
于 2012-11-09T15:15:02.773 回答