2

我写了下面的代码来构造一个给定顶点的树，给定顶点之间的连接列表。

type Connection = (Int,Int)
data Tree = Leaf Int | Node Int [Tree] deriving (Eq,Read,Show)

makeTree :: Int -> [Connection] -> Tree
makeTree x [] = Leaf x
makeTree indx connections =  Node indx otherTrees where
  otherTrees = [makeTree i cx | i <- directConnections, let cx = removeConnectionsTo indx connections]
  directConnections = map (\(x,y) -> if (x == indx) then y else x) $ filter (\(x,y) -> x == indx || y   == indx) connections

removeConnectionsTo :: Int -> [Connection] -> [Connection]
removeConnectionsTo indx = filter (\(x,y) ->    x /= indx && y /= indx)

出于某种原因，下面的输入给了我惊人的不同结果：

makeTree 1 [(1,2),(1,3)]给我Node 1 [Leaf 2,Leaf 3]

makeTree 1 [(1,2),(1,5),(2,3),(2,4),(5,6),(5,7)]给我Node 1 [Node 2 [Node 3 [],Node 4 []],Node 5 [Node 6 [],Node 7 []]]

我在 OS X 10.8.2 上运行 GHCi，版本 7.4.1。

我不明白为什么我在第一个示例中获得了两次 Leaf（正确），但在第二个示例中获得了空子树列表的节点（不正确）。

4

1 回答 1

3

一个快速的解决方法otherTrees是在决定是否构建 aLeaf或 a之前检查是否为空Node，例如

makeTree indx connections
  | null otherTrees = Leaf indx
  | otherwise       = Node indx otherTrees
  where ...

要了解这里发生了什么，让我们添加一些工具：

import Debug.Trace

makeTree :: Int -> [Connection] -> Tree
makeTree ix cs | traceShow (ix, cs) False = undefined
makeTree x [] = ... -- leave rest of the function as before

现在将其加载到 GHCi 中，让我们看看递归调用是什么：

> import Control.DeepSeq
> (show $ makeTree 1 [(1,2),(1,5),(2,3),(2,4),(5,6),(5,7)]) `deepseq` ()
(1,[(1,2),(1,5),(2,3),(2,4),(5,6),(5,7)])
(2,[(2,3),(2,4),(5,6),(5,7)])
(3,[(5,6),(5,7)])
(4,[(5,6),(5,7)])
(5,[(2,3),(2,4),(5,6),(5,7)])
(6,[(2,3),(2,4)])
(7,[(2,3),(2,4)])
()

如您所见，第二个参数中的列表不为空，这就是它与函数的第一种情况不匹配的原因，因此您需要像我的示例中那样添加一些额外的检查，或者确保您过滤掉其余的连接。

于 2012-10-26T03:28:48.507 回答