1

在 xquery 表达式中，我在 for 表达式中获得了一组值，其中一个值位于单独的变量中。

现在，我想从列表的第一个值中减去单个值，然后从彼此中减去列表的连续成员——在结果集的差值中，我想获得最小/最大值......

到目前为止的查询看起来像这样 -

let $value1:= 1998
let $rows_citations:= 
         $doc//div[@id="patent_citations"]
                     /div[@id="patent_citations_v"]
                          /table[@class="rel_patent"]
                             /tbody/tr[1]
                                      /following-sibling::tr
for $pos in $rows_citations/position()
let $date2_c := customfn:dateconverter1($rows_citations[$pos]/td[3])

现在我想要的减法是在第一个值date2_c和值 1 之间，然后在...的连续成员之间date2_c，从结果列表中我想要最小/最大值...我该怎么做呢？

我是特别的。对创建一个存储所有差异的新列表变量感到困惑，尤其是。当我们已经在一个 for 循环中，并且正在迭代列表的每个值时（通过变量 date2_c）

4

1 回答 1

2

I. 这个 XQuery 3.0 查询（也是一个纯 XPath 3.0 表达式）：

let $pVal := 1,
    $vList := (2,4,7,11,16),
    $vList2 := ($pVal, subsequence($vList, 1, count($vList)-1)),
    $vSubtactedList :=
            map-pairs(function($m as xs:integer, $n as xs:integer) as xs:integer
                        {
                         $m - $n
                        },
                        $vList,
                        $vList2
                      )
    return
      (min($vSubtactedList), max($vSubtactedList))

从减法列表中产生想要的结果最小值和最大值：

1 5

二、XQuery 1.0 解决方案：

let $pVal := 1,
    $vList := (2,4,7,11,16),
    $vList2 := ($pVal, subsequence($vList, 1, count($vList)-1)),
    $vSubtactedList :=
                for $i in 1 to count($vList)
                 return
                    $vList[$i] - $vList2[$i]

 return
    (min($vSubtactedList), max($vSubtactedList))

这再次产生相同的正确结果：

1 5
于 2012-10-17T18:30:40.227 回答