1

我正在使用 SQL Server 2008。

我有很多表，每个表都包含ID字段和TheOrder字段。

我想创建一个存储过程，它可以交换TheOrder字段中两条记录的值。

我通过ASP.NET代码获取这些记录的ID ，并将它们传递给存储过程。

但是因为我想在很多表上执行这个存储过程，我必须使用动态 SQL 并从ASP.NET代码中传递表名。

我的存储过程代码是：

ALTER PROCEDURE [dbo].[SwapOrders]
    @TblName nvarchar(20)
    , @ID1 int
    , @ID2 int
AS
BEGIN
    DECLARE @ID1Str nvarchar(5)
    SET @ID1Str = CAST(@ID1 AS nvarchar)
    DECLARE @ID2Str nvarchar(5)
    SET @ID2Str = CAST(@ID2 AS nvarchar)
    DECLARE @Order1 nvarchar(5)
    DECLARE @Order2 nvarchar(5)
    DECLARE @Cmd nvarchar(100)
    /* Get orders */
    SET @Cmd = 'SELECT @Order1 = [TheOrder] FROM ' + @TblName + ' WHERE ID = ' + @ID1Str
    EXECUTE sp_executesql @Cmd, "@Order1 nvarchar(5) OUTPUT", @Order1 = [TheOrder]
    SET @Cmd = 'SELECT @Order2 = [TheOrder] FROM ' + @TblName + ' WHERE ID = ' + @ID2Str
    EXECUTE sp_executesql @Cmd, "@Order2 nvarchar(5) OUTPUT", @Order2 = [TheOrder]
    /* Update orders */
    SET @Cmd = 'UPDATE ' + @TblName + ' SET TheOrder = @Order2 WHERE ID = ' + @ID1Str
    EXECUTE sp_executesql @Cmd, "@Order2 nvarchar(5)", @Order2
    SET @Cmd = 'UPDATE ' + @TblName + ' SET TheOrder = @Order1 WHERE ID = ' + @ID2Str
    EXECUTE sp_executesql @Cmd, "@Order1 nvarchar(5)", @Order1
END
GO

当我测试这段代码时， TheOrder字段的两个值变为NULL。

问题是什么？

非常感谢您的帮助，我很抱歉提出很长的问题。

4

1 回答 1

1

看到这个工作演示

代码如下

CREATE PROCEDURE [dbo].[SwapOrders]
  @TblName nvarchar(20),
  @ID1 int,
  @ID2 int
AS
set nocount on
DECLARE @Cmd nvarchar(max) =
 'set nocount on;
  update t
  set TheOrder = u.TheOrder
  from ' + quotename(@tblname) + 't
  join ' + quotename(@tblname) + 'u on
  u.id=case when t.id=@id1 then @id2 else @id1 end
  where t.id in (@id1,@id2);';
exec sp_executesql @cmd, N'@id1 int,@id2 int', @id1, @id2;
GO
于 2012-10-06T03:58:35.147 回答