2

我正在尝试格式化我的输出，使其看起来像在列中。我正在尝试使用printf函数。

这是我所拥有的：

printf("%s %10s %12s %10s\n", "Qty", "Desc.", "Unit \$", "Total");

for ($he = 0; $he <= 6; $he++) {
    if (@quantity[$he] != 0) {
        printf("%d %10s %12.2f %10.2f\n", @quantity[$he], @selections[$he], @prices[$he], @prices[$he] * @quantity[$he])
    }
}

我试图让循环if语句中的第二个 printffor与“Qty”、“Desc.”、“Unit \$”和“Total”对齐。

4

2 回答 2

1

您需要在两种格式中使用相同的数字：

printf("%3s %10s %15s %13s\n", "Qty", "Desc.", "Unit \$", "Total");

和

printf("%3d %10s %12.2f %10.2f\n", @quantity[$he], @selections[$he], @prices[$he], @prices[$he]*@quantity[$he])

注意 12.2 的意思是（12 位 + 1 点 + 2 位），这就是我在第一种格式中写 15 的原因。13号也是一样。

另请注意，您正在错误地访问数组元素。

而不是@quantity[$he]使用$quantity[$he]. 也就是说，将 替换@为$。

于 2012-10-23T20:26:28.190 回答
1

很久以前，Perl 主要用于格式化文件。尽管自 Perl 4.x 出现以来我还没有看到它在程序中使用过，但它仍然具有这些功能。

查看perlform文档、format函数和write函数。

我会给你一个关于代码是什么样子的例子，除非我已经多年没有这样做了。否则，使用该printf语句。您可以使用一种格式来限制文本字段的大小%-10.10s。这表示左对齐字符串，并将其填充到 10 个字符，但不超过 10 个字符。

我还建议你买一本关于现代Perl 的书。一个会教你参考的。

我已经重写了您的程序以使用引用。请注意，所有数据现在都在一个数组中，而不是分布在您希望将索引保持在一起的四个单独的数组中。

我可以通过说来谈论主菜。它更易于阅读和维护。$item[1]$item[1]->{ENTREE}

另请注意，我已经更改了您的for循环。在你的，你必须知道你有七个项目。如果您添加了新项目，则必须更改循环。在我的，我$#menu用来获取我的菜单的最后一个索引。然后我使用(0..$#menu)自动从 0 循环到@menu数组中的最后一项。

而且，当你在它的时候：

  • 注意printf语句格式。
  • 注意 和 的use strict;使用use warnings;。这将捕获很多错误。
  • 请注意我使用括号和花括号标记代码块的首选方式。这是首选方法。

而且，现在的程序：

use strict;
use warnings;

my @menu = (
    { ENTREE => "Hamburger",    PRICE => 3.49, QUANTITY => 3 },
    { ENTREE => "Frankfurter",  PRICE => 2.19, QUANTITY => 0 },
    { ENTREE => "French Fries", PRICE => 1.69, QUANTITY => 0 },
    { ENTREE => "Large Coke",   PRICE => 1.79, QUANTITY => 4 },
    { ENTREE => "Medium Coke",  PRICE => 1.59, QUANTITY => 0 },
    { ENTREE => "Small Coke",   PRICE => 1.39, QUANTITY => 0 },
    { ENTREE => "Onion Rings",  PRICE => 1.19, QUANTITY => 8 },
);

printf "%-3.3s %-10.10s %-6.6s %s\n\n", 'Qty', 'Desc.', 'Unit $', 'Total';

# Use $#menu to get the number of items in the array instead of knowing it's 6

foreach my $item (0..$#menu) {

    # Dereference $menu[$item] to make $menu_item a hash
    # This makes the syntax easier to read.
    my %menu_item = %{ $menu[$item] };

    if ( $menu_item{QUANTITY} ) {
        printf "%3d %-10.10s %9.2f %7.2f\n",
        $menu_item{QUANTITY}, $menu_item{ENTREE}, $menu_item{PRICE},
        $menu_item{QUANTITY} * $menu_item{PRICE};
    }
}

输出：

Qty Desc.      Unit $ Total

  3 Hamburger  3.49   10.47
  4 Large Coke 1.79    7.16
  8 Onion Ring 1.19    9.52
于 2012-10-24T00:22:07.943 回答