1

我正在寻找一些关于如何最好地解决我的问题的指导。

我有一个类似以下但规模更大的 XML 文档。

<NewDataSet>
  <Table Attri1="Attri1Val" Attri2="Attri2Val" Attri3="Attri3Val" Attri4="Attri4Val" Attri5="Attri5Val" Attri6="Attri6Val" Attri7="Attri7" />
</NewDataSet>

Attri2例如，我需要将某些属性从 Table 节点移动到 Table 节点中的Attri5元素中，但是我需要保持其余属性不变。

解决这个问题的最佳方法是什么？数据规模约为所示的3-4倍。

编辑：预期输出：

<NewDataSet>
  <Table Attri1="Attri1Val" Attri3="Attri3Val" Attri4="Attri4Val" Attri6="Attri6Val" Attri7="Attri7">
    <Attri2>Attri2Val</Attri2>
    <Attri5>Attri5Val</Attri5>
  </Table>
</NewDataSet>

复杂性并不是真正的问题，更多的是数据的规模以及处理它的最佳方法是什么。

4

2 回答 2

1

利用

<xsl:template match="@* | node()">
  <xsl:copy>
     <xsl:apply-templates select="@* | node()"/>
  </xsl:copy>
</xsl:template>

<xsl:template match="Table">
  <xsl:copy>
    <xsl:apply-templates select="@*[not(name() = 'Attri2') and not(name() = 'Attri5')]"/>
     <xsl:apply-templates select="@Attri2 | @Attri5 | node()"/>
  </xsl:copy>
</xsl:template>

<xsl:template match="Table/@Attri2 | Table/@Attri5">
 <xsl:element name="{name()}">
   <xsl:value-of select="."/>
 </xsl:element>
</xsl:template>

[编辑] 属性的名称比较有点难看，但可能对您的示例有用。我们真正需要的是@* execpt (@Attri2, @Attri5)，只有 XPath 2.0。使用 XPath 1.0 的等效项是

<xsl:template match="Table">
  <xsl:copy>
    <xsl:variable name="all-attributes" select="@*"/>
    <xsl:variable name="to-be-transformed" select="@Attri2 | @Attri5"/>
    <xsl:apply-templates select="$all-attributes[count(. | $to-be-transformed) != count($to-be-transformed)]"/>
     <xsl:apply-templates select="$to-be-transformed | node()"/>
  </xsl:copy>
</xsl:template>
于 2012-10-23T09:59:36.993 回答
0

此通用转换可以处理任何长度的任何属性集，其名称可以在转换外部指定：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:param name="pToTransform" select="'|Attri2|Attri5|'"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="Table">
  <xsl:copy>
      <xsl:apply-templates select=
         "@*[not(contains($pToTransform, concat('|',name(),'|')))] | node()"/>
      <xsl:apply-templates mode="makeElement"
        select="@*[contains($pToTransform, concat('|',name(),'|'))]"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="@*" mode="makeElement">
  <xsl:element name="{name()}" namespace="{namespace-uri()}">
   <xsl:value-of select="."/>
  </xsl:element>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于提供的 XML 文档时：

<NewDataSet>
    <Table Attri1="Attri1Val" Attri2="Attri2Val"
    Attri3="Attri3Val" Attri4="Attri4Val"
    Attri5="Attri5Val" Attri6="Attri6Val"
    Attri7="Attri7" />
</NewDataSet>

产生了想要的正确结果：

<NewDataSet>
   <Table Attri1="Attri1Val" Attri3="Attri3Val" Attri4="Attri4Val" Attri6="Attri6Val" Attri7="Attri7">
      <Attri2>Attri2Val</Attri2>
      <Attri5>Attri5Val</Attri5>
   </Table>
</NewDataSet>
于 2012-10-23T12:33:29.503 回答