2

第一次在这里海报。

所以我正在构建一个“多 RSS 提要阅读器”，并将其分为 2 个类，一个“TechFeed.as”和一个“Feed.as”；技术提要通过将 URL 传递给新的提要对象来实例化多个提要。

我目前的问题是在 Feed.as 中有几个公共变量，它们在 TechFeed.as 中用于显示有关提要的基本详细信息，但是，这些变量拒绝保留我在 Feed.as 的函数中赋予它们的任何值，并且出现“空”。

编辑：也许还有一些需要注意的地方；TechFeed.as 是舞台使用的主要 AS 文件。

TechFeed.as

package  {

    import flash.display.MovieClip;

    public class TechFeed extends MovieClip {

        private var feed_one:Feed = new Feed("http://feeds.feedburner.com/crunchgear");
        private var feed_two:Feed = new Feed("http://feeds.mashable.com/Mashable");
        private var feed_three:Feed = new Feed("http://www.engadget.com/rss.xml");

        public function TechFeed() {
            trace(feed_one.feed_title);

            //feed_name.text = feed_one.getFeedTitle();
        }

    }

}

饲料.as

package  {

    import flash.net.URLLoader;
    import flash.events.Event;
    import flash.net.URLRequest;

    public class Feed {

        //Public variables to display feed info
        public var feed_title:XMLList;
        public var feed_desc:String;
        public var feed_link:String;

        //Setting up variables which help load the feeds

        private var feedXML:XML;
        //Create a loader to load an external URL
        private var loader:URLLoader = new URLLoader();


        public function Feed(inURL:String = "") {
            //Load the xml document
            loader.load(new URLRequest(inURL));
            loader.addEventListener(Event.COMPLETE,onLoaded);
        }

        //When the loader had loaded the xml document, pass that into a variable for use. 
        private function onLoaded(e:Event):void {
            feedXML = new XML(e.target.data);

            // break down the xml document elements into singular XML array lists

            //Feed details
            this.feed_title = feedXML.channel.title;
            this.feed_link = feedXML.channel.link;
            this.feed_desc = feedXML.channel.description;

            trace(this.feed_title);

        }

    }

}

任何帮助将不胜感激 ：）

谢谢，杰夫

4

2 回答 2

1

如果问题是feed_one.feed_title在 TechFeed() ctor 中出现 null，那是因为您没有等待提要完成加载。您要做的是在完成加载和处理数据后从 Feed 发送一个事件，在 TechFeed 中捕获它，然后随意使用公共变量（这也意味着您的 Feed 类必须继承 EventDispatcher）：

在 Feed 类中：

private function onLoaded(e:Event):void {
            feedXML = new XML(e.target.data);

            // break down the xml document elements into singular XML array lists

            //Feed details
            this.feed_title = feedXML.channel.title;
            this.feed_link = feedXML.channel.link;
            this.feed_desc = feedXML.channel.description;

            trace(this.feed_title);
            dispatchEvent(new Event(Event.COMPLETE));////Dispatch Event

        }

在 TechFeed 类中：

public function TechFeed() {
            trace(feed_one.feed_title);//This will trace "null"
            feed_one.addEventListener(Event.COMPLETE, dataLoaded);//add event listener
        }
private function dataLoaded(e:Event):void{
            var feed = Feed(e.currentTarget);
            feed.removeEventListener(Event.COMPLETE, dataLoaded);//remove event listener to prevent memory leaks
            trace(feed.feed_title);// This will trace the correct title
        }
于 2012-10-17T06:17:56.750 回答
1

您的问题是您尝试在从服务器返回数据之前从提要写入数据的时间。
在此示例中，我分配了一个函数以在加载数据时进行回调。

包裹 {

    import flash.display.MovieClip;

    public class TechFeed extends MovieClip {

        private var feed_one:Feed;
        private var feed_two:Feed;
        private var feed_three:Feed;

        public function TechFeed() {
          feed_one= new Feed("http://feeds.feedburner.com/crunchgear",assignResults);
          feed_two= new Feed("http://feeds.mashable.com/Mashable",assignResults);
          feed_three= new Feed("http://www.engadget.com/rss.xml",assignResults);


        }

        public function assignResults(value:value):void{
          feed_name.text = value;
        }

    }

}






package  {

    import flash.net.URLLoader;
    import flash.events.Event;
    import flash.net.URLRequest;

    public class Feed {

        //Public variables to display feed info
        public var feed_title:XMLList;
        public var feed_desc:String;
        public var feed_link:String;

        //Setting up variables which help load the feeds

        private var feedXML:XML;
        //Create a loader to load an external URL
        private var loader:URLLoader = new URLLoader();

private var _callBackFunc:Function;
        public function Feed(inURL:String = "", callBackFunc:Function) {


           this._callBackFunc = callBackFunc;


            //Load the xml document
            loader.load(new URLRequest(inURL));
            loader.addEventListener(Event.COMPLETE,onLoaded);
        }

        //When the loader had loaded the xml document, pass that into a variable for use. 
        private function onLoaded(e:Event):void {
            feedXML = new XML(e.target.data);

            // break down the xml document elements into singular XML array lists

            //Feed details
            this.feed_title = feedXML.channel.title;
            this.feed_link = feedXML.channel.link;
            this.feed_desc = feedXML.channel.description;

            this._callBackFunc(this.feed_title);

        }

    }

}
于 2012-10-17T13:53:33.373 回答