4

我是 xslt 的新手。我有一个像

<EmpCollection>
<Emp>
<Name>Sai</Name>
<Sal>7000</Sal>
</Emp>
<Emp>
<Name>Nari</Name>
<Sal>7400</Sal>
</Emp>
<Emp>
<Name>Hari</Name>
<Sal>9000</Sal>
</Emp>
<Emp>
<Name>Suri</Name>
<Sal>8900</Sal>
</Emp>
</EmpCollection>

现在我想在不使用 sum() 函数的情况下添加工资总和。我想以清晰的方式学习 xslt :-)

4

2 回答 2

1

I. 可能是最简单的解决方案之一：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="Sal">
  <xsl:param name="pSum" select="0"/>
     <xsl:apply-templates select="following::Sal[1]">
       <xsl:with-param name="pSum" select="$pSum + ."/>
     </xsl:apply-templates>
 </xsl:template>

 <xsl:template match="Sal[not(following::Sal)]">
  <xsl:param name="pSum" select="0"/>
  <xsl:value-of select="$pSum + ."/>
 </xsl:template>

 <xsl:template match="/">
  <xsl:apply-templates select="descendant::Sal[1]"/>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于提供的 XML 文档时：

<EmpCollection>
    <Emp>
        <Name>Sai</Name>
        <Sal>7000</Sal>
    </Emp>
    <Emp>
        <Name>Nari</Name>
        <Sal>7400</Sal>
    </Emp>
    <Emp>
        <Name>Hari</Name>
        <Sal>9000</Sal>
    </Emp>
    <Emp>
        <Name>Suri</Name>
        <Sal>8900</Sal>
    </Emp>
</EmpCollection>

产生了想要的正确结果：

32300

二、更通用的解决方案是使用FXSL 2.xf:foldl()函数，如下所示：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:f="http://fxsl.sf.net/" exclude-result-prefixes="f">
   <xsl:import href="../f/func-foldl.xsl"/>
   <xsl:import href="../f/func-Operators.xsl"/>

   <xsl:output  encoding="UTF-8" omit-xml-declaration="yes"/>

    <xsl:template match="/">
      <xsl:value-of select="f:foldl(f:add(), 0, /*/*/Sal)"/>
    </xsl:template>
</xsl:stylesheet>

当这个 XSLT 2.0 转换应用于同一个 XML 文档（上图）时，会产生相同的正确和想要的结果：

32300

您可以将任何两个参数的函数作为参数传递给f:foldl()并产生不同问题的解决方案。

例如，传递f:mult()而不是f:add()（并将“零”参数更改为1）产生薪水的乘积：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:f="http://fxsl.sf.net/" exclude-result-prefixes="f">
   <xsl:import href="../f/func-foldl.xsl"/>
   <xsl:import href="../f/func-Operators.xsl"/>

   <xsl:output  encoding="UTF-8" omit-xml-declaration="yes"/>

    <xsl:template match="/">
      <xsl:value-of select="f:foldl(f:mult(), 1, /*/*/Sal)"/>
    </xsl:template>
</xsl:stylesheet>

将此转换应用于同一个 XML 文档的结果现在是所有Sal元素的乘积：

4.14918E15

三、在 XSLT 3.0 (XPath 3.0) 中，可以以与前一个解决方案完全相同的方式使用标准fold-left()或 fold-right()函数。

于 2012-10-11T12:00:52.163 回答
0

可能有更优雅的方式（我猜sum()：），但以下工作，通过“折叠”兄弟姐妹加法。终止条件是最后一个兄弟节点（即没有后续节点）

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                version="1.0">
    <xsl:output method="xml" omit-xml-declaration="yes"/>

    <xsl:template match="/EmpCollection">
        <result>Result Is : <xsl:apply-templates select="Emp[1]"/>
        </result>
    </xsl:template>

    <xsl:template match="Emp[following-sibling::Emp]">
        <xsl:variable name="salThis">
            <xsl:value-of select="Sal"/>
        </xsl:variable>
        <xsl:variable name="salOthers">
            <xsl:apply-templates select="following-sibling::Emp[position()=1]"/>
        </xsl:variable>
        <xsl:value-of select="$salThis + $salOthers"/>
    </xsl:template>

    <!--Termination - the last employee just returns its salary value-->
    <xsl:template match="Emp[not(following-sibling::Emp)]">
        <xsl:value-of select="Sal"/>
    </xsl:template>
</xsl:stylesheet>

给出结果：

<result>Result Is : 32300</result>

编辑

再次阅读您的问题后，我想这不是代码高尔夫问题？下面是使用硬编码元素名称执行此操作的更简单方法，它指示处理器将指定员工的工资加在一起：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                version="1.0">
    <xsl:output method="xml" omit-xml-declaration="yes"/>

    <xsl:template match="/EmpCollection">
        <result>
            Result Is : <xsl:value-of select="Emp[Name='Sai']/Sal + Emp[Name='Nari']/Sal + Emp[Name='Hari']/Sal + Emp[Name='Suri']/Sal"/>
        </result>
    </xsl:template>

</xsl:stylesheet>

然后应该很容易理解sum()正在做什么：

<xsl:template match="/EmpCollection">
    <result>
        Result Is : <xsl:value-of select="sum(Emp/Sal)"/>
    </result>
</xsl:template>

编辑

计数很简单：

<xsl:template match="/EmpCollection">
    <result>
        <xsl:text>Count Is : </xsl:text>
        <xsl:value-of select="count(Emp)"/>
    </result>
</xsl:template>

做到这count()一点并不那么简单。请注意，xsl:variables 一旦分配就不能更改（不可变）。所以以下根本不起作用。

<xsl:template match="/EmpCollection">
    <xsl:variable name="count" select="0" />
    <xsl:for-each select="Emp">
        <!--NB : You can't do this. Variables are immutable - XSLT is functional -->
        <xsl:variable name="count" select="$count + 1"></xsl:variable>
    </xsl:for-each>
    <result>
        Result Is : <xsl:value-of select="$count"/>
    </result>
</xsl:template>

因此，您可以“循环”所有节点，然后用于position()确定这是否是序列中的最后一个节点。（请注意，我们已经使用过for-each，但实际上最好使用 use apply-template）

<xsl:template match="/EmpCollection">
    <result>
        <xsl:text>Count Is : </xsl:text>
        <xsl:for-each select="Emp">
            <xsl:if test="position() = last()">
                <xsl:number value="position()" format="1" />
            </xsl:if>
        </xsl:for-each>
    </result>
</xsl:template>

:(

于 2012-10-11T08:20:16.900 回答