问问题
7238 次
1 回答
10
例如，您可以使用IHTMLSelectElement接口及其selectedIndex属性。作为展示，我制作了以下功能。
SelectOptionByValue 函数
以下函数尝试在指定元素（下拉列表）中查找并选择（如果找到）<option>给定属性值的（下拉列表项）。如果没有找到，则清除当前下拉列表选择（未选择任何项目）。value<select><option>
参数：
- ADocument - 输入 HTML 文档的接口
- AElementID -
<select>元素的 ID（下拉列表的元素 ID） - AOptionValue - 搜索
<option>到的元素值（下拉列表项的值）
返回值：
如果成功找到（并选择）<option>带有给定value的选项，则返回值是指定下拉列表中该选项的索引，否则返回-1。
源代码：
function SelectOptionByValue(const ADocument: IDispatch; const AElementID,
AOptionValue: WideString): Integer;
var
HTMLDocument: IHTMLDocument3;
HTMLElement: IHTMLSelectElement;
function IndexOfValue(const AHTMLElement: IHTMLSelectElement;
const AValue: WideString): Integer;
var
I: Integer;
begin
Result := -1;
for I := 0 to AHTMLElement.length - 1 do
if (AHTMLElement.item(I, I) as IHTMLOptionElement).value = AValue then
begin
Result := I;
Break;
end;
end;
begin
Result := -1;
if Supports(ADocument, IID_IHTMLDocument3, HTMLDocument) then
begin
if Supports(HTMLDocument.getElementById(AElementID), IID_IHTMLSelectElement,
HTMLElement) then
begin
Result := IndexOfValue(HTMLElement, AOptionValue);
HTMLElement.selectedIndex := Result;
end;
end;
end;
示例用法：
thirdvalue要从问题中的 HTML 文档的下拉列表中选择具有值的项目，可以使用此代码（假设在WebBrowser1此处的组件中加载了该文档）：
procedure TForm1.Button1Click(Sender: TObject);
var
Index: Integer;
begin
Index := SelectOptionByValue(WebBrowser1.Document, 'ComboBox', 'thirdvalue');
if Index <> -1 then
ShowMessage('Option was found and selected on index: ' + IntToStr(Index))
else
ShowMessage('Option was not found or the function failed (probably due to ' +
'invalid input document)!');
end;
来自问题的示例 HTML 文档：
<html>
<body>
<select id="ComboBox">
<option value="firstvalue">First Value</option>
<option value="secondvalue">Second Value</option>
<option value="thirdvalue">Third Value</option>
</select>
</body>
</html>
于 2012-10-13T18:32:35.927 回答