c++ - 在 CMake 中添加 C++0x 支持

Question

我在 CMake 中配置了一个相当大的应用程序。我最近添加了几个使用 C++0x 功能的类，它破坏了构建，因为 CMake 未配置为使用 C++0x 支持进行编译。如何将其添加为 CMake 的选项？

Answer 1

您需要将标志添加到CMAKE_CXX_FLAGS：

set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++0x")

Answer 2

我将此片段用于 GCC，但它是一种更复杂的方式：

if(CMAKE_COMPILER_IS_GNUCXX)
   SET(ENABLE_CXX11 "-std=c++11")

   EXECUTE_PROCESS(COMMAND "${CMAKE_CXX_COMPILER} -dumpversion" OUTPUT_VARIABLE GCC_VERSION)
   if (GCC_VERSION VERSION_LESS 4.7)
      SET(ENABLE_CXX11 "-std=c++0x")
   endif()

   SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${ENABLE_CXX11}")
endif()

Answer 3

我有以下模块：

$ cat FindCXX11.cmake
# - Finds if the compiler has C++11 support
# This module can be used to detect compiler flags for using C++11, and checks
# a small subset of the language.
#
# The following variables are set:
#   CXX11_FLAGS - flags to add to the CXX compiler for C++11 support
#   CXX11_FOUND - true if the compiler supports C++11
#
# TODO: When compilers starts implementing the whole C++11, check the full set

include(CheckCXXSourceCompiles)
include(FindPackageHandleStandardArgs)

set(CXX11_FLAG_CANDIDATES
    # GNU and Intel Linux
    "-std=c++0x"
    # Microsoft Visual Studio, and everything that automatically accepts C++11
    " "
    #Intel Windows
    "/Qstd=c++0x"
    )

set(CXX11_TEST_SOURCE
"
class Matrix
{
public:
    Matrix(int a, int b, int c, int d)
        : data {a, b, c, d}
    {}

private:
    int data[4];
};

int main()
{
    int n[] {4,7,6,1,2};
    for (auto i : n)
        Matrix mat (3,5,1,2);
    return 0;
}
")

foreach(FLAG ${CXX11_FLAG_CANDIDATES})
    set(SAFE_CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
    set(CMAKE_REQUIRED_FLAGS "${FLAG}")
    unset(CXX11_FLAG_DETECTED CACHE)
    message(STATUS "Try C++11 flag = [${FLAG}]")
    check_cxx_source_compiles("${CXX11_TEST_SOURCE}" CXX11_FLAG_DETECTED)
    set(CMAKE_REQUIRED_FLAGS "${SAFE_CMAKE_REQUIRED_FLAGS}")
    if(CXX11_FLAG_DETECTED)
        set(CXX11_FLAGS_INTERNAL "${FLAG}")
        break()
    endif(CXX11_FLAG_DETECTED)
endforeach(FLAG ${CXX11_FLAG_CANDIDATES})

set(CXX11_FLAGS "${CXX11_FLAGS_INTERNAL}")

find_package_handle_standard_args(CXX11 DEFAULT_MSG CXX11_FLAGS)
mark_as_advanced(CXX11_FLAGS)

我用它来检查编译器是否支持我正在使用的 C++11 的子集（实际上现在这是多余的，因为我正在使用更多）。很容易进一步构建它并添加更多功能，并添加其他编译器开关。实际上，如果我没记错的话，到目前为止我发现的唯一通过此测试的编译器是 GCC >= 4.6 和 Clang >= 3.1。

Answer 4

如this answer所示，最好使用target_compile_features要求支持您需要的特定功能。

这可以更好地解释/记录您的代码所需的功能，跨平台兼容，并且如果所需功能在其编译器中不可用，将为用户提供更有用的错误消息。

在此选项的手册页中：

target_compile_features

将预期的编译器功能添加到目标。

target_compile_features(<target> <PRIVATE|PUBLIC|INTERFACE> <feature> [...])

指定编译给定目标时所需的编译器功能。如果该特性没有在 CMAKE_C_COMPILE_FEATURES 变量或 CMAKE_CXX_COMPILE_FEATURES 变量中列出，那么 CMake 会报错。如果使用该功能需要额外的编译器标志，例如-std=gnu++11，该标志将被自动添加。

可以用这个宏测试的（希望是完整的）特性列表在这里。