我有一个字符串，我需要将每个单词的第一个字母转换为大写，然后使用 xsl 转换为小写，例如，
输入字符串= dInEsh sAchdeV kApil Muk
所需的输出字符串 = Dinesh Sachdev Kapil Muk
虽然，我知道我必须为此目的使用翻译功能，但是如何使用 XSLT 1.0 将每个单词的第一个宪章翻译成大写并全部小写
谢谢
问问题
19691 次
8 回答
18
以下不是“好”，我敢肯定有人（主要是 Dimitri）可以想出更简单的东西（尤其是在 XSLT 2.0 中）......但我已经测试过它并且它有效
<xsl:template name="CamelCase">
<xsl:param name="text"/>
<xsl:choose>
<xsl:when test="contains($text,' ')">
<xsl:call-template name="CamelCaseWord">
<xsl:with-param name="text" select="substring-before($text,' ')"/>
</xsl:call-template>
<xsl:text> </xsl:text>
<xsl:call-template name="CamelCase">
<xsl:with-param name="text" select="substring-after($text,' ')"/>
</xsl:call-template>
</xsl:when>
<xsl:otherwise>
<xsl:call-template name="CamelCaseWord">
<xsl:with-param name="text" select="$text"/>
</xsl:call-template>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template name="CamelCaseWord">
<xsl:param name="text"/>
<xsl:value-of select="translate(substring($text,1,1),'abcdefghijklmnopqrstuvwxyz','ABCDEFGHIJKLMNOPQRSTUVWXYZ')" /><xsl:value-of select="translate(substring($text,2,string-length($text)-1),'ABCDEFGHIJKLMNOPQRSTUVWXYZ','abcdefghijklmnopqrstuvwxyz')" />
</xsl:template>
基本思想是CamelCase，如果找到空格，则调用 ，然后在空格之前CamelCaseWord的所有内容（即第一个单词）上运行，然后在空格之后的所有内容（即句子的其余部分）上再次调用。否则，如果没有找到空格（因为它已经到了句子中的最后一个单词），那么它只会调用.CamelCaseCamelCaseWord
该CamelCaseWord模板仅将第一个字符从小写转换为大写（如有必要），并将所有剩余字符从大写转换为小写（如有必要）。
因此，要调用它，您将拥有...
<xsl:call-template name="CamelCase">
<xsl:with-param name="text">dInEsh sAchdeV kApil Muk</xsl:with-param>
</xsl:call-template>
于 2012-10-29T13:53:59.040 回答
5
额外的：
我错过了问题中的 1.0 要求。这仅适用于 2.0 版。
下面的原始答案。
我相信这个在不久前对我有用。声明一个函数：
<xsl:function name="my:titleCase" as="xs:string">
<xsl:param name="s" as="xs:string"/>
<xsl:choose>
<xsl:when test="lower-case($s)=('and','or')">
<xsl:value-of select="lower-case($s)"/>
</xsl:when>
<xsl:when test="$s=upper-case($s)">
<xsl:value-of select="$s"/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="concat(upper-case(substring($s, 1, 1)), lower-case(substring($s, 2)))"/>
</xsl:otherwise>
</xsl:choose>
</xsl:function>
并使用它：
<xsl:sequence select="string-join(for $x in tokenize($text,'\s') return my:titleCase($x),' ')"/>
归功于samjudson => http://p2p.wrox.com/xslt/80938-title-case-string.html
于 2012-10-29T14:18:14.797 回答
4
这是一个已有 8 年历史的 FXSL 1.x（一个完全用 XSLT 1.0 编写的 XSLT 1.0 库）解决方案：
测试-strSplit-to-Words10.xsl：
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:ext="http://exslt.org/common"
>
<xsl:import href="strSplitWordDel.xsl"/>
<!-- To be applied on: test-strSplit-to-Words10.xml -->
<xsl:output indent="yes" omit-xml-declaration="yes"/>
<xsl:variable name="vLower"
select="'abcdefgijklmnopqrstuvwxyz'"/>
<xsl:variable name="vUpper"
select="'ABCDEFGIJKLMNOPQRSTUVWXYZ'"/>
<xsl:template match="/">
<xsl:variable name="vwordNodes">
<xsl:call-template name="str-split-word-del">
<xsl:with-param name="pStr" select="/"/>
<xsl:with-param name="pDelimiters"
select="', .(	 '"/>
</xsl:call-template>
</xsl:variable>
<xsl:apply-templates select="ext:node-set($vwordNodes)/*"/>
</xsl:template>
<xsl:template match="word">
<xsl:choose>
<xsl:when test="not(position() = last())">
<xsl:value-of
select="translate(substring(.,1,1),$vLower,$vUpper)"/>
<xsl:value-of select="substring(.,2)"/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="."/>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template match="delim">
<xsl:value-of select="."/>
</xsl:template>
</xsl:stylesheet>
当此转换应用于以下 XML 文档 (test-strSplit-to-Words10.xml) 时：
<t>004.lightning crashes (live).mp3</t>
结果是：
004.Lightning Crashes (Live).mp3
应用于此 XML 文档（您提供的示例）时：
dInEsh sAchdeV kApil Muk
结果是：
DInEsh SAchdeV KApil Muk
只需一周时间，我们就可以得到以下代码：
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:ext="http://exslt.org/common"
>
<xsl:import href="strSplitWordDel.xsl"/>
<!-- To be applied on: test-strSplit-to-Words10.xml -->
<xsl:output indent="yes" omit-xml-declaration="yes"/>
<xsl:variable name="vLower"
select="'abcdefgijklmnopqrstuvwxyz'"/>
<xsl:variable name="vUpper"
select="'ABCDEFGIJKLMNOPQRSTUVWXYZ'"/>
<xsl:template match="/">
<xsl:variable name="vwordNodes">
<xsl:call-template name="str-split-word-del">
<xsl:with-param name="pStr" select="/"/>
<xsl:with-param name="pDelimiters"
select="', .(	 '"/>
</xsl:call-template>
</xsl:variable>
<xsl:apply-templates select="ext:node-set($vwordNodes)/*"/>
</xsl:template>
<xsl:template match="word">
<xsl:value-of
select="translate(substring(.,1,1),$vLower,$vUpper)"/>
<xsl:value-of select="translate(substring(.,2), $vUpper, $vLower)"/>
</xsl:template>
<xsl:template match="delim">
<xsl:value-of select="."/>
</xsl:template>
</xsl:stylesheet>
现在产生了想要的结果：
Dinesh Sachdev Kapil Muk
说明：
FXSL的str-split-word-del模板可用于将（可能不止一个）分隔符指定为字符串参数的标记化。
于 2012-10-29T22:52:58.050 回答
2
这是另一个简短的解决方案。它使用纯 XSL-T 2.0。我知道 OP 对 XSL-T 1.0 有要求，但由于此页面在 2015 年的“xsl-t 标题案例功能”在 Google 上排名第一，这似乎更相关：
<xsl:function name="xx:fixCase">
<xsl:param name="text" />
<xsl:for-each select="tokenize($text,' ')">
<xsl:value-of select="upper-case(substring(.,1,1))" />
<xsl:value-of select="lower-case(substring(.,2))" />
<xsl:if test="position() ne last()">
<xsl:text> </xsl:text>
</xsl:if>
</xsl:for-each>
</xsl:function>
其中“xx”是您自己的命名空间。
于 2015-04-09T22:36:58.197 回答
2
你也可以试试这个：
http://www.xsltfunctions.com/xsl/functx_camel-case-to-words.html
<xsl:function name="functx:camel-case-to-words" as="xs:string"
xmlns:functx="http://www.functx.com">
<xsl:param name="arg" as="xs:string?"/>
<xsl:param name="delim" as="xs:string"/>
<xsl:sequence select="
concat(substring($arg,1,1),
replace(substring($arg,2),'(\p{Lu})',
concat($delim, '$1')))
"/>
</xsl:function>
和向后： http ://www.xsltfunctions.com/xsl/functx_words-to-camel-case.html
<xsl:function name="functx:words-to-camel-case" as="xs:string"
xmlns:functx="http://www.functx.com">
<xsl:param name="arg" as="xs:string?"/>
<xsl:sequence select="
string-join((tokenize($arg,'\s+')[1],
for $word in tokenize($arg,'\s+')[position() > 1]
return functx:capitalize-first($word))
,'')
"/>
</xsl:function>
于 2017-12-06T15:19:59.023 回答
0
XQUERY 上的相同功能：
函数 Xquery 到骆驼案例。
declare function xf:toCamelCase($text as xs:string?) as xs:string{
if(contains($text,' ')) then
fn:concat(xf:CamelCaseWord(substring-before($text,' ')),' ', xf:toCamelCase(substring-after($text,' ')))
else
xf:CamelCaseWord($text)
};
declare function xf:CamelCaseWord($text as xs:string?) as xs:string{
fn:concat( translate(substring($text,1,1),'abcdefghijklmnopqrstuvwxyz','ABCDEFGHIJKLMNOPQRSTUVWXYZ'),
translate(substring($text,2,string-length($text)-1),'ABCDEFGHIJKLMNOPQRSTUVWXYZ','abcdefghijklmnopqrstuvwxyz'))
};
于 2013-10-17T19:05:38.230 回答
0
一个非常简短的解决方案，利用 EXSLT 的split()功能：
<xsl:variable name='text' select='"dInEsh sAchdeV kApil Muk"' />
<xsl:variable name='lowers' select='"abcdefghijklmnopqrstuvwxyz"' />
<xsl:variable name='uppers' select='"ABCDEFGHIJKLMNOPQRSTUVWXYZ"' />
<xsl:template match="/">
<xsl:for-each select='str:split($text, " ")'>
<xsl:value-of select='concat(
translate(substring(., 1, 1), $lowers, $uppers),
translate(substring(., 2), $uppers, $lowers),
" "
)' />
</xsl:for-each>
</xsl:template>
于 2014-02-04T13:30:55.527 回答
0
可以使用单行表达式来实现。试试这个
string-join(for $x in tokenize($text,'\s') return concat(upper-case(substring($x, 1, 1)), lower-case(substring($x, 2))),' ')
注意 - 这已经通过 Orbeon Forms 公式进行了验证。
于 2020-07-23T10:23:29.560 回答