windows - 使用批处理文件复制命令提示符

Question

我正在尝试使用批处理文件复制命令提示符。我当前的代码复制如下。

@echo off
title Command Prompt
:LOOP
set /p COMMAND="%CD%>"
title Command Prompt - %COMMAND%
call %COMMAND%
echo.
title Command Prompt
goto LOOP

但是，我有一个问题。如果我正在调用一个程序（例如gpedit.msc），批处理文件会等到程序返回后再继续，此时正常的命令提示符会返回而不等待程序返回。

如何测试命令是否是程序，以便我可以使用该start命令？

Answer 1

You can search the executable for user32.dll.

@echo off
title Command Prompt
:LOOP
    set /p COMMAND="%CD%>"
    title Command Prompt - %COMMAND%

    call :is_gui %COMMAND%
    if errorlevel 1 (
        call %COMMAND%
    ) else (
        start "" %COMMAND%
    )

    echo.
    title Command Prompt
    goto LOOP

:is_gui app_name
    set app_name=%~1
    set file_app=

    rem Get path of application
    if exist "%app_name%" (
        set file_app=%app_name%
    ) else (
        rem Lookup path of app
        for %%P in (%PATHEXT%) do (
          for %%I in (%1 %1%%P) do (
            if exist "%%~$PATH:I" (
              set file_app=%%~$PATH:I
              goto continue
            )
          )
        )
    )
    :continue
    if "%file_app%"=="" exit /b 1
    find /i "user32.dll" < "%file_app%" >nul 2>&1
    exit /b %errorlevel%