xml - 如何对元素字符串的一部分进行排序？

Question

我遇到了一些 XSLT 转换的问题。在我的 XML 数据中有一些像这样的坐标元素：

XML:

[...]
<polygon some="attributes">
  <coordinates>
    <point>(8.234/9.435)</point>
    <point>(2.456/5.678)</point>
    [...]
  </coordinates>
</polygon>
[...]

等等。的值表示 x 和 ay 坐标 (x/y)。现在我必须从特定坐标集中获取 x OR y 的最大值或最小值。

我们在 c++ 代码中使用 msxml，因此我不能将 XSLT 2.0 或 XPath 2.0 用于 min() 和 max() 函数。

格式 (x/y) 是静态的，我也无法更改它，因为它是程序的输出。

我尝试在 XSLT 中这样做：

XSLT：

<xsl:template name="getMinOf"> <!--this one is getting nodeset, min/max, x/y params-->
  <xsl:for-each select="$nodeSet"> <!--in this case "//polygon/coordinates/point"-->
    *<xsl:choose>
      <xsl:when test="$MinOrMax = 'min' ">
        <xsl:choose>
          <xsl:when test="$XorY = 'x'">*
        <xsl:sort select="substring-before(substring-after(.,'('),'/')" data-type="number" order="ascending"/> <!--Here is my problem-->
              <xsl:if test="position() = 1">
                <xsl:value-of select="." /><!--  return xMin -->
              </xsl:if>
          </xsl:when>
      [...]
</xsl:template>

select=" substring-before(substring-after(.,'('),'/')"应该得到 ( 和 / 之间的部分，即 x 坐标。如果我做

<!--this one does return the x value.-->
<xsl:value-of select="substring-before(substring-after(.,'('),'/')"/>

所以......我希望你能理解我的问题并能帮助我。我不知道如何更进一步。谢谢。

编辑：忘记了所需的输出。它应该是这样的：

<polygon>
  <xMin>2.456</xMin>
  <xMax>8.234</xMax>
  <yMin>5.678</yMin>
  <yMax>9.435</yMax>
</polygon>

Answer 1

虽然问题中没有提到，但我猜您的问题是您收到消息“Keyword xsl:sort may not be used here.”，这是因为您的xsl:sort嵌套在xsl:when应该是什么时候直接在xsl:for-each下

实际上，您正在尝试根据您的参数进行条件排序。一个条件是是否按 x 或 y 坐标排序，另一个条件是按升序还是降序排序。

对于排序，您可以定义一个变量，该变量将保存“升序”或“降序”，然后按以下顺序排序：

  <xsl:variable name="order">
     <xsl:choose>
        <xsl:when test="$MinOrMax='max'">descending</xsl:when>
        <xsl:otherwise>ascending</xsl:otherwise>
     </xsl:choose>
  </xsl:variable>
  <xsl:for-each select="coordinates/point">
     <xsl:sort select="substring-before(substring-after(.,'('),'/')" data-type="number" order="{$order}"/>

下一个问题是如何根据您的参数选择“x”或“y”坐标。一种方法是使用xsl:choose在排序方法之间进行选择

  <xsl:choose>
     <xsl:when test="$XorY='x'">
        <xsl:for-each select="coordinates/point">
           <xsl:sort select="substring-before(substring-after(.,'('),'/')" data-type="number" order="{$order}"/>
           <xsl:if test="position() = 1">
              <xsl:value-of select="substring-before(substring-after(.,'('),'/')"/>
           </xsl:if>
        </xsl:for-each>         
     </xsl:when>
     <xsl:otherwise>
        <xsl:for-each select="coordinates/point">
           <xsl:sort select="substring-before(substring-after(.,'/'),')')" data-type="number" order="{$order}"/>
           <xsl:if test="position() = 1">
              <xsl:value-of select="substring-before(substring-after(.,'/'),')')"/>
           </xsl:if>
        </xsl:for-each>         
     </xsl:otherwise>
  </xsl:choose>

但是，有一种方法可以避免这种潜在的代码重复，并且只有一个xsl:for-each。试试这个

     <xsl:sort select="concat(
          substring(substring-before(substring-after(.,'('),'/'), 1, 100 * ($XorY = 'x')), 
          substring(substring-before(substring-after(.,'/'),')'), 1, 100 * ($XorY = 'y')))" 
       data-type="number" order="{$order}"/>

这利用($XorY = 'x')了表达式中将评估为 0 或 1 的事实。为了更好地理解它，它实际上是对这两个表达式进行串联：

substring(<x co-ordinate>, 1, 100 * <0 or 1>)
substring(<y co-ordinate>, 1, 100 * <0 or 1>)

当 $XorY = 'x' 时返回 1，因此第一个子字符串（x 坐标）返回一个完整字符串，但第二个子字符串返回一个空字符串。当 $XorY = 'y' 时，则相反，并返回第二个子字符串（y 坐标）。

试试这个 XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml" indent="yes"/>

   <xsl:template match="polygon">
      <polygon>
         <xMin>
            <xsl:call-template name="getMinOf">
               <xsl:with-param name="MinOrMax" select="'min'" />
               <xsl:with-param name="XorY" select="'x'" />
            </xsl:call-template>   
         </xMin>
         <xMax>
            <xsl:call-template name="getMinOf">
               <xsl:with-param name="MinOrMax" select="'max'" />
               <xsl:with-param name="XorY" select="'x'" />
            </xsl:call-template>   
         </xMax>
         <yMin>
            <xsl:call-template name="getMinOf">
               <xsl:with-param name="MinOrMax" select="'min'" />
               <xsl:with-param name="XorY" select="'y'" />
            </xsl:call-template>   
         </yMin>         
         <yMax>
            <xsl:call-template name="getMinOf">
               <xsl:with-param name="MinOrMax" select="'max'" />
               <xsl:with-param name="XorY" select="'y'" />
            </xsl:call-template>   
         </yMax>
      </polygon>
   </xsl:template>

   <xsl:template name="getMinOf">
      <xsl:param name="MinOrMax"/>
      <xsl:param name="XorY"/>
      <xsl:variable name="order">
         <xsl:choose>
            <xsl:when test="$MinOrMax='max'">descending</xsl:when>
            <xsl:otherwise>ascending</xsl:otherwise>
         </xsl:choose>
      </xsl:variable>
      <xsl:for-each select="coordinates/point">
         <xsl:sort select="concat(substring(substring-before(substring-after(.,'('),'/'), 1, 100 * ($XorY = 'x')), substring(substring-before(substring-after(.,'/'),')'), 1, 100 * ($XorY = 'y')))" data-type="number" order="{$order}"/>
         <xsl:if test="position() = 1">
            <xsl:value-of select="concat(substring(substring-before(substring-after(.,'('),'/'), 1, 100 * ($XorY = 'x')), substring(substring-before(substring-after(.,'/'),')'), 1, 100 * ($XorY = 'y')))"/>
         </xsl:if>
      </xsl:for-each>
   </xsl:template>

   <xsl:template match="@*|node()">
      <xsl:copy>
         <xsl:apply-templates select="@*|node()"/>
      </xsl:copy>
   </xsl:template>
</xsl:stylesheet>

应用于您的示例 XML 时，将输出以下内容

<polygon>
   <xMin>2.456</xMin>
   <xMax>8.234</xMax>
   <yMin>5.678</yMin>
   <yMax>9.435</yMax>
</polygon>