perl - 从文件中复制特定字符串后的文本并在 perl 中附加到另一个

Question

我想从一个文件中提取所需的信息并将其附加到另一个文件中。第一个文件包含一些行作为没有特定模式的标题，并且仅以“END OF HEADER”字符串结尾。我编写了以下代码来查找标题末尾的匹配行：

$find = "END OF HEADER";                     
open FILEHANDLE, $filename_path;      
while (<FILEHANDLE>) {

     my $line = $_;                                                
     if ($line =~ /$find/) {

         #??? what shall I do here???                                                                                      
     }
}

，但我不知道如何获取文件的其余部分并将其附加到另一个文件中。

感谢您的任何帮助

Answer 1

我想如果文件的内容不是很大，你可以将整个文件加载到一个标量中，然后用“END OF HEADER”分割它，然后在新文件中打印分割右侧的输出（附加)

open READHANDLE, 'readfile.txt' or die $!;
my $content = do { local $/; <READHANDLE> };
close READHANDLE;

my (undef,$restcontent) = split(/END OF HEADER/,$content);

open WRITEHANDLE, '>>writefile.txt' or die $!;
print WRITEHANDLE $restcontent;
close WRITEHANDLE;

Answer 2

此代码将从命令行获取文件名，打印END OF HEADER从第一个文件开始的所有文件，然后是第二个文件的所有行。请注意，输出将发送到 STDOUT，因此您必须重定向输出，如下所示：

perl program.pl headfile.txt mainfile.txt > newfile.txt

Update Now 修改为打印所有第一个文件之后的行END OF HEADER，然后是所有第二个文件

use strict;
use warnings;

my ($header_file, $main_file) = @ARGV;

open my $fh, '<', $header_file or die $!;
my $print;
while (<$fh>) {
  print if $print;
  $print ||= /END OF HEADER/;
}

open $fh, '<', $main_file or die $!;
print while <$fh>;

Answer 3

use strict;
use warnings;

use File::Slurp;

my @lines = read_file('readfile.txt');

while ( my $line = shift @lines) {
  next unless ($line =~ m/END OF HEADER/);
  last;
}

append_file('writefile.txt', @lines);

Answer 4

我相信这会满足您的需求：

use strict;
use warnings;

my $find = 'END OF HEADER';
my $fileContents;

{
    local $/;
    open my $fh_read, '<', 'theFile.txt' or die $!;
    $fileContents = <$fh_read>;
}

my ($restOfFile) = $fileContents =~ /$find(.+)/s;

open my $fh_write, '>>', 'theFileToAppend.txt' or die $!;

print $fh_write $restOfFile;

close $fh_write;

Answer 5

my $status = 0;
my $find = "END OF HEADER";

open my $fh_write, '>', $file_write
    or die "Can't open file $file_write $!";

open my $fh_read, '<', $file_read
    or die "Can't open file $file_read $!";

LINE:
while (my $line = <$fh_read>) {

     if ($line =~ /$find/) {

         $status = 1;
         next LINE;
     }                       

     print $fh_write $line if $status;
}

close $fh_read;
close $fh_write;