1

我目前正在使用一本名为 Cuda by Example 的书参加并行计算课程。在本书的第 4 章中，我使用了一些包含“GL/glut.h”和“GL/gext.h”的 .h 文件，我有在线安装 GLUT 的步骤，并遵循了这些步骤。我认为这行得通，但我不确定。然后我试图找到 glext 的方向，但我似乎找不到那么多。我确实找到了一个 .h 文件，并尝试通过将其包含在 GL 文件夹中来使用它。这似乎不起作用，因为我在编译类似的东西时收到错误：

错误 1 ​​错误：不允许从设备调用主机函数（“cuComplex::cuComplex”）/_全局_ 函数（“julia”） C:\Users\Laptop\Documents\Visual Studio 2010\Projects\Lab1\Lab1 \lab1.cu 29 1 实验室1

我认为这是因为我需要更多的 glext.h，比如 .dll 和类似于 glut 的东西，但我不确定。对此的任何帮助将不胜感激。谢谢你。

编辑： - 这是我正在使用的代码，除了前两个包含语句和 .h 文件来自谷歌代码之外，我没有改变我在书中看到的内容：谢谢你的帮助

#include "cuda_runtime.h"
#include "device_launch_parameters.h"
#include "book.h"
#include "cpu_bitmap.h"

#define DIM 1000

struct cuComplex {
    float r;
    float i;
    cuComplex( float a, float b) : r(a), i(b) {}
    __device__ float magnitude2(void) {
        return r*r + i*i;
    }
    __device__ cuComplex operator* (const cuComplex& a) {
        return cuComplex(r*a.r - i*a.i, i*a.r + r*a.i);
    }
    __device__ cuComplex operator+ (const cuComplex& a) {
        return cuComplex(r+a.r, i+a.i);
    }
};

__device__ int julia( int x, int y) {
    const float scale = 1.5;
    float jx = scale * (float)(DIM/2 -x)/(DIM/2);
    float jy = scale * (float)(DIM/2 - y)/(DIM/2);

    cuComplex c(-0.8, .156);
    cuComplex a(jx, jy);

    int i = 0;
    for(i=0;i<200;i++) {
        a = a * a + c;
        if(a.magnitude2() > 1000)
            return 0;
    }

    return 1;
}

__global__ void kernel(unsigned char *ptr ) {
    //map from threadIdx/BlockIdx to pixel position
    int x = blockIdx.x;
    int y = blockIdx.y;
    int offset = x + y * gridDim.x;
    //now claculate the value at that position
    int juliaValue = julia(x,y);
    ptr[offset*4 + 0] = 255 * juliaValue;
    ptr[offset*4 + 1] = 0;
    ptr[offset*4 + 2] = 0;
    ptr[offset*4 + 3] = 255;
}

int main( void ) {
    CPUBitmap bitmap(DIM, DIM);
    unsigned char *dev_bitmap;
    HANDLE_ERROR(cudaMalloc((void**)&dev_bitmap, bitmap.image_size()));
    dim3    grid(DIM,DIM);
    kernel<<<grid,1>>>( dev_bitmap );
    HANDLE_ERROR( cudaMemcpy( bitmap.get_ptr(), dev_bitmap, bitmap.image_size(), cudaMemcpyDeviceToHost));
    bitmap.display_and_exit();
    HANDLE_ERROR( cudaFree( dev_bitmap ));
}
4

1 回答 1

2

尝试添加以下内容。

原始代码：

cuComplex( float a, float b) : r(a), i(b) {}

修改的：

__host__ __device__ cuComplex( float a, float b ) : r(a), i(b)  {}

它为我解决了这个问题。我也不需要您添加的两个包含文件，但您可能取决于您的构建过程。

CUDA 程序由两种类型的代码组成：主机代码和设备代码。主机代码运行在主机 CPU 上，不能运行在 GPU 上，设备代码运行在 GPU 上，不能运行在 CPU 上。如果您不以任何方式装饰您的程序，那么它将是所有主机代码。但是，一旦您开始添加由 __ global__ 或 __ device__ 等关键字描述的 CUDA 部分，那么您的程序将包含一些设备代码。

您收到的编译器错误表明设备上运行的函数正试图使用​​为 CPU 编译的代码。这是一个禁忌，编译器不允许这样做。这个例子是不寻常的，因为在某个时间点（当本书编写时）它可能没有产生这个错误，而且 cuComplex 结构中的代码似乎用 __ device__ 关键字修饰。但是，在我修改的代码行的结构的最外层，没有标识 __ device__ 的关键字。当我添加 __ device__ __ host__ 关键字时，这会告诉编译器“对于这个逻辑部分，创建代码的设备编译版本和主机编译版本”。这明确告诉编译器您希望能够在设备中使用这部分代码。加上这个，

显然，在这种情况下，编译器生成设备代码所需的装饰级别发生了一些变化。据推测，对于较旧的编译器，结构中的 __device__ 关键字足以让编译器知道它必须生成可由 cuComplex 类型调用的运算符的设备版本。

于 2012-10-07T23:00:37.117 回答