1

我是 Perl 的新手，我遇到了心理障碍。我需要从制表符分隔的文件中提取信息，如下所示。

#name  years risk total
 adam  5     100  200
 adam  5     50   100
 adam  10    20   300
 bill  20    5    100
 bill  30    10   800

在此示例中，制表符分隔的文件显示投资长度、风险金额和投资结束时的总额。

我想解析这个文件，并为每个名称（例如adam）计算投资年数总和5+5，并计算收入总和(200-100) + (100-50) + (300-20)。我还想保存每个名称的总数（200、100、300）。

这是我到目前为止所尝试的：

my $filename;
my $seq_fh;

open $seq_fh, $frhitoutput 
    or die "failed to read input file: $!";

while (my $line = <$seq_fh>) {

    chomp $line;
    ## skip comments and blank lines and optional repeat of title line

    next if $line =~ /^\#/ || $line =~ /^\s*$/ || $line =~ /^\+/;

    #split each line into array
    my @line = split(/\s+/, $line);
    my $yeartotal = 0;
    my $earning   = 0;

    #$line[0] = name
    #$line[1] = years
    #$line[2] = start
    #$line[3] = end

    while (@line[0]){

        $yeartotal += $line[1];
        $earning   += ($line[3]-$line[2]);
    }
}

关于我哪里出错的任何想法？

4

5 回答 5

7

该Text::CSV模块可用于读取制表符分隔的数据。split在引用、转义等方面，通常比尝试手动破解某些东西要好得多。

于 2012-10-24T09:55:12.700 回答
6

你错了：while(@line[0]){

我会做：

my $seq_fh;
my %result;
open($seq_fh, $frhitoutput) || die "failed to read input file: $!";
while (my $line = <$seq_fh>) {
    chomp $line;
    ## skip comments and blank lines and optional repeat of title line
    next if $line =~ /^\#/ || $line =~ /^\s*$/ || $line =~ /^\+/;
    #split each line into array
    my @line = split(/\s+/, $line);
    $result{$line[0]}{yeartotal} += $line[1];
    $result{$line[0]}{earning} += $line[3] - $line[2];
}
于 2012-10-24T08:15:16.950 回答
3

您应该使用哈希，如下所示：

my %hash;
while (my $line = <>) {

    next if $line =~ /^#/;

    my ($name, $years, $risk, $total) = split /\s+/, $line;

    next unless defined $name and defined $years
            and defined $risk and defined $total;

    $hash{$name}{years}    += $years;
    $hash{$name}{risk}     += $risk;
    $hash{$name}{total}    += $total;
    $hash{$name}{earnings} += $total - $risk;
}

foreach my $name (sort keys %hash) {

    print "$name earned $hash{$name}{earnings} in $hash{$name}{years}\n";
}
于 2012-10-24T08:17:56.637 回答
2

探索 Perl 强大的命令行选项的好机会！:)

代码

注意：这段代码应该是一个命令行单行代码，但是这样读起来更容易一些。在将其写入适当的脚本文件时，您确实应该启用严格和警告并使用更好的名称。此版本不会在严格下编译，您必须声明our $d.

#!/usr/bin/perl -nal

# collect data
$d{$F[0]}{y} += $F[1];
$d{$F[0]}{e} += $F[3] - $F[2];

# print summary
END { print "$_:\tyears: $d{$_}{y},\tearnings: $d{$_}{e}" for sort keys %d }

输出

adam:   years: 20,  earnings: 430
bill:   years: 50,  earnings: 885

解释

我在这里使用了-n开关，它基本上可以让您的代码遍历输入记录（-l告诉它使用行）。该-a开关让 perl 将行拆分为数组@F。简化版：

while (defined($_ = <STDIN>)) {
    chomp $_;
    our(@F) = split(' ', $_, 0);

    # collect data
    $d{$F[0]}{y} += $F[1];
    $d{$F[0]}{e} += $F[3] - $F[2];
}

%d是一个以名称为键、hashrefs 为值的散列，其中包含年份 ( y) 和收益 ( e)。

该END块在完成输入行处理和输出后执行%d。

使用ODeparse查看实际执行的代码：

book:/tmp memowe$ perl -MO=Deparse tsv.pl
BEGIN { $/ = "\n"; $\ = "\n"; }
LINE: while (defined($_ = <ARGV>)) {
    chomp $_;
    our(@F) = split(' ', $_, 0);
    $d{$F[0]}{'y'} += $F[1];
    $d{$F[0]}{'e'} += $F[3] - $F[2];
    sub END {
        print "${_}:\tyears: $d{$_}{'y'},\tearnings: $d{$_}{'e'}" foreach (sort keys %d);
    }
    ;
}
tsv.pl syntax OK
于 2012-10-24T09:00:52.743 回答
0

它似乎是一个固定宽度的文件，我会用unpack它

于 2012-10-24T13:46:03.547 回答