2

假设我的 AS 代码中有以下设置：

var color:String = "#0000FF"; //blue
var alpha:Number = 42; //42% or 42/100

我如何将它们组合成#RRGGBBAA十六进制颜色？我一直在谷歌搜索并试图找出十六进制转换和符号，但没有运气。

4

2 回答 2

8

有两种方法可以做到这一点。使用 int 的toString()方法并将 16 作为基数/基数传递有点 hacky ：

var rgb:int = (int)("#0000FF".replace("#","0x"));//convert the string to a int (note you can type hex ints starting with 0x (e.g. 0x0000FF)
var a:int = 42;
var rgba:int = int("0x"+rgb.toString(16) + a.toString(16));

或使用按位运算符的不太复杂且可能更快的计算方法：

var rgb:uint = (uint)("#0000FF".replace("#","0x"));
//extract components using bit shifting (>>) and masking (0xFF)
var r:uint = rgb >> 16 & 0xFF;
var g:uint = rgb >>  8 & 0xFF;
var b:uint = rgb >>  0 & 0xFF;//same as rgb >> 0xFF, just added >> 0 to make the shift obvious
var a:uint = 42;
var rgba:uint = r << 24 | g << 16 | b << 8 | a;
var argb:uint = a << 24 | r << 16 | g << 8 | b;
//test
trace(rgba.toString(16));
trace(argb.toString(16));

请注意，toString(16)在上面的跟踪中使用是为了使其对我们人类有用，在使用十六进制颜色值时，您将使用实际的 uint 值。

另请注意，有时您可能希望在 as3 中使用 ARGB，例如在使用BitmapData时：

addChild(new BitmapData(100,100,true,0x2a0000ff));//add a 42% transparent blue box (100x100 px)

更新

上面的 bitshift 代码片段实际上详细解释了 rgb 提取，这有助于更好地理解事物，但是您已经有了 rgb，所以只需添加 alpha 分量即可。您还提到了 42%，这与 0 到 255 的比例不同。因此，下面是您的答案：

var rgb:uint = (uint)("#0000FF".replace("#","0x"));
var   a:uint = (uint)((42 * .01) * 255);//map 42 from 0<>100 to 0<>255 ( *.01 is the same as / 100 but faster
var rgba:uint = rgb << 8 | a;
var argb:uint = a << 24 | rgb;

关于速度，如果我运行这两种不同的转换方法一百万次，这里是执行时间：

using strings (var rgba:int = int("0x"+rgb.toString(16) + a.toString(16));) takes 851 ms 
using bitwise ops (var rgba:uint = rgb << 8| a;) takes 3 ms

如您所见，按位版本比字符串版本更快，并且对于您的情况甚至更简洁。此外，既然您了解了按位运算符，可能更容易阅读/理解。

综上所述：

var color:String = "#0000FF"; //blue
var alpha:Number = 42; //42% or 42/100
var rgb:uint = (uint)(color.replace("#","0x"));
var   a:uint = (uint)((alpha * .01) * 255);
var rgba:uint = rgb << 8 | a;
trace("hex: #",rgba.toString(16),"test",0x0000ff6b.toString(16));

此外，您提到 Google 很有趣，因为您可以使用搜索转换为 hex。

更新：似乎有点混乱，所以我将 3 个步骤拆分为函数：

  1. 将十六进制字符串转换为 int
  2. 将 alpha 百分比 (0-100) 转换为 0-255 int
  3. 连接以上

这将是：

function getHex(hexStr:String):uint{
    return (uint)(hexStr.replace("#","0x"));
}
function getHexAlpha(alpha:uint):uint{
    return (uint)((alpha * .01) * 255);
}
function rgbaConcat(rgb:uint,a:uint):uint{
    return rgb << 8 | a;
}
trace("test",rgbaConcat(getHex("#FF9900"),getHexAlpha(50)).toString(16));

或一口气：

function rgbaConcat(hexStr:String,alpha:uint):uint{
    var rgb:uint = (uint)(hexStr.replace("#","0x"));
    var a:uint = (uint)((alpha * .01) * 255);
    return (rgb << 8 | a);
}
trace("test",rgbaConcat("#123456",100).toString(16));
于 2012-10-18T04:04:47.603 回答
2

我不确定 sprintf 或类似的东西在动作脚本中是否可用，但你会使用类似的东西：

var alpha_2:int = Math.round(255*alpha/100);
var rgba:String = sprintf("%s%2x", color, alpha_2);

#RRGGBBAA顺便说一句，一定要检查它是否应该是#AARRGGBB

所以显然 sprintf 不可用，您可以使用动作脚本 3 中是否有类似 printf 中提到的一些替代品？

如果您不喜欢使用类似 printf 的功能，可以使用：

function hex_char(value:int) {
  if (value < 0)
    return "X";
  if (value < 10)
    return String.fromCharCode("0".charCodeAt(0)+value);
  if (value < 16)
    return String.fromCharCode("A".charCodeAt(0)+value-10);
  return "X";
}

var alpha_2:int = Math.round(255*alpha/100);
var rgba:String = color + hex_char(alpha_2/16) + hex_char(alpha_2%16);

或者，您可以使用以下定义（我假设）将为您提供低于或高于hex_char的任何值的异常/错误，而不是015"X"

function hex_char(value:int) {
  return "0123456789ABCDEF".charAt(value);
}
于 2012-10-18T03:14:14.643 回答