2

我有工作：

运行程序

它有以下步骤：

第 1 步：做某事
第 2 步：做其他事情
第 3 步：发送电子邮件

在第 3 步中，我有：

EXEC spSendSuccessEmail -- and here's where I want to pass the job name.

这是上面存储过程的代码：

ALTER PROCEDURE [dbo].[spSendSuccessEmail] @JobName VARCHAR(30)
AS 
BEGIN
    SET NOCOUNT ON;

    DECLARE @EmailBody VARCHAR(50)

    SET @EmailBody = @JobName + ' ran successfully'

    BEGIN TRY
        EXEC msdb.dbo.sp_send_dbmail 
            @profile_name = 'DBTeam',
            @recipients = 'user@universe.com',
            @copy_recipients = 'user2@universe.com',
            @subject = 'Process Complete',
            @body = @EmailBody,
            @importance = 'Normal',
            @sensitivity = 'Normal';
    END TRY
    BEGIN CATCH
        EXEC spGetDatabaseErrorInfo
    END CATCH           
END

如何将其所在作业的名称传递给此存储过程？

我阅读了令牌，但我对如何完成这项任务有点困惑。

谁能帮我一把？

4

1 回答 1

5

更新 我做了一些测试，对于某些版本的 SQL Server（2005 sp1 及更高版本），您必须转义令牌。我已将转义命令添加到下面的代码中。

$(JOBID) 是你要使用的令牌，你可以从 msdb..sysjobs 查询找到作业名称。

对于 sql server 2005 sp1 及更高版本：

declare @jobName varchar(100)

select @jobName = name from msdb..sysjobs where job_id = $(ESCAPE_NONE(JOBID))

exec spSendSuccessEamil @jobName

对于 sql server 2005 及更早版本：

declare @jobName varchar(100)

select @jobName = name from msdb..sysjobs where job_id = $(JOBID)

exec spSendSuccessEamil @jobName

只需在工作的第三步中使用其中之一作为命令文本。

于 2012-10-03T17:11:25.127 回答