arrays - 如何比较压缩数组

Question

我有一组像这样打包的数组：

sub pack_key {
     return pack 'N' . ('w/a*' x @_), scalar(@_), @_;
}

因为我将它们用作散列中的多值键（即：散列的键是数组）。

有没有什么快速的方法来比较打包数组中的前 n 个元素是否相同？或者相反 - 比较最后 m 个元素是否不同？

有一个明显的解决方案，即解包，并使用 smartmatch 运算符 (~~)，但我正在寻找直接在打包数组上运行的东西。

谢谢。

Answer 1

因为您已经打包了嵌入长度的任意长度数据，所以答案是否定的，没有快速的方法来比较两个字符串。您必须一次通过字符串一个组件。

这是一个有效的解决方案。

警告：这取决于您使用单字节字符编码安装 Perl。这通常是正确的，但如果不是，请查看Encode以确保这些字符串被视为字节。

use strict;
use warnings;

my @arr1 = (1,2,3,4,5);
my @arr2 = (1,2,3,4,8);

sub pack_key {
     return pack 'N' . ('w/a*' x @_), scalar(@_), @_;
}

sub n_elements_equal {
    my ($compare_length,$k1,$k2) = @_;
    my $length1 = unpack('N',$k1);
    my $length2 = unpack('N',$k2);
    if ($length1<$compare_length or $length2<$compare_length) { return 0; }

    my $curr_pos = 4;
    my $curr_element = 1;

    while ($curr_element++ <= $compare_length)
    {
        my $el1 = unpack('w/a*',substr($k1,$curr_pos));
        my $el2 = unpack('w/a*',substr($k2,$curr_pos));
        if ($el1 ne $el2) { return 0; }
    $curr_pos += (unpack('w',substr($k1,$curr_pos)) + 1);       
    }
    return 1;
}

my $key1 = pack_key(@arr1);
my $key2 = pack_key(@arr2);

for (1..5)
{
    print "First $_ elements are " . 
        (n_elements_equal($_,$key1,$key2) ? '' : 'not ') . "equal.\n"; 
}

这比仅仅打开包装并进行智能匹配更好吗？如果您的数组真的很长，那么它会更快，因为您不必解压缩整个数组。它只遍历字符串，直到确定匹配状态。如果数组不是很长，它可能不会为您节省任何东西。

最好通过更改设计来解决这个问题。但这取决于你在做什么。