2

我正在使用带有以下代码的“LWP::UserAgent”检索“ISO-8859-1”编码的网站。

问题是特殊字符显示不正确，尤其是“€”符号显示错误。

内容编码被识别为“ISO-8859-1”，这是正确的。

为了显示检索到的文本，我将它保存到一个文件中并使用 Notepag++ 打开它。

问题：如何以正确的方式检索“ISO-8859-1”编码的特殊字符？


#SENDING REQUEST
my $ua = LWP::UserAgent->new();
$ua->agent('Mozilla/5.0 (Windows NT 6.1; WOW64; rv:15.0) Gecko/20100101 Firefox/15.0.1'); # pretend we are very capable browser

my $req = HTTP::Request->new(GET => $url);

#add some header fields
$req->header('Accept', 'text/html,application/xhtml+xml,application/xml;q=0.9,*/*;q=0.8');
$req->header('Accept-Language', 'en;q=0.5');
$req->header('Connection', 'keep-alive');
$req->header('Host', 'www.url.com');

#SEND
my $response = $ua->request($req);

#decode  trial1
print $response->content_charset(); # gives ISO-8859-1 which is right
my $content  = $response->decoded_content(); #special chars are displayed wrong

#decode trial2
my $decContent =  decode('ISO-8859-1', $response->content());
my $utf8Content = encode( 'utf-8', $decContent ); #special char € is displayed as Â

#decode trial3
Encode::from_to($content, 'iso-8859-1', 'utf8'); #special char € is displayed as  too


#example on writing data to file
open(MYOUTFILE, ">>D:\\encodingperl.html"); #open for write, overwrite
print MYOUTFILE "$utf8Content"; #write text
close(MYOUTFILE);
4

2 回答 2

4

和其他一样：

my $content = $response->decoded_content();

也就是说，iso-8859-1字符集不包括欧元符号。你可能实际上有cp1252。您可以按如下方式解决此问题：

my $content = $response->decoded_content( charset => 'cp1252' );

您的第二个问题是您没有对输出进行编码。这就是你的做法。

open(my $MYOUTFILE, '>>:encoding(cp1252)', 'D:\\encodingperl.html')
   or die $!;
print $MYOUTFILE $content;

UTF-8如果不是cp1252您想要的，请使用适合您的编码（例如）。如果您想要原始编码的原始文件，请使用

my $content = $response->decoded_content( charset => 'none' );

和

open(my $MYOUTFILE, '>>', 'D:\\encodingperl.html')
   or die $!;
binmode($MYOUTFILE);
print $MYOUTFILE $content;
于 2012-11-04T03:57:14.657 回答
0

ISO-8859-1 没有欧元符号。如果您需要欧元符号，您应该使用 ISO-8859-15，或者更好的是 UTF-8。

于 2012-11-04T00:55:10.810 回答