2

我有以下 xml 文件：

<root_tag>
<tag1>
    <tag1_1>A</tag1_1>
    <tag1_2>B</tag1_2>
    <tag1_3>C</tag1_3>
</tag1>
<tag2>
    <tag2_1>D</tag2_1>
    <tag2_2>
        <elem xmlns="http://a.b.com/sample">
            <elem_1>E</elem_1>
            <elem_2>F</elem_2>
        </elem>
    </tag2_2>
</tag2></root_tag>

和 xslt 模板：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:output method="xml" version="1.0" indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:template match="/">
    <NODE>
        <node1>
            <xsl:value-of select="/root_tag/tag1/tag1_2"/>
        </node1>
        <node2>
            <xsl:value-of select="/root_tag/tag2/tag2_1"/>
        </node2>
        <node3>
            <xsl:value-of select="/root_tag/tag2/tag2_2/child::*[local-name(.) = 'elem']/child::*[local-name(.) = 'elem_1']"/>
        </node3>
        <xsl:variable name="A" select="namespace-uri(/root_tag/tag2/tag2_2/child::*[local-name(.) = 'elem'])"/>
        <node4>    
            <xsl:value-of select="$A"/>
        </node4>
        <node5>
            <!-- some code here -->
        </node5>
    </NODE>
</xsl:template>

输出是：

<NODE>
    <node1>B</node1>
    <node2>D</node2>
    <node3>E</node3>
    <node4>http://a.b.com/sample</node4>
    <node5></node5>
</NODE>

有没有办法在 node5 中获取/root_tag/tag2/tag2_2/elem/elem_1的值而不使用像 node3 中的 xpath？存储 elem 命名空间的变量 A 可以以某种方式用于此目的吗？

我还设法通过在 xsl:stylesheet标记中添加xmlns:a_1="http://abcom/sample"并使用 xpath /root_tag/tag2/tag2_2/a_1:elem/a_1:elem_1 来提取信息，但这只是涵盖了我提前知道命名空间的情况。

4

2 回答 2

1

很不幸的是，不行。更短的 XPath：

/root_tag/tag2/tag2_2/*[local-name(.) = 'elem']/*[local-name(.) = 'elem_1']
于 2012-11-01T23:32:05.353 回答
1

xxx:node-set()这是使用扩展在 XSLT 1.0 中执行此操作的一种方法：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common" exclude-result-prefixes="ext">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:variable name="vrtfDoc2">
  <xsl:apply-templates/>
 </xsl:variable>

 <xsl:template match="/">
  <node5>
   <xsl:value-of select=
    "ext:node-set($vrtfDoc2)/root_tag/tag2/tag2_2/elem/elem_1"/>
  </node5>
 </xsl:template>

 <xsl:template match="*">
   <xsl:element name="{name()}">
     <xsl:apply-templates select="@*|node()"/>
   </xsl:element>
 </xsl:template>

 <xsl:template match="@*">
  <xsl:attribute name="{name()}">
   <xsl:value-of select="."/>
  </xsl:attribute>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于提供的 XML 文档时：

<root_tag>
    <tag1>
        <tag1_1>A</tag1_1>
        <tag1_2>B</tag1_2>
        <tag1_3>C</tag1_3>
    </tag1>
    <tag2>
        <tag2_1>D</tag2_1>
        <tag2_2>
            <elem xmlns="http://a.b.com/sample">
                <elem_1>E</elem_1>
                <elem_2>F</elem_2>
            </elem>
        </tag2_2>
    </tag2>
</root_tag>

产生了想要的正确结果 ( node5)：

<node5>E</node5>

说明：

  1. 这是一个两遍转换。

  2. 在 pass1 中，文档被转换为包含原始文档元素的 RTF（结果树片段），但所有元素都在“无命名空间”中。

  3. EXSLText:node-set()扩展函数用于将上面1.中得到的RTF转换成正则树。

  4. 提供的不包含任何谓词和对local-name()函数的引用的 XPath 表达式将根据上面 3. 中生成的文档进行评估。

于 2012-11-02T03:03:54.287 回答