10

我有关于基于扭曲的并行减少的想法，因为根据定义，扭曲的所有线程都是同步的。

所以想法是输入数据可以减少 64 倍（每个线程减少两个元素），而无需任何同步。

与 Mark Harris 的原始实现相同，减少应用于块级，数据位于共享内存上。 http://gpgpu.org/static/sc2007/SC07_CUDA_5_Optimization_Harris.pdf

我创建了一个内核来测试他的版本和我的基于 warp 的版本。
内核本身完全相同地将 BLOCK_SIZE 元素存储在共享内存中，并在输出数组中的唯一块索引处输出其结果。

该算法本身运行良好。用完整的数组进行测试以测试“计数”。

实现的函数体：

/**
 * Performs a parallel reduction with operator add 
 * on the given array and writes the result with the thread 0
 * to the given target value
 *
 * @param inValues T* Input float array, length must be a multiple of 2 and equal to blockDim.x
 * @param targetValue float 
 */
__device__ void reductionAddBlockThread_f(float* inValues,
    float &outTargetVar)
{
    // code of the below functions
}

1.他的版本的实现：

if (blockDim.x >= 1024 && threadIdx.x < 512)
    inValues[threadIdx.x] += inValues[threadIdx.x + 512];
__syncthreads();
if (blockDim.x >= 512 && threadIdx.x < 256)
    inValues[threadIdx.x] += inValues[threadIdx.x + 256];
__syncthreads();
if (blockDim.x >= 256 && threadIdx.x < 128)
    inValues[threadIdx.x] += inValues[threadIdx.x + 128];
__syncthreads();
if (blockDim.x >= 128 && threadIdx.x < 64)
    inValues[threadIdx.x] += inValues[threadIdx.x + 64];
__syncthreads();

//unroll last warp no sync needed
if (threadIdx.x < 32)
{
    if (blockDim.x >= 64) inValues[threadIdx.x] += inValues[threadIdx.x + 32];
    if (blockDim.x >= 32) inValues[threadIdx.x] += inValues[threadIdx.x + 16];
    if (blockDim.x >= 16) inValues[threadIdx.x] += inValues[threadIdx.x + 8];
    if (blockDim.x >= 8) inValues[threadIdx.x] += inValues[threadIdx.x + 4];
    if (blockDim.x >= 4) inValues[threadIdx.x] += inValues[threadIdx.x + 2];
    if (blockDim.x >= 2) inValues[threadIdx.x] += inValues[threadIdx.x + 1];

    //set final value
    if (threadIdx.x == 0)
        outTargetVar = inValues[0];
}

资源：

使用了 4 个同步线程 使用了
12 个 if 语句
11 个读取 + 添加 + 写入操作
1 个最终写入操作
5 个寄存器使用

表现：

五次测试运行平均：~ 19.54 ms

2.基于Warp的方法：（与上面相同的函数体）

/*
 * Perform first warp based reduction by factor of 64
 *
 * 32 Threads per Warp -> LOG2(32) = 5
 *
 * 1024 Threads / 32 Threads per Warp = 32 warps
 * 2 elements compared per thread -> 32 * 2 = 64 elements per warp
 *
 * 1024 Threads/elements divided by 64 = 16
 * 
 * Only half the warps/threads are active
 */
if (threadIdx.x < blockDim.x >> 1)
{
    const unsigned int warpId = threadIdx.x >> 5;
    // alternative threadIdx.x & 31
    const unsigned int threadWarpId = threadIdx.x - (warpId << 5);
    const unsigned int threadWarpOffset = (warpId << 6) + threadWarpId;

    inValues[threadWarpOffset] += inValues[threadWarpOffset + 32];
    inValues[threadWarpOffset] += inValues[threadWarpOffset + 16];
    inValues[threadWarpOffset] += inValues[threadWarpOffset + 8];
    inValues[threadWarpOffset] += inValues[threadWarpOffset + 4];
    inValues[threadWarpOffset] += inValues[threadWarpOffset + 2];
    inValues[threadWarpOffset] += inValues[threadWarpOffset + 1];
}

// synchronize all warps - the local warp result is stored
// at the index of the warp equals the first thread of the warp
__syncthreads();

// use first warp to reduce the 16 warp results to the final one
if (threadIdx.x < 8)
{
    // get first element of a warp
    const unsigned int warpIdx = threadIdx.x << 6;

    if (blockDim.x >= 1024) inValues[warpIdx] += inValues[warpIdx + 512];
    if (blockDim.x >= 512) inValues[warpIdx] += inValues[warpIdx + 256];
    if (blockDim.x >= 256) inValues[warpIdx] += inValues[warpIdx + 128];
    if (blockDim.x >= 128) inValues[warpIdx] += inValues[warpIdx + 64];

    //set final value
    if (threadIdx.x == 0)
        outTargetVar = inValues[0];
}

资源：

使用了 1 个同步线程
7 if 语句
10 读取添加写入操作
1 最终写入操作
5 寄存器使用

5 位移位
1 加
1 子

表现：

五次测试运行平均：~ 20.82 ms

在具有256 mb 浮点值的Geforce 8800 GT 512 mb上多次测试两个内核。并以每块 256 个线程（100% 占用率）运行内核。

基于 warp 的版本慢了 ~ 1.28毫秒。

如果未来的卡允许更大的块大小，则基于 warp 的方法仍然不需要进一步的同步语句，因为最大值为 4096，它会减少到 64，而最终的 warp 会减少到 1

为什么它不快？或者这个想法的缺陷在哪里，内核？

从资源使用情况来看，翘曲方法应该领先吗？

Edit1：更正了内核只有一半线程处于活动状态，不会导致超出范围的读取，添加了新的性能数据

4

2 回答 2

12

我认为您的代码比我的代码慢的原因是，在我的代码中，在第一阶段，每个 ADD 活动的扭曲数量是其一半。在您的代码中，所有经线在所有第一阶段都处于活动状态。因此，总体而言，您的代码会执行更多的扭曲指令。在 CUDA 中，重要的是要考虑执行的总“warp 指令”，而不仅仅是一个 warp 执行的指令数。

此外，只使用一半的经线是没有意义的。启动经线只是为了让它们评估两个分支并退出有开销。

另一个想法是使用unsigned char并且short实际上可能会降低您的性能。我不确定，但它肯定不会为您节省寄存器，因为它们没有打包到单个 32 位变量中。

另外，在我的原始代码中，我用模板参数 BLOCKDIM 替换了 blockDim.x，这意味着它只使用了 5 个运行时 if 语句（第二阶段的 if 被编译器消除）。

顺便说一句，计算你的更便宜的方法threadWarpId是

const int threadWarpId = threadIdx.x & 31;

您可以查看这篇文章以获取更多想法。

编辑： 这是另一种基于扭曲的块减少。

template <typename T, int level>
__device__
void sumReduceWarp(volatile T *sdata, const unsigned int tid)
{
  T t = sdata[tid];
  if (level > 5) sdata[tid] = t = t + sdata[tid + 32];
  if (level > 4) sdata[tid] = t = t + sdata[tid + 16];
  if (level > 3) sdata[tid] = t = t + sdata[tid +  8];
  if (level > 2) sdata[tid] = t = t + sdata[tid +  4];
  if (level > 1) sdata[tid] = t = t + sdata[tid +  2];
  if (level > 0) sdata[tid] = t = t + sdata[tid +  1];
}

template <typename T>
__device__
void sumReduceBlock(T *output, volatile T *sdata)
{
  // sdata is a shared array of length 2 * blockDim.x

  const unsigned int warp = threadIdx.x >> 5;
  const unsigned int lane = threadIdx.x & 31;
  const unsigned int tid  = (warp << 6) + lane;

  sumReduceWarp<T, 5>(sdata, tid);
  __syncthreads();

  // lane 0 of each warp now contains the sum of two warp's values
  if (lane == 0) sdata[warp] = sdata[tid];

  __syncthreads();

  if (warp == 0) {
    sumReduceWarp<T, 4>(sdata, threadIdx.x);
    if (lane == 0) *output = sdata[0];
  }
}

这应该会更快一些，因为它使用了在第一阶段启动的所有经线，并且在最后阶段没有分支，代价是额外的分支、共享加载/存储和__syncthreads()新的中间阶段。我没有测试过这段代码。如果你运行它，请告诉我它的性能。如果您在原始代码中为 blockDim 使用模板，它可能会再次更快，但我认为这段代码更简洁。

请注意，使用临时变量t是因为 Fermi 和后来的架构使用纯加载/存储架构，因此+=从共享内存到共享内存会导致额外的负载（因为sdata指针必须是易失的）。一次显式加载到临时文件中可以避免这种情况。在 G80 上，它不会对性能产生影响。

于 2012-10-04T23:37:34.560 回答
0

您还应该检查 SDK 中的示例。我记得一个很好的例子，它实现了几种减少方法。其中至少一个也使用基于扭曲的减少。

（我现在无法查找名称，因为我只将它安装在我的另一台机器上）

于 2012-10-05T00:06:17.537 回答