2

我有 JDK6 并使用 JAXP 进行转换。我是 XSLT 的初学者。

源 XML：

<Number>
    <Value>529.82</Value>
</Number>

XSLT：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="Number">
        <xsl:element name="Result">
            <xsl:element name="Total">
                <xsl:attribute name="Amount">
                    <xsl:value-of select="format-number(Value, '#.00')*100"/>
                </xsl:attribute>
            </xsl:element>
        </xsl:element>
    </xsl:template>
</xsl:stylesheet>

输出 XML：

<?xml version="1.0" encoding="UTF-8"?>
<Result>
     <Total Amount="52982.00000000001"/>
</Result>

这里属性的值Amount应该是52982。请帮忙。

4

3 回答 3

3

使用：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="Number">
     <Result>
      <Total amount="{round(format-number(Value, '#.00')*100)}"/>
     </Result>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于提供的 XML 文档时：

<Number>
    <Value>529.82</Value>
</Number>

产生了想要的正确结果：

<Result>
   <Total amount="52982"/>
</Result>

说明：

XSLT 1.0 只有一个数字类型，它是双精度类型。

与任何浮点类型一样，存在精度误差。

在 XPath 2.0 / XSLT 2.0 中，可以使用该xs:decimal类型，从而消除任何精度错误——当然，该xs:decimal类型具有定义的最大位数。

作为参考，这里是相应的 XSLT 2.0 转换，使用xs:decimal：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema" exclude-result-prefixes="xs">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="Number">
     <Result>
      <Total amount="{xs:decimal(format-number(Value, '#.00'))*100}"/>
     </Result>
 </xsl:template>
</xsl:stylesheet>

结果：

<Result>
   <Total amount="52982"/>
</Result>

甚至更简单（没有format-number()）：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema" exclude-result-prefixes="xs">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="Number">
     <Result>
      <Total amount="{xs:decimal(Value)*100}"/>
     </Result>
 </xsl:template>
</xsl:stylesheet>
于 2012-10-30T14:41:55.127 回答
1

尝试

<xsl:value-of select="format-number(Value*100, '#')"/>

您之前的方法的问题是您将其格式化Value为字符串，然后将其转换回数字并将其乘以 100。您需要对原始数字进行乘法运算，然后格式化结果。

于 2012-10-30T14:41:13.197 回答
1

您可以使用该round()功能。只需将您的电话包裹format-number()在其中即可。以下样式表可以解决问题：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="Number">
        <xsl:element name="Result">
            <xsl:element name="Total">
                <xsl:attribute name="Amount">
                    <xsl:value-of select="round(format-number(Value, '#.00')*100)"/>
                </xsl:attribute>
            </xsl:element>
        </xsl:element>
    </xsl:template>
</xsl:stylesheet>
于 2012-10-30T14:41:39.203 回答