1

我正在尝试创建一个接收列表的函数，如果其中一个元素为负数，则该列表中与其正数对应的任何元素都应更改为 0。例如，如果有 -2在列表中，则该列表中的所有 2 都应更改为 0。

任何想法为什么它只适用于某些情况而不适用于其他情况？我不明白这是为什么，我已经看了好几遍了。

changeToZero [] = []
changeToZero [x] = [x]
changeToZero (x:zs:y:ws) | (x < 0) && ((-1)*(x) == y) = x : zs : 0 : changeToZero ws
changeToZero (x:xs) = x : changeToZero xs

changeToZero [-1,1,-2,2,-3,3]
-- [-1,1,-2,2,-3,3]

changeToZero [-2,1,2,3]
-- [-2,1,0,3]

changeToZero [-2,1,2,3,2]
-- [-2,1,0,3,2]

changeToZero [1,-2,2,2,1]
-- [1,-2,2,0,1]
4

3 回答 3

7

我认为列表理解更清晰，更容易在这里获得。

changeToZero xs = [if x > 0 && (-x) `elem` xs then 0 else x | x <- xs]

如果您需要更有效的东西，您可以构建一组负面元素并检查它而不是使用elem.

import qualified Data.Set as Set

changeToZero' xs = [if (-x) `Set.member` unwanted then 0 else x | x <- xs]
  where unwanted = Set.fromList $ filter (< 0) xs
于 2012-10-06T21:50:54.753 回答
2

好吧，以@jdevelop 的答案为基础，如果否定必须出现在肯定之前才能计数，那么您可以通过输入单次传递来构建结果，而无需反转它：

import qualified Data.Set as S
import Control.Monad.State

changeToZero :: [Int] -> [Int]
changeToZero xs = evalState (mapM f xs) S.empty where
  f x | x < 0     = modify (S.insert (-x)) >> return x
      | otherwise = gets (S.member x) >>= \hasNeg -> return $ if hasNeg then 0 else x

这样你就可以得到答案

take 4 $ changeToZero $ 1 : (-2) : 3 : 2 : undefined

其他解决方案将失败的地方。

** 编辑 **

这是同样的事情，但没有Statemonad，这样更容易理解：

changeToZero' :: [Int] -> [Int]
changeToZero' = go S.empty where
  go _ [] = []
  go s (x:xs) | x < 0        = x : go (S.insert (-x) s) xs
              | S.member x s = 0 : go s xs
              | otherwise    = x : go s xs
于 2012-10-07T18:50:56.033 回答
2

您实际上不记得您在列表中找到了哪些负面符号

import qualified Data.Set as S

changeToZero :: [Int] -> [Int]
changeToZero [] = []
changeToZero xs = reverse . snd $ foldl f (S.empty,[]) xs
  where
    f (negs,res) x | x < 0 = (S.insert (-x) negs, x:res)
                   | S.member x negs = (negs,0:res)
                   | otherwise = (negs,x:res)
于 2012-10-06T21:51:07.693 回答