18

对于一个项目，我构建了一个 C 库并使用 CMake 隐含 Python 绑定（通过 GObject 自省）。我还想使用 distutils 分发一些 Python 辅助模块。我可以用这个构建和安装模块CMakeLists.txt

find_program(PYTHON "python")

if (PYTHON)
    set(SETUP_PY_IN "${CMAKE_CURRENT_SOURCE_DIR}/setup.py.in")
    set(SETUP_PY    "${CMAKE_CURRENT_BINARY_DIR}/setup.py")
    set(DEPS        "${CMAKE_CURRENT_SOURCE_DIR}/module/__init__.py")
    set(OUTPUT      "${CMAKE_CURRENT_BINARY_DIR}/build")

    configure_file(${SETUP_PY_IN} ${SETUP_PY})

    add_custom_command(OUTPUT ${OUTPUT}
                       COMMAND ${PYTHON}
                       ARGS setup.py build
                       DEPENDS ${DEPS})

    add_custom_target(target ALL DEPENDS ${OUTPUT})

    install(CODE "execute_process(COMMAND ${PYTHON} ${SETUP_PY} install)")
endif()

以及以下内容setup.py.in：

from distutils.core import setup, Extension

if __name__ == '__main__':
    setup(name='foo',
          version='${PACKAGE_VERSION}',
          package_dir={ '': '${CMAKE_CURRENT_SOURCE_DIR}' },
          packages=['module'])

不幸的是，每次运行时都会执行构建步骤make。我想，问题与自定义命令的输出有关，该命令是目录而不是文件。现在，有没有办法告诉 CMakepython setup.py build仅在setup.py.in或其中一个源发生更改时运行？

4

1 回答 1

10

只有文件，而不是目录，可以可靠地用作 OUTPUT 和 DEPENDS。您可以修改自定义命令以生成时间戳文件，如下所示：

add_custom_command(
  OUTPUT ${OUTPUT}/timestamp
  COMMAND ${PYTHON} setup.py build
  COMMAND ${CMAKE_COMMAND} -E touch ${OUTPUT}/timestamp
  DEPENDS ${DEPS}
)

add_custom_target(target ALL DEPENDS ${OUTPUT}/timestamp)
于 2012-11-09T10:13:05.987 回答