2

我目前对使用字符串表单名称创建表单感到困惑（如在 Delphi 中是否可以通过其名称实例化一个类？）但我的表单有它自己的构造函数创建。

//-BASE CLASS-//
TBaseForm = class(TForm)
  constructor Create(param1, param2: string); overload;
protected
  var1, var2: string;    
end;

constructor TBaseForm.Create(param1, param2: string);
begin
  inherited Create(Application);
  var1 := param1;
  var2 := param2;
end;

//-REAL CLASS-//
TMyForm = class(TBaseForm)
end;

//-CALLER-//
TCaller = class(TForm)
  procedure Btn1Click(Sender: TObject);
  procedure Btn2Click(Sender: TObject);
end;

uses UnitBaseForm, UnitMyForm;

procedure TCaller.Btn1Click(Sender: TObject);
begin
  TMyForm.Create('x', 'y');
end;

procedure TCaller.Btn1Click(Sender: TObject);
var PC: TPersistentClass;
    Form: TForm;
    FormBase: TBaseForm;
begin
  PC := GetClass('TMyForm');

  // This is OK, but I can't pass param1 & 2
  Form := TFormClass(PC).Create(Application);

  // This will not error while compiled, but it will generate access violation because I need to create MyForm not BaseForm.
  FormBase := TBaseForm(PC).Create('a', 'z');
end;

根据我提供的代码，如何仅通过字符串表单名称来创建动态自定义构造函数表单？还是真的不可能？（我开始认为这是不可能的）

4

1 回答 1

2

您需要定义一个class of TBaseForm数据类型，然后将结果GetClass()类型转换为该类型，然后您可以调用您的构造函数。您还需要将您的构造函数声明为虚拟，以便可以正确调用派生类构造函数。

尝试这个：

type
  TBaseForm = class(TForm)
  public
    constructor Create(param1, param2: string); virtual; overload;
  protected
    var1, var2: string;    
  end;

TBaseFormClass = class of TBaseForm;

.

procedure TCaller.Btn1Click(Sender: TObject);
var
  BF: TBaseFormClass;
  Form: TBaseForm;
begin
  BF := TBaseFormClass(GetClass('TMyForm'));
  Form := BF.Create('a', 'z');
end;
于 2012-10-25T08:59:10.133 回答