groovy - Groovy TimeCategory 坏毫秒加法

Question

尝试此示例代码时：

use(groovy.time.TimeCategory) {
    800.millisecond + 300.millisecond
}

在 groovy web控制台中，我得到了一个有趣的结果：

0.1100 seconds

有谁知道为什么会发生这种情况或如何解决？

Answer 1

这看起来像一个错误， TimeDuration 包含 1100 毫秒，但是当它打印出来时，它错误地将其转换为秒。

我已将它作为错误添加到 Groovy JIRA

同时，我想你需要自己做从 TimeDuration 到 String 的转换器：-/

---

编辑

你可以做这样的事情（并且可能有一种更简洁的方法）

groovy.time.TimeDuration.metaClass.normalize = { ->
  def newdmap = ['days','hours','minutes','seconds','millis'].collectEntries { 
    [ (it):delegate."$it" ]
  }.with { dmap ->
    [millis:1000,seconds:60,minutes:60,hours:24,days:-1].inject( [ dur:[ days:0, hours:0, minutes:0, seconds:0, millis:0 ], roll:0 ] ) { val, field ->
      val.dur."$field.key" = dmap."$field.key" + val.roll
      val.roll = val.dur."$field.key".intdiv( field.value )
      val.dur."$field.key" = field.value < 0 ?
                               val.dur."$field.key" :
                               val.dur."$field.key" % field.value
      val
    }.dur
  }
  new TimeDuration( newdmap.days, newdmap.hours, newdmap.minutes, newdmap.seconds, newdmap.millis )
}

这将一个normalize方法添加到TimeDuration，然后执行以下操作：

use(groovy.time.TimeCategory) {
    800.millisecond + 300.millisecond
}.normalize()

节目1.100 seconds

我没有对该方法进行大量测试，因此请注意它可以通过一些单元测试来确保它不会因其他情况而崩溃。