2

原始的office文件没有问题（我尝试了word和excel），但是当我将文件作为二进制文件上传到数据库然后从那里下载到我的PC并打开下载的文件时，我收到警告消息“找到excel内容无法读取”等，并且与原始文件相比，文件变得更加清晰。

确切的错误信息是；“Excel 在 filename.xls 中发现了不可读的内容。是否要恢复此工作簿的内容？如果您信任此工作簿的来源，请单击“是”。

我如何上传文件：

'UPLOAD FILE
Dim fi As New FileInfo(FilePath)
Dim s As Stream = fi.OpenRead()
Dim buffer(fi.Length) As Byte 'I put the buffer in database in varbinary(max) format
s.Read(buffer, 0, fi.Length)
s.Close()

我如何下载和打开文件：

'DOWNLOAD FILE
Dim fi As New FileInfo(FilePath)
Dim s As Stream = fi.OpenWrite()
Dim buffer As Byte() = reader("Binary")
s.Write(buffer, 0, buffer.Length)
s.Close()

'OPEN FILE
Dim p As New Process
p.StartInfo = New ProcessStartInfo(FilePath)
p.Start()

更新：

正如建议的那样，我尝试简单地复制文件，将 SQL 完全排除在外。这是我尝试过的代码，但也失败了：

Private Sub CopyFile(ByVal filePath As String)
    Dim fi As New FileInfo(filePath)
    Dim s As Stream = fi.OpenRead()
    Dim buffer(CType(fi.Length, Integer) - 1) As Byte
    s.Read(buffer, 0, CType(fi.Length, Integer))
    s.Close()

    Dim fi2 As New FileInfo(filePath & " Copy")
    Dim s2 As Stream = fi2.OpenWrite()
    s2.Write(buffer, 0, buffer.Length)
    s2.Close()
End Sub
4

1 回答 1

3

正如这篇 MSDN 文章所述，VB.NET 数组的声明方式与其他语言（例如 C#）不同。在其他语言中，当声明一个固定长度的数组时，给定的大小被用作数组的总长度。例如，在 c# 中，该语句fixed byte buffer[3];将声明一个包含 3 个元素（索引从 0 到 2）的字节数组。但是，在 VB 中，声明固定数组时给出的大小用作数组的上限，而不是大小。因此，在 VB 中，该语句Dim buffer(3) As Byte声明了一个包含 4 个元素（索引从 0 到 3）的字节数组。

考虑到这一点，如果您仔细查看您的代码，您实际上是在声明一个字节数组，它比文件的大小大一个元素（索引从 0 到 fi.Length）。然后，您将从索引 0 开始将整个文件读入字节数组。因此，数组中的最后一个字节保留为值 0（空字符）。然后，您将字节数组的全部内容写入一个新文件，包括最后一个空字节。因此，您的代码正确地复制了文件中的所有字节，但在文件末尾添加了一个额外的空字节，这使 Excel 不高兴。如果查看原始文件大小和新创建文件的文件大小，您会发现新文件比原始文件大一个字节。

要解决此问题，您只需在声明数组时调整数组的大小，使其与文件的长度完全相同：

Dim buffer(fi.Length - 1) As Byte

但是，当我这样做时，我觉得有义务指出您发布的代码中的其他一些改进领域。首先，在使用实现IDisposable接口的对象时，如Stream，最好尽可能使用Using语句。这样做可确保对象始终正确关闭/处置，即使在遇到异常的情况下也是如此。例如，如果你这样做会更好：

Dim fi As New FileInfo(FilePath)
Using s As Stream = fi.OpenRead()
    Dim buffer(fi.Length - 1) As Byte
    s.Read(buffer, 0, fi.Length)
End Using

此外，很明显您没有使用Option Strict，因为如果您使用了，则不允许您使用 fi.Length (a Long) 作为数组大小或缓冲区长度的参数。如果打开Option Strict，您将被迫明确声明要将Long值强制转换为Integer. 例如：

Dim fi As New FileInfo(FilePath)
Using s As Stream = fi.OpenRead()
    Dim buffer(CInt(fi.Length) - 1) As Byte
    s.Read(buffer, 0, CInt(fi.Length))
End Using

在大多数情况下，打开Option Strict是一个非常好的主意。它迫使您了解变量类型以及何时可能丢失数据。例如，在这种情况下，通过Option Strict打开，您会意识到文件大小 ( Long.MaxValue) 可能大于数组的最大长度 ( Integer.MaxValue)，因此，如果您想处理非常大的文件，您会需要编写一个循环读取和写入块中的文件。即使您不想处理大文件，最好先检查大小，这样您就可以优雅地处理错误，而不是允许抛出溢出异常：

If fi.Length >= Integer.Max Then
    'Display or log error that the file is too large, and skip loading the file
Else
    'Load file
End If

最后，如果您不关心处理大文件，还有一种更简单的方法来读取和写入文件中的所有字节：

'UPLOAD FILE
Dim buffer() As Byte = File.ReadAllBytes(filePath)

'DOWNLOAD FILE
Dim buffer As Byte() = reader("Binary")
File.WriteAllBytes(filePath, buffer)
于 2012-10-03T12:31:00.820 回答