8

我想知道是否有一种通用方法可以使用驱动器号（例如X:\foo\bar.txt）将路径解析为其等效的 UNC 路径，这可能是以下之一：

  • X:\foo\bar.txt如果X:是真正的驱动器（即硬盘、U 盘等）
  • \\server\share\foo\bar.txt是否X:安装了网络驱动器\\server\share
  • C:\xyz\foo\bar.txtifX:是SUBST命令映射X:到的结果C:\xyz

我知道有部分解决方案可以：

  1. 解析网络驱动器（参见例如问题 556649，它依赖于WNetGetUniversalName）

  2. 解析SUBST驱动器号（查看QueryDosDevice哪个按预期工作，但不返回本地驱动器或网络驱动器等事物的 UNC 路径）。

我是否错过了在 Win32 中实现此驱动器号解析的一些直接方法？还是我真的必须把两者都搞砸WNetGetUniversalName才能QueryDosDevice得到我需要的东西？

4

2 回答 2

6

这是将驱动器号转换为 UNC 路径或反向替换路径的批处理。不保证它的工作原理。

使用示例：script.cmd echo Z: Y: W:

@echo off
:: u is a variable containing all arguments of the current command line
set u=%*

:: enabledelayedexpansion: exclamation marks behave like percentage signs and enable
:: setting variables inside a loop
setlocal enabledelayedexpansion

:: parsing result of command subst
:: format:  I: => C:\foo\bar
:: variable %G will contain I: and variable H will contain C:\foo\bar
for /f "tokens=1* delims==> " %%G IN ('subst') do (
set drive=%%G
:: removing extra space
set drive=!drive:~0,2!
:: expanding H to a short path in order not to break the resulting command line
set subst=%%~sfH
:: replacing command line.
call set u=%%u:!drive!=!subst!%%
)

:: parsing result of command net use | findstr \\ ; this command is not easily tokenized because not always well-formatted
:: testing whether token 2 is a drive letter or a network path.
for /f "tokens=1,2,3 delims= " %%G IN ('net use ^| findstr \\') do (
set tok2=%%H
if "!tok2:~0,2!" == "\\" (
  set drive=%%G
  set subst=%%H
) else (
  set drive=%%H
  set subst=%%I
)
:: replacing command line.
call set u=%%u:!drive!=!subst!%%
)

call !u!
于 2011-01-12T14:50:13.913 回答
4

是的，您需要独立解析驱动器号。

WNetGetUniversalName()接近，但仅适用于映射到实际 UNC 共享的驱动器号，但情况并非总是如此。没有一个 API 函数可以为您完成所有工作。

于 2009-08-20T00:24:43.750 回答