0

我想使用 GUID 来唯一标识我的应用程序并从代码中获取此值。我看到 DPROJ 中有一个非常理想的 GUID：

<Project xmlns="http://schemas.microsoft.com/developer/msbuild/2003">
    <PropertyGroup>
        <ProjectGuid>{D4DB842C-FB4C-481B-8952-77DA04E37102}</ProjectGuid>

这是否会在任何地方进入 exe，例如作为资源？如果不是，那么将此 GUID 值链接到我的 exe 文件并在代码中读取它的最简洁方法是什么。上面的 GUID 位于一个专用的文本文件中，并使用我的DprojMaker 工具粘贴到 DPROJ 中，因此我可以将它包含在您可能建议的任何内容中。谢谢

4

2 回答 2

3

AFAIK<ProjectGUID>未嵌入在 Exe 文件中，但您可以创建一个应用程序来读取项目 guid 并作为资源插入到您的 exe 中。

检查此示例应用程序，该应用程序读取文件并在 exe 中创建/更新资源。

program UpdateResEXE;

{$APPTYPE CONSOLE}

uses
  Classes,
  Windows,
  SysUtils;

//you can improve this method to read the ProjectGUID value directly from the dproj file using XML.
procedure UpdateExeResource(Const Source, ResourceName, ExeFile:string);
var
  LStream    : TFileStream;
  hUpdate    : THANDLE;
  lpData     : Pointer;
  cbData     : DWORD;
begin
  LStream := TFileStream.Create(Source,fmOpenRead or fmShareDenyNone);
  try
    LStream.Seek(0, soFromBeginning);
    cbData:=LStream.Size;
    if cbData>0 then
    begin
      GetMem(lpData,cbData);
      try
        LStream.Read(lpData^, cbData);
        hUpdate:= BeginUpdateResource(PChar(ExeFile), False);
        if hUpdate <> 0 then
          if UpdateResource(hUpdate, RT_RCDATA, PChar(ResourceName),0,lpData,cbData) then
          begin
            if not EndUpdateResource(hUpdate,FALSE) then RaiseLastOSError
          end
          else
          RaiseLastOSError
        else
        RaiseLastOSError;
      finally
        FreeMem(lpData);
      end;
    end;
  finally
    LStream.Free;
  end;
end;

begin
  try
    if ParamCount<>3 then
    begin
     Writeln('Wrong parameters number');
     Halt(1);
    end;
    Writeln(Format('Adding/Updating resource %s in %s',[ParamStr(2), ParamStr(3)]));
    UpdateExeResource( ParamStr(1), ParamStr(2), ParamStr(3));
    Writeln('Done');
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.

现在从您的应用程序中，您可以使用 Post build 事件以这种方式调用此应用程序

"C:\The path where is the tool goes here\UpdateResEXE.exe"  "C:\The path of the file which contains the ProjectGUID goes here\Foo.txt"  Project_GUID  "$(OUTPUTPATH)"

并像这样使用：

{$APPTYPE CONSOLE}

uses
  Windows,
  Classes,
  System.SysUtils;


function GetProjectGUID : string;
var
  RS: TResourceStream;
  SS: TStringStream;
begin
  RS := TResourceStream.Create(HInstance, 'Project_GUID', RT_RCDATA);
  try
    SS:=TStringStream.Create;
    try
      SS.CopyFrom(RS, RS.Size);
      Result:= SS.DataString;
    finally
     SS.Free;
    end;
  finally
    RS.Free;
  end;
end;


begin
  try
    Writeln(Format('Project GUID %s',[GetProjectGUID]));
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
  readln;
end.
于 2012-11-06T17:30:27.547 回答
2

为什么不在自己的代码中硬编码自己的 GUID？代码编辑器有一个CTRL+SHIFT+G键盘快捷键，用于在当前活动的代码行生成新的 GUID 字符串。您可以将该声明调整为常量变量，以便您的代码根据需要使用，例如：

const
  MyGuid: TGUID = '{04573E0E-DE08-4796-A5BB-E5F1F17D51F7}';
于 2012-11-06T19:08:25.770 回答