我还在学习 Perl。谁能建议我使用 Perl 代码来比较 .tar.gz 中的文件和目录路径。
假设我有几天前采取的以下目录路径的 tar.gz 备份。
a/file1
a/file2
a/file3
a/b/file4
a/b/file5
a/c/file5
a/b/d/file and so on..
现在我想将此路径下的文件和目录与 tar.gz 备份文件进行比较。
请建议 Perl 代码来做到这一点。
问问题
2944 次
5 回答
5
请参阅存档::Tar。
于 2009-08-13T13:51:25.463 回答
5
Archive::Tar和模块将File::Find很有帮助。下面显示了一个基本示例。它只是打印有关 tar 中的文件和目录树中的文件的信息。
从您的问题中不清楚您想如何比较文件。如果您需要比较实际内容，则可能需要使用get_content()中的方法。Archive::Tar::File如果一个更简单的比较就足够了（例如，名称、大小和 mtime），那么您只需要以下示例中使用的方法即可。
#!/usr/bin/perl
use strict;
use warnings;
# A utility function to display our results.
sub Print_file_info {
print map("$_\n", @_), "\n";
}
# Print some basic information about files in a tar.
use Archive::Tar qw();
my $tar_file = 'some_tar_file.tar.gz';
my $tar = Archive::Tar->new($tar_file);
for my $ft ( $tar->get_files ){
# The variable $ft is an Archive::Tar::File object.
Print_file_info(
$ft->name,
$ft->is_file ? 'file' : 'other',
$ft->size,
$ft->mtime,
);
}
# Print some basic information about files in a directory tree.
use File::Find;
my $dir_name = 'some_directory';
my @files;
find(sub {push @files, $File::Find::name}, $dir_name);
Print_file_info(
$_,
-f $_ ? 'file' : 'other',
-s,
(stat)[9],
) for @files;
于 2009-08-13T15:21:47.650 回答
2
Perl 在这方面有点矫枉过正，真的。一个shell脚本就可以了。您需要采取的步骤：
- 将 tar 提取到某处的临时文件夹中。
diff -uR这两个文件夹并将输出重定向到某处（或者可能less是适当的管道）- 清理临时文件夹。
你完成了。不应超过 5-6 行。快速且未经测试的东西：
#!/bin/sh
mkdir $TEMP/$$
tar -xz -f ../backups/backup.tgz $TEMP/$$
diff -uR $TEMP/$$ ./ | less
rm -rf $TEMP/$$
于 2009-08-13T13:23:56.580 回答
2
这是一个检查存档中的每个文件是否也存在于文件夹中的示例。
# $1 is the file to test
# $2 is the base folder
for file in $( tar --list -f $1 | perl -pe'chomp;$_=qq["'$2'$_" ]' )
do
# work around bash deficiency
if [[ -e "$( perl -eprint$file )" ]]
then
echo " $file"
else
echo "no $file"
fi
done
这就是我测试的方式：
我删除/重命名config，然后运行以下命令：
bash 测试下载/update-dnsomatic-0.1.2.tar.gz 下载/
这给出了以下输出：
“下载/更新-dnsomatic-0.1.2/” 没有“下载/更新-dnsomatic-0.1.2/config” “下载/update-dnsomatic-0.1.2/update-dnsomatic” “下载/更新-dnsomatic-0.1.2/README” “下载/更新-dnsomatic-0.1.2/install.sh”
我是 bash / shell 编程的新手，所以可能有更好的方法来做到这一点。
于 2009-08-13T16:19:45.023 回答
1
对于一个好的 Perl 程序，这可能是一个很好的起点。它做了问题所要求的。
它只是拼凑在一起，忽略了 Perl 的大部分最佳实践。
perl test.pl 完整的\
下载/更新-dnsomatic-0.1.2.tar.gz \
下载/\
更新-dnsomatic-0.1.2
#! /usr/bin/env perl
use strict;
use 5.010;
use warnings;
use autodie;
use Archive::Tar;
use File::Spec::Functions qw'catfile catdir';
my($action,$file,$directory,$special_dir) = @ARGV;
if( @ARGV == 1 ){
$file = *STDOUT{IO};
}
if( @ARGV == 3 ){
$special_dir = '';
}
sub has_file(_);
sub same_size($$);
sub find_missing(\%$);
given( lc $action ){
# only compare names
when( @{[qw'simple name names']} ){
my @list = Archive::Tar->list_archive($file);
say qq'missing file: "$_"' for grep{ ! has_file } @list;
}
# compare names, sizes, contents
when( @{[qw'full aggressive']} ){
my $next = Archive::Tar->iter($file);
my( %visited );
while( my $file = $next->() ){
next unless $file->is_file;
my $name = $file->name;
$visited{$name} = 1;
unless( has_file($name) ){
say qq'missing file: "$name"' ;
next;
}
unless( same_size( $name, $file->size ) ){
say qq'different size: "$name"';
next;
}
next unless $file->size;
unless( same_checksum( $name, $file->get_content ) ){
say qq'different checksums: "$name"';
next;
}
}
say qq'file not in archive: "$_"' for find_missing %visited, $special_dir;
}
}
sub has_file(_){
my($file) = @_;
if( -e catfile $directory, $file ){
return 1;
}
return;
}
sub same_size($$){
my($file,$size) = @_;
if( -s catfile($directory,$file) == $size ){
return $size || '0 but true';
}
return; # empty list/undefined
}
sub same_checksum{
my($file,$contents) = @_;
require Digest::SHA1;
my($outside,$inside);
my $sha1 = Digest::SHA1->new;
{
open my $io, '<', catfile $directory, $file;
$sha1->addfile($io);
close $io;
$outside = $sha1->digest;
}
$sha1->add($contents);
$inside = $sha1->digest;
return 1 if $inside eq $outside;
return;
}
sub find_missing(\%$){
my($found,$current_dir) = @_;
my(@dirs,@files);
{
my $open_dir = catdir($directory,$current_dir);
opendir my($h), $open_dir;
while( my $elem = readdir $h ){
next if $elem =~ /^[.]{1,2}[\\\/]?$/;
my $path = catfile $current_dir, $elem;
my $open_path = catfile $open_dir, $elem;
given($open_path){
when( -d ){
push @dirs, $path;
}
when( -f ){
push @files, $path, unless $found->{$path};
}
default{
die qq'not a file or a directory: "$path"';
}
}
}
}
for my $path ( @dirs ){
push @files, find_missing %$found, $path;
}
return @files;
}
重命名为 后config，config.rm向 中添加一个额外的字符README，在 中更改一个字符install.sh，然后添加一个文件.test。这是它输出的：
缺少文件：“update-dnsomatic-0.1.2/config” 不同大小：“update-dnsomatic-0.1.2/README” 不同的校验和：“update-dnsomatic-0.1.2/install.sh” 文件不在存档中：“update-dnsomatic-0.1.2/config.rm” 文件不在存档中：“update-dnsomatic-0.1.2/.test”
于 2009-08-13T21:14:56.817 回答