2

只是为了我自己的教育，有什么巧妙的方法可以转换一些数组，以便每个数组都与哈希的键相关联，并且所有这些哈希最终都在一个数组中？

为了让事情更清楚一点，假设我有一些像这样的数组：

my @n = ( 1,    2,    3 );
my @f = ( 3.14, 1.21, 0.75 );
my @s = ( 'a',  'b',  'c' );

我想要一个看起来像这样的哈希数组：

my %h = ( number => 1, float => 3.14, string => 'a' );

简单的 C 风格迭代是一个明显的解决方案：

for ( my $i = 0; $i < @n; $i++ ) {
    my %h = ();
    $h{number} = $n[$i];
    $h{float}  = $f[$i];
    $h{string} = $s[$i];
    push @a, \%h;
}

稍微多一点Perlish：

for (0..$#n) {
    push @c, { number => $n[$_], float => $f[$_], string => $s[$_] };
}

或者，如果我想简洁而不关心破坏数组：

for (0..$#n) {
    push @a, { number => shift @n, float => shift @f, string => shift @s };
}

并与List::MoreUtils：

use List::MoreUtils qw (each_array);
my $it = each_array @n, @f, @s;
while ( my ($n, $f, $s) = $it->() ) {
    push @a, { number => $n, float => $f, string => $s };
}

因此，本着 TMTOWTDI 的精神，我还缺少哪些其他解决方案？

4

4 回答 4

2

my @array = map { number => $n[$_], float => $f[$_], string => $s[$_] }, 0 .. $#n;

我不是 Perl 人，只是一个建议:)

于 2012-10-25T14:37:33.523 回答
2

不是真的可读，使用切片：

@{ $d[$_] }{qw/number float string/} = ($n[$_], $f[$_], $s[$_]) for 0 .. $#n;
于 2012-10-25T14:32:11.240 回答
0

这使用了一些实用程序List::MoreUtils

  • mesh整合数组列表
  • part对数组进行分区

也_POSINT从Params::Util判断下一个参数是否为正整数。

use List::MoreUtils qw<mesh part>; # integrate and partition arrays
use Params::Util    qw<_POSINT>;   # test number positive

# accept size number if positive int, otherwise we will be returning pairs. 
sub by (@) { 
   my $num = &_POSINT ? shift : 2;
   my $i   = -1;
   return part { int( ++$i / $num ) } @_;
}

my @n      = qw< 1    2    3 >;
my @f      = qw< 3.14 1.21 0.75 >;
my @s      = qw< a    b    c >;
my @fields = qw<number float string>;

my @results = map { +{ mesh @fields, @$_ } } by 3 => mesh @n, @f, @s;

当然，使用它，您可以像这样列出数据：

my @results 
    = map { +{ mesh @fields, @$_ } } 
      by 3 => qw< 1 3.14 a
                  2 1.21 b
                  3 0.75 c
                >
    ;

并跳过第一个mesh。布局指示数据的结构（就像代码一样。）

于 2012-10-25T17:31:51.160 回答
0

该程序可以满足您的要求

use strict;
use warnings;

my @n = ( 1,    2,    3 );
my @f = ( 3.14, 1.21, 0.75 );
my @s = ( 'a',  'b',  'c' );

my @data;
for my $i (0 .. $#n) {
  @{$data[$i]}{ qw/ number float string / } = map $_->[$i], \(@n, @f, @s);
}

use Data::Dump;
dd \@data;

输出

[
  { float => 3.14, number => 1, string => "a" },
  { float => 1.21, number => 2, string => "b" },
  { float => 0.75, number => 3, string => "c" },
]

或者您可能更喜欢使用List::MoreUtils库each_array函数的解决方案。该程序的输出与我上面之前的解决方案的输出相同。

use strict;
use warnings;

use List::MoreUtils 'each_array';

my @n = ( 1,    2,    3 );
my @f = ( 3.14, 1.21, 0.75 );
my @s = ( 'a',  'b',  'c' );

my $iter = each_array(@n, @f, @s);
my @data;
while ( my @values = $iter->() ) {
  my $i = $iter->('index');
  @{ $data[$i] }{ qw/ number float string / } = @values;
}

use Data::Dump;
dd \@data;
于 2012-10-25T16:59:08.403 回答