4

我对汇编很陌生，我想知道如何将输出写入标准错误。我知道您可以访问 C 标准库函数，例如 printf，以打印到控制台。但我不知道如何打印到标准错误。我试图使用 fprintf，但我只是在猜测参数，我不知道如何将 stderr 指定为文件指针。谢谢。

编辑：根据sehe的建议，我尝试了这个：

.586
.model small,c
.stack 100h

.data
msg db 'test', 0Ah

.code
includelib MSVCRT
extrn fprintf:near
extrn exit:near

public main
main proc
    push    offset msg
    push    2       ;specify stderr
    call    fprintf ;print to stderr
    push    0
    call    exit    ;exit status code 0

main endp

end main

但这只是导致我的程序崩溃。还有什么建议吗？

4

2 回答 2

8

您是否使用 MSVCRT dll 中的 fprintf？

第一个参数是指向流的指针。这是在汇编中使用 fprintf 的方法。此外，从 Assembly 调用 C 函数时，您需要在每次调用后调整堆栈，然后将参数推送到该堆栈。

另外，一个 BIGGIE ......你的字符串不是 NULL 终止的！您必须 NULL 终止您的字符串，这就是函数如何找到字符串的长度。不确定您使用的是什么汇编程序，但这是您可以在 MASM 中执行此操作的方法：

include masm32rt.inc

_iobuf STRUCT
    _ptr        DWORD ?
    _cnt        DWORD ?
    _base       DWORD ?
    _flag       DWORD ?
    _file       DWORD ?
    _charbuf    DWORD ?
    _bufsiz     DWORD ?
    _tmpfname   DWORD ?
_iobuf ENDS

FILE TYPEDEF _iobuf

.data
msg         db 'test', 0Ah, 0    

.data?
stdin       dd ?
stdout      dd ?
stderr      dd ?

.code
start: 

    call    crt___p__iob
    mov     stdin,eax          
    add     eax,SIZEOF(FILE)
    mov     stdout,eax          
    add     eax,SIZEOF(FILE)
    mov     stderr,eax        

    push    offset msg
    push    eax
    call    crt_fprintf
    add     esp, 4 * 2

    push    0
    call    crt_exit 

end start
于 2012-10-03T01:39:18.280 回答
1

我来到这里是因为我在 Debian Linux 下无法写入 stderr。我使用 yasm，因为我正在阅读 Ray Seyfarth 的书。我正在用 Intel 语法编写 elf64 格式和 dwarf2 调试协议。

我第一次尝试使用 fprintf 时遇到了分段错误。我查看了 stdio 的内部结构。我设法编写了相当于一个单行程序：

     int main()
     {
       fprintf(stderr, "%d\n", 3);
     }

但是当我完全修改它时，我又开始遇到分段错误。我的目标是获得相当于：

    int main(int argc, char* argv[])
    {
      if (argc != 2) {
        fprintf(stderr, "Usage: %s n\n", argv[0]);
      } else {
        /* program code */
      }
    }

我的最终解决方案是使用 sprintf() 调用，然后使用文件描述符进行 write() 系统调用。还需要调用 strlen()。这种策略应该适用于可以从汇编代码调用 C 库函数的任何环境。这是一些示例代码。如果没有给出参数或参数太多，则会打印一条使用消息并退出程序。如果提供了一个参数，则将其转换为整数并打印。

        segment .text
        global  main
        extern  printf, atoi, sprintf, strlen, write

    main:
    .argc   equ 0
    .argv   equ 4

        segment .data
    .f1 db  "Usage: %s n", 0x0a, 0
    .f2 db  "%d", 0x0a, 0

        segment .bss
    .buf    resb    255

        segment .text

        push    rbp
        mov rbp, rsp
        sub rsp, 16

        ; Save the arguments.
        mov [rsp+.argc], rdi
        mov [rsp+.argv], rsi

        ; if (argc != 2)
        cmp rdi, 2
        jne .usage

        ; Convert argv[1] to an integer, then print it.
        ; We could have printed argv[1] as a string,
        ; but in an actual program we might want to do
        ; n = atoi(argv[1])
        ; because we are passing a number on the command line.

        ; printf("%d\n", atoi(argv[1]))

        ; Get argv[1].
        mov rax, [rsp+.argv]
        mov rdi, [rax+8]        ; rdi gets *(argv + 1), or argv[1].
        call    atoi            ; Return value in eax.

        lea rdi, [.f2]
        mov esi, eax
        xor eax, eax
        call    printf

        jmp .done

    .usage:
        ; Get argv[0].
        mov rax, [rsp+.argv]
        mov rax, [rax]

        ; sprintf(buf, "Usage: %s n\n", argv[0])
        lea rdi, [.buf]
        lea rsi, [.f1]
        mov rdx, rax
        xor eax, eax
        call    sprintf

        ; len = strlen(buf);
        lea rdi, [.buf]
        call    strlen      ; string length is placed in eax.

        ; write(2, buf, strlen(buf))
        mov edi, 2      ; fd for stderr
        lea rsi, [.buf]
        mov edx, eax
        call    write

    .done:
        leave
        ret

假设上面的代码包含在 progname.asm 中，它的组装和链接如下：

    yasm -f elf64 -g dwarf2 -l progname.lst progname.asm
    gcc progname.o -o progname
于 2017-01-12T01:57:19.737 回答