2

我正在研究由多个响应问题组成的数据集。我想对所有变量运行计数频率并合并图表，以便显示选中该框的人的百分比。我无法弄清楚如何让 SPSS 进行多次计数并合并输出图。有人有一些见识吗？

数据集成立

q1 q2 q3 q4 q5
1  -  1  1  1
1  1  1  1  1
1  1  -  1  1
1  -  -  1  -

所以我试图输出的图表将包含变量并输出：

q1==== 100%
q2==    50%
q3==    50%
q4==== 100%
q5===  75%

我曾尝试将响应合并到一个变量，但这会导致未对齐数据。这可以通过重新编码来实现吗？

4

3 回答 3

2

使用数据 > 定义多个响应集，而不是 MULT RESPONSE。然后您可以在图表生成器中使用多响应变量，如果您有自定义表格选项，您也可以在构建表格时使用它。但是，以这种方式定义的集合定义不能在 MULT RESPONSE 过程中使用。

于 2012-10-19T13:05:25.827 回答
2

为了说明Jon和 Lanelor 的出色建议，从您的数据开始；

data list fixed / q1 TO q5 1-5.
begin data
1  111
11111
11 11
1  1 
end data.
dataset name mr.

我通常不会将其保留为缺失数据，而是在缺少值的情况下重新编码为零（这会改变图表中案例的处理方式 - 所以它确实会产生影响）；

recode q1 TO q5 (SYSMIS = 0).

然后，您可以定义多个响应集并将其包含在通过图表构建器构建的图表中。

* Define Multiple Response Sets.
MRSETS
  /MDGROUP NAME=$qs CATEGORYLABELS=VARLABELS VARIABLES=q1 q2 q3 q4 q5 VALUE=1
  /DISPLAY NAME=[$qs].

*Make the chart - can use chart builder GGRAPH to include multiple response sets.
GGRAPH
  /GRAPHDATASET NAME="graphdataset" VARIABLES=$qs[name="qs"] COUNT()[name=
  "COUNT"] MISSING=LISTWISE REPORTMISSING=NO
  /GRAPHSPEC SOURCE=INLINE.
BEGIN GPL
 SOURCE: s=userSource(id("graphdataset"))
 DATA: qs=col(source(s), name("qs"), unit.category())
 DATA: COUNT=col(source(s), name("COUNT"))
 GUIDE: axis(dim(1), label("$qs"))
 GUIDE: axis(dim(2), label("Count"))
 SCALE: cat(dim(1), include("q1", "q2", "q3", "q4", "q5"))
 SCALE: linear(dim(2), include(0))
 ELEMENT: interval(position(qs*COUNT), shape.interior(shape.square))
END GPL.

同样，如果创建Lanelor建议的表；

MULT RESPONSE GROUPS=$q1toq5 (q1 q2 q3 q4 q5 (1))
  /FREQUENCIES=$q1toq5.

您可以在表格中选择所需的统计数据，然后右键单击并从这些选择中生成一个图表（在屏幕截图之后，它包括它在我的机器上使用我的个人图表模板生成的图表）；

在此处输入图像描述

在此处输入图像描述

GGRAPH 和 MRSETS 命令更强大，允许对绘图进行更多自定义，但 Lanelor 的建议对于一些快速 EDA 来说是很好的。

于 2012-10-19T13:26:19.317 回答
1

从菜单中：Analyze->Multiple Response->Define Variable Set->Move to "Selected" q1 to q5，检查二分法类型并输入要计数的数字（在示例中为 1）。选择一个名称并确认。然后Analyze->Multiple Response->Frequencies-> /name of the created set/。

如果您必须重复许多变量，请查看 SPSS 中的语法编码，例如：

MULT RESPONSE GROUPS=$q1toq5 (q1 q2 q3 q4 q5 (1))
  /FREQUENCIES=$q1toq5.
于 2012-10-19T12:57:45.463 回答